LSL Access Menu Script

list menu = ["Red", "Blue", "Green"];
list access_menu = ["OWNER", "GROUP", "ALL", "*BACK"];
string access_type = "OWNER";

integer listener_channel = -938424;
integer listener_handler;
default
{
       state_entry()
       {

       }
       touch_start(integer total_number)
       {
              key toucher = llDetectedKey(0);

              if(toucher == llGetOwner())
              {
                     listener_handler = llListen(listener_channel, "", toucher, "");
                     llDialog(toucher, "Select a Color", menu + ["ACCESS"], listener_channel);
              }else if(access_type == "GROUP" && llSameGroup(toucher))
              {
                     listener_handler = llListen(listener_channel, "", toucher, "");
                     llDialog(toucher, "Select a Color", menu, listener_channel);

              }else if(access_type == "ALL")
              {
                     listener_handler = llListen(listener_channel, "", toucher, "");
                     llDialog(toucher, "Select a Color", menu, listener_channel);
              }
       }

       listen(integer channel, string name, key id, string message)
       {
              llListenRemove(listener_handler);
              if(message == "Red")
              {
                     llSetColor(<1,0,0>, ALL_SIDES);
              }else if(message == "Blue")
              {
                     llSetColor(<0,0,1>, ALL_SIDES);
              }else if(message == "Green")
              {
                     llSetColor(<0,1,0>, ALL_SIDES);
              }else if(message == "ACCESS" && id == llGetOwner())
              {
                     listener_handler = llListen(listener_channel, "", id, "");
                     llDialog(id, "Select an Access Type", access_menu, listener_channel);
              }else if(message == "*BACK" && id == llGetOwner())
              {
                     listener_handler = llListen(listener_channel, "", id, "");
                     llDialog(id, "Select a Color", menu + ["ACCESS"], listener_channel);
              }else if(id == llGetOwner())
              {
                     access_type = message;
                     llOwnerSay("Access Type has changed to: " + access_type);
              }
       }
}