@echo off

if .%1. == .. (
    echo USAGE: %0 [product name]
    goto :EOF
)

set PRODUCT=gobi-%1
set PRODUCT_SOLUTION=%1.sln

set MULTIPROC=/m

for %%A in (%*) do (
    if "%%A"=="-no-m" (
        echo ...disabling multi-processor build
        set MULTIPROC=
    )
)

echo.
echo *** Setup and Build utility for %PRODUCT% ***
echo.

if not exist products\%PRODUCT% (
    echo.
    echo ******* ERROR *******
    echo "products\%PRODUCT%" does not exist.
    echo This utility should be run from the gobiplatform root,
    echo where \gobi-sdk and \products are subdirectories.
    echo.
    goto :EOF
)

echo *******************************
echo Building gobi SDK
echo *******************************

del /f debug\SageAppArchitect.exe.config
pushd gobi-sdk
msbuild %MULTIPROC% gobi-15.sln
popd

echo *******************************
echo Building %PRODUCT%
echo *******************************

pushd products\%PRODUCT%
msbuild %MULTIPROC% %PRODUCT_SOLUTION%
popd

:SetupEnvironment

echo.
echo *******************************
echo Copying sundry binaries, configuration and configuring support files in model
echo *******************************
echo.

pushd gobi-sdk
msbuild /p:ProductName=%PRODUCT% /t:BuildAll EnvironmentSetup.proj
popd

:END
echo *******************************
echo Done
echo *******************************