ffmpeg-convert-movies-to-hevc-10bit-using-geforce-cuda.bat

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
COLOR 0A
TITLE CONVERT MKV AND MP4 TO MKV H265 USING FFMPEG AND GEFORCE CUDA

:-----------------------------------------------------------------------------

REM By: SlyFox1186
REM Pastebin: https://pastebin.com/u/slyfox1186

REM THIS SCRIPT WILL CONVERT MKV AND/OR MP4 FILES INTO MKV
REM H265 (HEVC) USING GEFORCE'S HARDWARE ACCELERATION (CUDA).

REM THIS HAS TO BE USED WITH CARDS SUPPORTING TURING TECHNOLOGY.

REM PLACE THIS SCRIPT IN THE SAME FOLDER AS THE FILES. THE CONVERTED
REM FILES WILL BE FOUND IN THE SAME FOLDER AND HAVE (x265) INCLUDED
REM IN THE OUTPUT NAME.

:-----------------------------------------------------------------------------

PUSHD "%~dp0"
IF NOT "%1"=="MAX" START /MAX CMD /D /C %0 MAX & GOTO :EOF

:-----------------------------------------------------------------------------

REM YOU MUST REPLACE THIS WITH THE FULL PATH TO FFMPEG.EXE
SET FF=FULL\PATH\TO\ffmpeg.exe

:-----------------------------------------------------------------------------

REM DELETE LEFTOVER FILES FROM PREVIOUS RUNS
FOR %%G IN (*.mkv) DO IF EXIST "%%~dpnG (x265).mkv" DEL /Q "%%~dpnG (x265).mkv"
FOR %%G IN (*.mp4) DO IF EXIST "%%~dpnG (x265).mp4" DEL /Q "%%~dpnG (x265).mp4"

:-----------------------------------------------------------------------------

REM CONVERT USING FFMPEG.EXE AND GEFORCE CUDA
FOR %%G IN (*.mkv, *.mp4) DO (
    "%FF%" ^
    -y ^
    -hide_banner ^
    -stats ^
    -vsync vfr ^
    -threads 0 ^
    -hwaccel_output_format cuda ^
    -i "%%G" ^
    -movflags +faststart ^
    -c:v hevc_nvenc ^
    -preset:v p7 ^
    -tune:v hq ^
    -pix_fmt:v p010le ^
    -profile:v main ^
    -rc:v vbr ^
    -cq:v 21 ^
    -bf:v 3 ^
    -b_ref_mode:v middle ^
    -g:v 250 ^
    -qmin:v 0 ^
    -qmax:v 99 ^
    -temporal-aq:v 1 ^
    -rc-lookahead:v 32 ^
    -i_qfactor:v 0.75 ^
    -b_qfactor:v 1.1 ^
    -c:a copy ^
    "%%~dpnG (x265).mkv"
)

:-----------------------------------------------------------------------------

ECHO=
PAUSE