function grab_free_pap( player )
{
    current_weapon = player GetCurrentWeapon();
    weaponsize = player GetWeaponsListPrimaries();

    if( zm_utility::is_player_valid( player ) && !IS_DRINKING(player.is_drinking) && !zm_utility::is_placeable_mine( current_weapon )  && !zm_equipment::is_equipment( current_weapon ) && !player zm_utility::is_player_revive_tool(current_weapon) && level.weaponNone!= current_weapon  && !player zm_equipment::hacker_active() && !player laststand::player_is_in_laststand())
    {
        b_weapon_supports_aat = zm_weapons::weapon_supports_aat( current_weapon );
        currentAATHashID = -1;
        if ( b_weapon_supports_aat )
        {
            currentAAT = player aat::getAATOnWeapon(current_weapon);
            if (isDefined(currentAAT))
            {
                currentAATHashID = currentAAT.hash_id;
            }
            player.restore_ammo = true;
            player.restore_clip = player GetWeaponAmmoClip( current_weapon );
            player.restore_clip_size = current_weapon.clipSize;
            player.restore_stock = player Getweaponammostock( current_weapon );
            player.restore_max = current_weapon.maxAmmo;
        }

        upgrade_weapon = zm_weapons::get_upgrade_weapon( current_weapon, b_weapon_supports_aat );

        weapon_limit = zm_utility::get_player_weapon_limit( player );

        if(!zm_weapons::is_weapon_upgraded(current_weapon))//Checks if that weapon is already upgraded.
        {
            player TakeWeapon(current_weapon);//Takes players original weapon (non pap version), else the player has the pap version and normal one.
         }

        player zm_weapons::take_fallback_weapon();

        if(!zm_weapons::is_weapon_upgraded(current_weapon))
        {
            primaries = player GetWeaponsListPrimaries();
            if( isDefined( primaries ) && primaries.size >= weapon_limit )
            {
                upgrade_weapon = player zm_weapons::weapon_give( upgrade_weapon );
            }
            else
            {
                upgrade_weapon = player zm_weapons::give_build_kit_weapon( upgrade_weapon );
                player GiveStartAmmo( upgrade_weapon );
            }
        }
        else if( IS_TRUE( b_weapon_supports_aat ) )//Error fixed, Before It would start weapon give anim after weapon switch every time.
        {
            upgrade_weapon = player zm_weapons::give_build_kit_weapon( upgrade_weapon );
        }

        aatID = -1;
        if ( IS_TRUE( b_weapon_supports_aat ) )
        {
            player thread aat::acquire( upgrade_weapon );
            aatObj = player aat::getAATOnWeapon(upgrade_weapon);
            if (isDefined(aatObj))
            {
                aatID = aatObj.hash_id;
            }
        }
        else
        {
            player thread aat::remove( upgrade_weapon );
        }

        if (IS_TRUE(player.restore_ammo))
        {
            new_clip = player.restore_clip + ( upgrade_weapon.clipSize - player.restore_clip_size );
            new_stock = player.restore_stock + ( upgrade_weapon.maxAmmo - player.restore_max );
            player SetWeaponAmmoStock( upgrade_weapon, new_stock );
            player SetWeaponAmmoClip( upgrade_weapon, new_clip );
        }
        player.restore_ammo = undefined;
        player.restore_clip = undefined;
        player.restore_stock = undefined;
        player.restore_max = undefined;
        player.restore_clip_size = undefined;

        if(!zm_weapons::is_weapon_upgraded( current_weapon ) || IS_TRUE( b_weapon_supports_aat ))//Your weapon is not upgraded or supports aat
        {
            player PlayLocalSound( "free_packapunch_vox" );
            player SwitchToWeapon( upgrade_weapon );
        }
        else{
            player PlayLocalSound(level.zmb_laugh_alias);//Sam laughs here, So you know it doesnt worked aka 'Your weapon not supports aat and/or is already upgraded like the original start weapon'.
        }
    }
    else {
        player PlayLocalSound(level.zmb_laugh_alias);//Sam laughs here, if you are down and try to pick it up, if you are drinking a perkacola, if you are placeing a mine, if you currently are holding equipment (monkey or mine), and if you are reviving someone.
    }
}