Macro Colher Fungo 1.8

$${
IF(@running);
    LOG("&4[Craftlandia] Finalizando a macro...");
    KEYUP(FORWARD);
	KEYUP(BACK);
    UNSET(@running);
    UNSET(@colheitaretomar);
    STOP();
ELSE;
    LOG("&2[Craftlandia] Iniciando o macro...");
    LOG("&2[Craftlandia] Passe as informações necessárias");
	LOG("&2para seu funcionamento!");
    SET(@running);
ENDIF;

    IF(@colheitaretomar);
        UNSET(@colheitaretomar);
    ELSE;
            IF(backup);
                DO;
                    PROMPT(#backup,$$?,"[Macro] Deseja continuar a última configuração? Sim[1] Não[2]");
                WHILE((%#backup%<1)||(%#backup%>2));
                IF(%#backup%=1);
                    UNSET(register);
                ELSE;
					UNSET(backup);
                    SET(register);
                ENDIF;
            ELSE;
                SET(register);
            ENDIF;
    ENDIF;

    IF(register);
        DO;
            PROMPT(#slot,$$?,"[Macro] Digite em qual slot do HotBar está o item a ser utilizado na colheita (1-9) :");
        WHILE((%#slot%<1)||(%#slot%>9));
        DO;
            PROMPT(#coluna,$$?,"[Macro] De quantas em quantas colunas você deseja guardar os fungos? :");
                IF(%#coluna%=0);
                    #coluna=1;
                ENDIF;
        WHILE(%#coluna%<0);
        DO;
            PROMPT(#repetir,$$?,"[Macro] Você deseja repetir quando terminar de colher, até que desative a macro? Sim[1] Não[2] :");
        WHILE((%#repetir%<1)|(%#repetir%>2));
        DO;
            PROMPT(#storeys,$$?,"[Macro] Digite o numero de andares que sua plantação tem :");
                IF(%#storeys%=0);
                    #storeys = 1;
                ENDIF;
        WHILE((%#storeys%<0));

        PROMPT(&name,$$?,"[Macro] Digite o nome da /home dos andares :");

        SET(backup);
    ENDIF;

    CLEARCHAT();
    LOG(" ");
    LOG("&9&l[&f&oM&facro&9&l] &aConfiguração:");
    LOG(" ");
    IF(%#repetir%=2);
        LOG("&9&l[&f&oM&facro&9&l] &f&oRepetir colheita: &cNão");
    ELSE;
        LOG("&9&l[&f&oM&facro&9&l] &f&oRepetir colheita: &aSim");
    ENDIF;
    IF(%#coluna%>1);
        LOG("&9&l[&f&oM&facro&9&l] &f&oGuardar fungos no baú a cada: &a%#coluna% colunas");
    ELSE;
        LOG("&9&l[&f&oM&facro&9&l] &f&oGuardar fungos no baú a cada: &a%#coluna% coluna");
    ENDIF;
    LOG("&9&l[&f&oM&facro&9&l] &f&oAndares: &a%#storeys%");
    LOG(" ");
    WAIT(1);

    KEY(CHAT);WAIT(1);
    TYPE(/home %&name%1);WAIT(1);
    PRESS(RETURN);
    WAIT(8);

    &dire=%DIRECTION%;
    IFMATCHES(%&dire%,N);&dire=NORTH;ENDIF;
    IFMATCHES(%&dire%,S);&dire=SOUTH;ENDIF;
    IFMATCHES(%&dire%,E);&dire=EAST;ENDIF;
    IFMATCHES(%&dire%,W);&dire=WEST;ENDIF;
    #storey=1;#coluna_atual=1;&fungo="nether_wart|soul_sand";

    SET(@colheitaretomar);

    DO;
        SLOT(%#slot%);WAIT(100ms);
        LOOK(%&dire%);WAIT(100ms);
        LOOK(,90);WAIT(100ms);
		IFMATCHES(%HITID%,%&fungo%);
			IF(%HIT_AGE%=3);
				KEY(ATTACK);WAIT(100ms);
			ENDIF;
		ENDIF;
		LOOK(,65);
        WAIT(100ms);
            DO;
				LOOK(,65);
                    IFMATCHES(%HITID%,%&fungo%);
                        KEYDOWN(FORWARD);
							IF(%HIT_AGE%=3);
								KEY(ATTACK);WAIT(50ms);
							ENDIF;
                    ELSE;
                        KEYUP(FORWARD);
                        BREAK;
                    ENDIF;
            LOOP;
		LOOK(%&dire%);
        LOOK(+180,);WAIT(100ms);
        LOOK(,90);WAIT(100ms);
        PICK(nether_wart);WAIT(100ms);
            DO(3);
                KEY(USE);
            LOOP;
        WAIT(100ms);
        LOOK(,65);
        WAIT(100ms);
            DO;
				LOOK(,65);
                PICK(nether_wart);
                    IFMATCHES(%HITID%,%&fungo%);
                        KEYDOWN(FORWARD);
                        KEY(USE);
                        WAIT(50ms);
                    ELSE;
                        KEYUP(FORWARD);
                        BREAK;
                    ENDIF;
            LOOP;
            IF(%#coluna%=%#coluna_atual%);
                #coluna_atual=1;
                KEY(USE);
                WAIT(1);
                    FOR(#i,54,88);
                        GETSLOTITEM(%#i%,&id,#stack);
                            IFMATCHES(%&id%,nether_wart);
                                SLOTCLICK(%#i%,l,true);
                                WAIT(50ms);
                            ENDIF;
                    NEXT;
                GUI();
                WAIT(1);
            ELSE;
                INC(#coluna_atual,1);
            ENDIF;
        WAIT(500ms);
            IFMATCHES(%GUI%,GUICHEST);
                GUI();
            ENDIF;
        LOOK(-90,48);
        WAIT(100ms);
            IFMATCHES(%HITID%,%&fungo%);
                WAIT(100ms);
                LOOK(-180,45);

                #posx=%XPOS%;
                #posz=%ZPOS%;
                KEYUP(SPRINT);
                    DO;
                        KEYDOWN(BACK);
                        WAIT(10ms);
                        KEYUP(BACK);
                    UNTIL((%XPOS%=%#posx%+1)|(%XPOS%=%#posx%-1)|(%ZPOS%=%#posz%+1)|(%ZPOS%=%#posz%- 1));
				KEYDOWN(SNEAK);
                KEYDOWN(BACK);
                WAIT(230ms);
                KEYUP(BACK);
				KEYUP(SNEAK);
                WAIT(500ms);
            ELSE;
                #coluna_atual=1;
                WAIT(100ms);
                    IF(%#storeys%>1);
                        WAIT(100ms);
                            IF(%#storey%=%#storeys%);
                                KEY(CHAT);WAIT(1);
                                TYPE(/home %&name%1);WAIT(1);
                                PRESS(RETURN);
                                WAIT(8);
                                    IF(%#repetir%=2);
                                        UNSET(@running);
                                        UNSET(@colheitaretomar);
                                        STOP();
                                    ELSE;
                                        #storey = 1;
                                    ENDIF;
                            ELSE;
                                INC(#storey,1);
                                KEY(CHAT);WAIT(1);
                                TYPE(/home %&name%%#storey%);WAIT(1);
                                PRESS(RETURN);
                                WAIT(8);
                            ENDIF;
                    ELSE;
                        KEY(CHAT);WAIT(1);
                        TYPE(/home %&name%1);WAIT(1);
                        PRESS(RETURN);
                        WAIT(8);
                            IF(%#repetir%=2);
                                UNSET(@running);
                                UNSET(@colheitaretomar);
                                STOP();
                            ENDIF;
                    ENDIF;
            ENDIF;
    LOOP;
}$$