API tools faq
paste
toribio

toribio

toribio
Dec 14th, 2009
116
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
C 6.07 KB | None | 0 0
raw download clone embed print report
  1. /**
  2.  *  Progress Bar 1.2.0.0
  3.  *  Copyright 2007-2010 Infernus' Group,
  4.  *  Flávio Toribio (flavio_toibio@hotmail.com)
  5.  */
  6.  
  7. #if defined _progress_included
  8.     #endinput
  9. #endif
  10.  
  11. #if !defined _samp_included
  12.     #tryinclude <a_samp>
  13.     #if !defined _samp_included
  14.         #error could not locate a_samp.inc file, please check your server includes
  15.     #endif
  16. #endif
  17.  
  18. #tryinclude <foreach>
  19.  
  20. #define _progress_included
  21. #define _progress_version   0x1200
  22.  
  23. #define MAX_BARS                (MAX_TEXT_DRAWS / 3)
  24. #define INVALID_BAR_VALUE       (Float:0xFFFFFFFF)
  25. #define INVALID_BAR_ID          (Bar:-1)
  26. #define pb_percent(%1,%2,%3,%4) ((%1 - 6.0) + ((((%1 + 6.0 + %2 - 2.0) - %1) / %3) * %4))
  27. //pb_percent(x, width, max, value)
  28.  
  29. /* Pawno/Infernus Pawn Editor function list
  30. native Bar:CreateProgressBar(Float:x, Float:y, Float:width=55.5, Float:height=3.2, color, Float:max=100.0);
  31. native DestroyProgressBar(Bar:barid);
  32. native ShowProgressBarForPlayer(playerid, Bar:barid);
  33. native HideProgressBarForPlayer(playerid, Bar:barid);
  34. native ShowProgressBarForAll(Bar:barid);
  35. native HideProgressBarForAll(Bar:barid);
  36. native SetProgressBarValue(Bar:barid, Float:value);
  37. native Float:GetProgressBarValue(Bar:barid);
  38. native SetProgressBarMaxValue(Bar:barid, Float:max);
  39. native UpdateProgressBar(Bar:barid, playerid=INVALID_PLAYER_ID);
  40. */
  41.  
  42. forward Float:GetProgressBarValue(Bar:barid);
  43.  
  44. enum e_bar
  45. {
  46.     Float:pb_x,
  47.     Float:pb_y,
  48.     Float:pb_w,
  49.     Float:pb_h,
  50.     Float:pb_m,
  51.     Float:pb_v,
  52.     Text:pb_t1,
  53.     Text:pb_t2,
  54.     Text:pb_t3,
  55.     pb_color,
  56.     bool:pb_created
  57. }
  58.  
  59. static Bars[MAX_BARS][e_bar];
  60.  
  61. stock Bar:CreateProgressBar(Float:x, Float:y, Float:width=55.5, Float:height=3.2, color, Float:max=100.0)
  62. {
  63.     new
  64.         barid;
  65.  
  66.     for(barid = 0; barid < sizeof Bars; ++barid)
  67.         if(!Bars[barid][pb_created]) break;
  68.  
  69.     if(Bars[barid][pb_created])
  70.         return INVALID_BAR_ID;
  71.  
  72.     new Text:in_t = Bars[barid][pb_t1] = TextDrawCreate(x, y, "_");
  73.     TextDrawUseBox          (in_t, 1);
  74.     TextDrawTextSize        (in_t, x + width, 0.0);
  75.     TextDrawLetterSize      (in_t, 1.0, height / 10);
  76.     TextDrawBoxColor        (in_t, 0x000000FF);
  77.  
  78.     in_t = Bars[barid][pb_t2] = TextDrawCreate(x + 1.2, y + 2.15, "_");
  79.     TextDrawUseBox          (in_t, 1);
  80.     TextDrawTextSize        (in_t, x + width - 2.0, 0.0);
  81.     TextDrawLetterSize      (in_t, 1.0, height / 10 - 0.35);
  82.     TextDrawBoxColor        (in_t, (color & 0xFFFFFF00) | 0x66);
  83.  
  84.     in_t = Bars[barid][pb_t3] = TextDrawCreate(x + 1.2, y + 2.15, "_");
  85.     TextDrawTextSize        (in_t, pb_percent(x, width, max, 1.0), 0.0);
  86.     TextDrawLetterSize      (in_t, 1.0, height / 10 - 0.35);
  87.     TextDrawBoxColor        (in_t, (color & 0xFFFFFF00) | 0xFF);
  88.  
  89.     Bars[barid][pb_x] = x;
  90.     Bars[barid][pb_y] = y;
  91.     Bars[barid][pb_w] = width;
  92.     Bars[barid][pb_h] = height;
  93.     Bars[barid][pb_m] = max;
  94.     Bars[barid][pb_color] = color;
  95.     Bars[barid][pb_created] = true;
  96.     return Bar:barid;
  97. }
  98.  
  99. stock DestroyProgressBar(Bar:barid)
  100. {
  101.     if(barid != INVALID_BAR_ID && Bar:-1 < barid < Bar:MAX_BARS)
  102.     {
  103.         if(!Bars[_:barid][pb_created])
  104.             return 0;
  105.  
  106.         TextDrawDestroy(Bars[_:barid][pb_t1]);
  107.         TextDrawDestroy(Bars[_:barid][pb_t2]);
  108.         TextDrawDestroy(Bars[_:barid][pb_t3]);
  109.  
  110.         Bars[_:barid][pb_t1] = Text:0;      
  111.         Bars[_:barid][pb_t2] = Text:0;      
  112.         Bars[_:barid][pb_t3] = Text:0;
  113.         Bars[_:barid][pb_x] = 0.0;
  114.         Bars[_:barid][pb_y] = 0.0;
  115.         Bars[_:barid][pb_w] = 0.0;
  116.         Bars[_:barid][pb_h] = 0.0;
  117.         Bars[_:barid][pb_m] = 0.0;
  118.         Bars[_:barid][pb_v] = 0.0;
  119.         Bars[_:barid][pb_color] = 0;
  120.         Bars[_:barid][pb_created] = false;
  121.         return 1;
  122.     }
  123.     return 0;
  124. }
  125.  
  126. stock ShowProgressBarForPlayer(playerid, Bar:barid)
  127. {
  128.     if(IsPlayerConnected(playerid) && barid != INVALID_BAR_ID && Bar:-1 < barid < Bar:MAX_BARS)
  129.     {
  130.         if(!Bars[_:barid][pb_created])
  131.             return 0;
  132.  
  133.         TextDrawShowForPlayer(playerid, Bars[_:barid][pb_t1]);
  134.         TextDrawShowForPlayer(playerid, Bars[_:barid][pb_t2]);
  135.         TextDrawShowForPlayer(playerid, Bars[_:barid][pb_t3]);
  136.         return 1;
  137.     }
  138.     return 0;
  139. }
  140.  
  141. stock HideProgressBarForPlayer(playerid, Bar:barid)
  142. {
  143.     if(IsPlayerConnected(playerid) && barid != INVALID_BAR_ID && Bar:-1 < barid < Bar:MAX_BARS)
  144.     {
  145.         if(!Bars[_:barid][pb_created])
  146.             return 0;
  147.  
  148.         TextDrawHideForPlayer(playerid, Bars[_:barid][pb_t1]);
  149.         TextDrawHideForPlayer(playerid, Bars[_:barid][pb_t2]);
  150.         TextDrawHideForPlayer(playerid, Bars[_:barid][pb_t3]);
  151.         return 1;
  152.     }
  153.     return 0;
  154. }
  155.  
  156. stock SetProgressBarValue(Bar:barid, Float:value)
  157. {
  158.     if(barid == INVALID_BAR_ID || Bar:MAX_BARS < barid < Bar:-1)
  159.         return 0;
  160.  
  161.     if(Bars[_:barid][pb_created])
  162.     {
  163.         value =
  164.             (value < 0.0) ? (0.0) : (value > Bars[_:barid][pb_m]) ? (Bars[_:barid][pb_m]) : (value);
  165.  
  166.         TextDrawUseBox(Bars[_:barid][pb_t3], value > 0.0);
  167.  
  168.         Bars[_:barid][pb_v] = value;
  169.  
  170.         TextDrawTextSize(Bars[_:barid][pb_t3],
  171.             pb_percent(Bars[_:barid][pb_x], Bars[_:barid][pb_w], Bars[_:barid][pb_m], value), 0.0);
  172.  
  173.         return 1;
  174.     }
  175.     return 0;
  176. }
  177.  
  178. stock Float:GetProgressBarValue(Bar:barid)
  179. {
  180.     if(barid == INVALID_BAR_ID || Bar:MAX_BARS < barid < Bar:-1)
  181.         return INVALID_BAR_VALUE;
  182.  
  183.     if(Bars[_:barid][pb_created])
  184.         return Bars[_:barid][pb_v];
  185.  
  186.     return INVALID_BAR_VALUE;
  187. }
  188.  
  189. stock SetProgressBarMaxValue(Bar:barid, Float:max)
  190. {
  191.     if(barid == INVALID_BAR_ID || Bar:MAX_BARS < barid < Bar:-1)
  192.         return 0;
  193.  
  194.     if(Bars[_:barid][pb_created])
  195.     {
  196.         Bars[_:barid][pb_m] = max;
  197.         SetProgressBarValue(barid, Bars[_:barid][pb_v]);
  198.         return 1;
  199.     }
  200.     return 0;
  201. }
  202.  
  203. stock ShowProgressBarForAll(Bar:barid)
  204. {
  205.     #if defined _foreach_included
  206.     foreach(Player, i)
  207.     #else
  208.     for(new i = 0; i < MAX_PLAYERS; ++i)
  209.         if(IsPlayerConnected(i))
  210.     #endif
  211.     #if defined IsPlayerNPC
  212.         if(!IsPlayerNPC(i))
  213.     #endif
  214.     {
  215.         ShowProgressBarForPlayer(i, barid);
  216.     }
  217.     return 1;
  218. }
  219.  
  220. stock HideProgressBarForAll(Bar:barid)
  221. {
  222.     #if defined _foreach_included
  223.     foreach(Player, i)
  224.     #else
  225.     for(new i = 0; i < MAX_PLAYERS; ++i)
  226.         if(IsPlayerConnected(i))
  227.     #endif
  228.     #if defined IsPlayerNPC
  229.         if(!IsPlayerNPC(i))
  230.     #endif
  231.     {
  232.         HideProgressBarForPlayer(i, barid);
  233.     }
  234.     return 1;
  235. }
  236.  
  237. stock UpdateProgressBar(Bar:barid, playerid=INVALID_PLAYER_ID)
  238. {
  239.     if(playerid == INVALID_PLAYER_ID)
  240.     {
  241.         return ShowProgressBarForAll(barid);
  242.     } else {
  243.         return ShowProgressBarForPlayer(playerid, barid);
  244.     }
  245. }
Add Comment
Please, Sign In to add comment
Public Pastes
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!