POST_9

/*  TITULO: Display LCD 16x2 con comunicación I2C

    AUTOR:

    MARIANO DEL CAMPO GARCÍA (@2015) --> INGENIERO TÉCNICO INDUSTRIAL ESPECIALIDAD ELECTRÓNICA
    - FACEBOOK: https://www.facebook.com/mariano.delcampogarcia
    - TWITTER: https://twitter.com/MarianoCampoGa
    - CORREO: marianodc83@gmail.com


    DESCRIPCIÓN DEL PROGRAMA

    En este programa vamos a comunicar un Display LCD 16x2 con Arduino mediante comunicación I2C,
    gracias a la utilización del módulo LCM 1602 I2C V1, que tenemos soldado a los pines del LCD 1602.
    Además mediante la utilización del IDE de Arduino, vamos a poder mandar caracteres a Arduino y
    visualizarlos a través del LCD 1602.


    ESQUEMA DE CONEXION

                                      +-----+
         +----[PWR]-------------------| USB |--+
         |                            +-----+  |
         |         GND/RST2  [ ][ ]            |
         |       MOSI2/SCK2  [ ][ ]  A5/SCL[ ] |   SCL del módulo I2C conectado al LCD 1602
         |          5V/MISO2 [ ][ ]  A4/SDA[ ] |   SDA del módulo I2C conectado al LCD 1602
         |                             AREF[ ] |
         |                              GND[ ] |
         | [ ]N/C                    SCK/13[ ] |
         | [ ]IOREF                 MISO/12[ ] |
         | [ ]RST                   MOSI/11[ ]~|
         | [ ]3V3    +---+               10[ ]~|
         | [ ]5v    -| A |-               9[ ]~|
         | [ ]GND   -| R |-               8[ ] |
         | [ ]GND   -| D |-                    |
         | [ ]Vin   -| U |-               7[ ] |
         |          -| I |-               6[ ]~|
         | [ ]A0    -| N |-               5[ ]~|
         | [ ]A1    -| O |-               4[ ] |
         | [ ]A2     +---+           INT1/3[ ]~|
         | [ ]A3                     INT0/2[ ] |
         | [ ]A4/SDA  RST SCK MISO     TX>1[ ] |
         | [ ]A5/SCL  [ ] [ ] [ ]      RX<0[ ] |
         |            [ ] [ ] [ ]              |
         |  UNO_R3    GND MOSI 5V  ____________/
          \_______________________/

  NOTAS:
   - La alimentación y la masa del módulo LCM 1602 I2C V1 van directamente conectadas a VCC (+5V) y GND
     respectivamente.
*/


  // Importar librerías
  #include <Wire.h> // Librería comunicación I2C
  #include <LiquidCrystal_I2C.h> // Librería LCD I2C

  // Declaración del objeto
  // Terminales de conexión del LCD:
  //                    addr, en,rw,rs,d4,d5,d6,d7,bl,blpol
  LiquidCrystal_I2C lcd(0x3E, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);

  void setup()
  {
    Serial.begin(9600);  // Configura la velocidad de la comunicación serie
    lcd.begin(16,2);   // Inicializa el LCD para 16x2


  // Realiza 3 parpadeos del LED (backlight)
    for(int i = 0; i< 3; i++)
    {
      lcd.backlight();
      delay(250);
      lcd.noBacklight();
      delay(250);
    }
   lcd.backlight(); // Finaliza con el LED encendido (backlight)

  // Escribe el texto en el LCD
  // NOTA: La posición del cursor del LCD (Carácter, línea) comienza en (0,0)
    lcd.setCursor(0,0);
    lcd.write("Hola, Usuario!"); // Podemos poner tanto write como print
    delay(1000);
    lcd.setCursor(0,1);
    lcd.write("Bienvenido");
    delay(2000);

  // Espera a que se conecte el monitor serie y envía los caracteres al LCD
  // Configurar el monitor serie en el modo "Sin final de línea"
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("Monitor serie...");
    lcd.setCursor(0,1);
    lcd.print(">Pulsa una tecla");
  }


  void loop()
  {
      char ch;
      // Si se recibe un carácter por el puerto serie...
      if (Serial.available())
      {
        // Retardo para que pueda recibir el caracter
        delay(100);
        // Borra la pantalla
        lcd.clear();
        lcd.print("Recibiendo>>> ");
        lcd.setCursor(14,0);

        // Si lo recibido es mayor que 0...
        while (Serial.available() > 0)
        {
          // Lee el carácter que llega
          ch = Serial.read();
          // Muestra el carácter a través del LCD
          lcd.write(ch);
          // Muestra por terminal virtual el carácter enviado al LCD
          Serial.write(ch);
        }
      }
  }