Server Autoinstaller

@echo off
setlocal enableextensions

:: Set the the installation folders.
set scmdpath=C:\steamcmd
set filepath=C:\dayzserver
set batchname=dayz_ds
set /p username="SteamUserID: "

:::: End of Settings ::::

goto start

:restart
start "" "%~f0"
exit

:start
mode 45,10
<NUL title Main Menu
for /F "tokens=1,2 delims=#" %%x in ('"prompt #$H#$E# & echo on & for %%w in (1) do     rem"') do (
  set "DEL=%%x"
)
cls
@echo 1.Install or Update SteamCMD
@echo.
@echo 2.Install or Update Server
@echo.
@echo 3.Create Server Launcher Batch File
choice /C 123
if errorlevel 3 goto batchsetup
if errorlevel 2 goto stablerelease
if errorlevel 1 goto downloadsteamcmd

:downloadsteamcmd
mode 120,30
<NUL title Installing SteamCMD...
md "%scmdpath%"
curl -SL -A "Mozilla/5.0" http://steamcdn-a.akamaihd.net/client/installer/steamcmd.zip --ssl-reqd --output "%scmdpath%"\SteamCMD.zip

cd /d "%scmdpath%"
powershell -command "Expand-Archive -Force SteamCMD.zip ./"
"%scmdpath%"\steamcmd.exe +login %username% +force_install_dir "%filepath%" +app_update 223350 +quit
<NUL title SteamCMD Installed!
del SteamCMD.zip
timeout 3
goto restart

:stablerelease
mode 120,30
<NUL title Updating DayZ Server.
"%scmdpath%"\steamcmd.exe +login %username% +force_install_dir "%filepath%" +app_update 223350 validate +quit
<NUL title Rust Server Updated!
timeout 3
goto restart

:batchsetup
REM Creating Start File
(
	echo @echo off
	echo :start
	echo DayZServer_x64.exe -batchmode ^^
	echo -config=serverDZ.cfg ^^
	echo -port=2302 ^^
	echo --dologs ^^
	echo -adminlog ^^
	echo -netlog ^^
	echo -freezecheck ^^
	echo -profiles=.\DayZServerprofiles
	echo goto start
)>DayZServer.bat

:: DayZ Server Butler by Judess69er ::