# Maintainer Pol Marcet Sardà <polmarcetsarda@gmail.com>

pkgname=doomseeker
pkgver=1.3
pkgrel=2
pkgdesc="A cross-platform Doom server browser"
arch=('any')
url="https://doomseeker.drdteam.org/"
license=("LGPL")

depends=('zlib' 'bzip2' 'qt5-tools' 'qt5-base' 'qt5-multimedia')
makedepends=('cmake' 'git')
optdepends=('qt4: A cross-platform application and UI framework'
            'zandronum: GZDoom fork supporting client/server multiplayer'
            'odamex: Classic client/server multiplayer fork'
            'chocolate-doom: Doom source port accurately reproducing the original DOS versions of Doom'
            'srb2: A 3D Sonic fan game based off of Doom Legacy (aka "Sonic Robo Blast 2")')

source=("https://bitbucket.org/Doomseeker/doomseeker/get/${pkgver}.tar.bz2"
        "https://bitbucket.org/Doomseeker/doomseeker-blobs/get/master.tar.bz2")
sha512sums=('cb0e1a6540c2f3be07d545a48171382ad2a9dbd82c2b165d61be9ce58bfc6640932496a2ff75f611f5ef009a214f95b93cb22899072ce445009b054552104064'
            'SKIP')

prepare() {
     find ${srcdir}/ -maxdepth 1 -type d -name "Doomseeker-doomseeker-blobs-*" -print0 -quit | xargs -0 -r0 -I{} mv -f {} ${srcdir}/${pkgname}-blobs
     find ${srcdir}/ -maxdepth 1 -type d -name "Doomseeker-doomseeker-*" -print0 -quit | xargs -0 -r0 -I{} mv -f {} ${srcdir}/${pkgname}
}


build() {
    cd "${srcdir}/${pkgname}-blobs"
    python3 geolite2_conv.py geo/GeoLite2-Country-Blocks-IPv4.csv geo/GeoLite2-Country-Locations-en.csv "$srcdir/$pkgname/src/core/IpToCountry.dat"
    cd "${srcdir}/${pkgname}"
    mkdir -p build
    cd build
    cmake   -DCMAKE_BUILD_TYPE=Release                              \
            -DCMAKE_INSTALL_PREFIX=/usr                             \
            -DDOOMSEEKER_IP2C_DAT:FILEPATH="IpToCountry.dat"        \
            ..
    make
}

package() {
    cd "${srcdir}/${pkgname}/build/"
    make DESTDIR=${pkgdir} install
}