POST_67

/*  TITULO: Robot Miniskybot 2.0 controlado a través de Bluetooth

    AUTOR:

    MARIANO DEL CAMPO GARCÍA (@2016) --> INGENIERO TÉCNICO INDUSTRIAL ESPECIALIDAD ELECTRÓNICA
    - FACEBOOK: https://www.facebook.com/mariano.delcampogarcia
    - TWITTER: https://twitter.com/MarianoCampoGa
    - CORREO: marianodc83@gmail.com


    DESCRIPCIÓN DEL PROGRAMA

    Con este programa controlamos el movimiento del Robot Miniskybot 2.0 mediante Bluetooth,
    a través de la aplicación para Smartphones con S.O Android llamada "Wise HC-06 Carrinho Bluetooth",
    que nos podemos descargar directamente de la Play Store de nuestro Smarthpone.
    Al pulsar cada una de las flechas de la aplicación, el robot se movera en una dirección concreta,
    a excepción de la flecha hacia abajo, puesto que si el robot está en movimiento, al pulsarla el
    robot se para, y si el robot esta parado, al pulsarla se movera marcha atrás.


    ESQUEMA DE CONEXION

                                      +-----+
         +----[PWR]-------------------| USB |--+
         |                            +-----+  |
         |         GND/RST2  [ ][ ]            |
         |       MOSI2/SCK2  [ ][ ]  A5/SCL[ ] |
         |          5V/MISO2 [ ][ ]  A4/SDA[ ] |
         |                             AREF[ ] |
         |                              GND[ ] |
         | [ ]N/C                    SCK/13[ ] |
         | [ ]IOREF                 MISO/12[ ] |
         | [ ]RST                   MOSI/11[ ]~|   Pin RX del Módulo Bluetooth HC-06
         | [ ]3V3    +---+               10[ ]~|   Pin TX del Módulo Bluetooth HC-06
         | [ ]5v    -| A |-               9[ ]~|
         | [ ]GND   -| R |-               8[ ] |
         | [ ]GND   -| D |-                    |
         | [ ]Vin   -| U |-               7[ ] |
         |          -| I |-               6[ ]~|
         | [ ]A0    -| N |-               5[ ]~|   Cable blanco (Señal) del SERVO_IZQUIERDO
         | [ ]A1    -| O |-               4[ ] |
         | [ ]A2     +---+           INT1/3[ ]~|   Cable blanco (Señal) del SERVO_DERECHO
         | [ ]A3                     INT0/2[ ] |
         | [ ]A4/SDA  RST SCK MISO     TX>1[ ] |
         | [ ]A5/SCL  [ ] [ ] [ ]      RX<0[ ] |
         |            [ ] [ ] [ ]              |
         |  UNO_R3    GND MOSI 5V  ____________/
          \_______________________/

  NOTAS:

    - Todas las alimentaciones (cables rojos) y las masas (cables negros) de los servos van
      conectadas a +5V y GND respectivamente.
    - La alimentación y la masa del Módulo Bluetooth HC-06 van conectadas directamente a +5V y
      GND respectivamente.
    - Las conexiones están marcadas soble la placa de Arduino UNO, aunque luego conectemos
      directamente sobre los terminales de 3 pines (GVS) del sensor shield V4.0 que correspondan
      a cada pin digital de Arduino que estemos utilizando.

*/

  // Incluimos la librería para la comunicación serie con Arduino
  #include "SoftwareSerial.h"
  // Incluimos la librería para el funcionamiento y control de los servos
  #include <Servo.h>

  // Declaramos el objeto BT1 para la comunicación serie con el módulo Bluetooth HC-06
  // Utilizamos el pin 10 para recibir y el 11 para transmitir hacia el módulo Bluetooth HC-06
  SoftwareSerial BT1(10,11); // RX, TX para Arduino

  char cadena[5]; // Creamos un array de caracteres de 5 posiciones para guardar el código de cada flecha
  char dato; // Variable para guardar el carácter
  int i=0; // Tamaño actual del array
  int movimiento=0; // Variable para controlar si el robot se mueve o está parado (inicialmente parado).

  // Constantes para el motor derecho
  const int SERVO_DERECHO = 3;  // PIN PWM donde conecto el servomotor derecho
  const int SERVO_DERECHO_ADELANTE = 0;    // Mueve el motor derecho hacia adelante
  const int SERVO_DERECHO_ATRAS = 180;  // Mueve el motor derecho hacia atrás
  const int SERVO_DERECHO_PARA = 90; // Para el motor derecho

  // Constantes para el motor izquierdo (invertidas porque se monta el servo al revés)
  const int SERVO_IZQUIERDO = 5;  // PIN PWM donde conecto el servomotor izquierdo
  const int SERVO_IZQUIERDO_ADELANTE = 180;  // Mueve el motor izquierdo hacia adelante
  const int SERVO_IZQUIERDO_ATRAS = 0;    // Mueve el motor izquierdo hacia atrás
  const int SERVO_IZQUIERDO_PARA = 90; // Para el motor izquierdo


  // Declaramos los dos objetos de tipo servo
  Servo motor_derecho;  // Motor derecho
  Servo motor_izquierdo;  // Motor izquierdo

  // Función que manda AVANZAR al robot
  void robot_avanza()
  {
    motor_derecho.write(SERVO_DERECHO_ATRAS);
    motor_izquierdo.write(SERVO_IZQUIERDO_ATRAS);
  }

  // Función que manda RETROCEDER al robot
  void robot_retrocede()
  {
    motor_derecho.write(SERVO_DERECHO_ADELANTE);
    motor_izquierdo.write(SERVO_IZQUIERDO_ADELANTE);
  }

  // Función que manda PARARSE al robot
  void robot_para()
  {
    motor_derecho.write(SERVO_DERECHO_PARA);
    motor_izquierdo.write(SERVO_IZQUIERDO_PARA);
  }

  // Función que hace que gire el robot a la IZQUIERDA
  void robot_izquierda()
  {
    motor_derecho.write(SERVO_DERECHO_ATRAS);
    motor_izquierdo.write(SERVO_IZQUIERDO_ADELANTE);
  }

  // Función que hace que gire el robot a la DERECHA
  void robot_derecha()
  {
    motor_derecho.write(SERVO_DERECHO_ADELANTE);
    motor_izquierdo.write(SERVO_IZQUIERDO_ATRAS);
  }


  void setup()
  {
    // Configuramos el pin de señal de los dos servos
    motor_derecho.attach(SERVO_DERECHO); // Servo derecho
    motor_izquierdo.attach(SERVO_IZQUIERDO); // Servo izquierdo

    // Iniciamos la comunicación serie con el módulo Bluetooth HC-06
    BT1.begin(9600); // Aquí hay que poner la velocidad que tengamos configurada en nuestro HC-06
  }

  void loop()
  {
    // Si hay disponible comunicación con el módulo Bluetooth HC-06...
    if (BT1.available())
    {
      dato = BT1.read(); // Leemos un carácter y lo guardamos en dato
      cadena[i++]=dato; // Vamos acumulando cada carácter (dato) recibido en el array "cadena"

    // Cuando hemos recibido una cadena completa (4 caracteres).
    if(i==4)
    {
      // Cuando pulsamos la flecha DERECHA de la aplicación se recibe la cadena "D1S0"
      if(strstr(cadena,"D1S0")!=0)
      {
        movimiento = 1; // El robot comienza a moverse
        robot_derecha(); // El robot gira hacia la DERECHA
      }

      // Cuando pulsamos la flecha IZQUIERDA de la aplicación se recibe la cadena "E1S0"
      if(strstr(cadena,"E1S0")!=0)
      {
        movimiento = 1; // El robot comienza a moverse
        robot_izquierda(); // El robot gira hacia la IZQUIERDA
      }

      // Cuando pulsamos la flecha ARRIBA de la aplicación se recibe la cadena "F1S0"
      if(strstr(cadena,"F1S0")!=0)
      {
        movimiento = 1; // El robot comienza a moverse
        robot_avanza(); // El robot se mueve hacia ADELANTE
      }

      // Cuando pulsamos la flecha ABAJO y el coche está PARADO se recibe la cadena "T1S0"
      if(strstr(cadena,"T1S0")!=0 && movimiento == 0)
      {
        movimiento = 1; // El robot comienza a moverse
        robot_retrocede();  // El robot se mueve hacia ATRÁS
        clean(); // Ejecutamos la función clean() para limpiar el array
      }

      // Cuando pulsamos la flecha ABAJO y el coche está EN MOVIMIENTO se recibe la cadena "T1S0"
      if(strstr(cadena,"T1S0")!=0 && movimiento == 1)
      {
        movimiento = 0; // El robot permanece parado
        robot_para(); // El robot se PARA
        clean(); // Ejecutamos la función clean() para limpiar el array
      }

      clean(); // Ejecutamos la función clean() para limpiar el array
      i=0; // Inicializamos el contador del array
    }
   }
  }

  // Limpia el array para poder recibir nuevos códigos
  void clean()
  {
    for (int cl=0; cl<=i; cl++)
    {
      cadena[cl]=0;
    }
    i=0;
  }