MHW save backtup tool

@echo off
:: CHANGE THESE AS NEEDED

::Location of the saves (replace XXXXX with your user ID)
set PATH=C:\Program Files (x86)\Steam\userdata\XXXXX\582010
::Location to save the file to. (replace XXXXX with your user ID)
set BACKUPPATH=C:\Program Files (x86)\Steam\userdata\XXXXXX
::Location of 7zip cmd version (can be obtained from https://www.7-zip.org/a/7z1805-extra.7z)
set SZIPPATH=C:\7z_console
::Log path
set LOGPATH=%BACKUPPATH%
::FLAG to check only if save file changed, set to 0 if want to backup no matter what
::THIS ONLY WORKS ON WINDOWS 10 due to formatting! TURN OFF OTHERWISE BY SETTING TO 0
set /a CHK=1

::DO NOT CHANGE ANYTHING UNDERNEATH UNLESS YOU KNOW WHAT YOU ARE DOING
if exist "%SZIPPATH%" goto CHECKPATH
color 0C
echo ERROR!
echo Cannot find 7-zip
echo Download the cmd version from https://www.7-zip.org/download.html
echo and place it in the path listed above.
pause
goto END

:CHECKPATH
if exist "%PATH%" goto RUN
echo ERROR!
echo Cannot find %PATH%
pause
goto END

:RUN
if not exist "%BACKUPPATH%\MHW_last_cksum.txt" goto BACKUP
if %CHK% == 0 goto BACKUP

"%SystemRoot%\system32\CertUtil" -hashfile "%PATH%\remote\SAVEDATA1000" MD5 > "%BACKUPPATH%\MHW_curr_cksum.txt"

for /f "tokens=1*delims=:" %%G in ('%SystemRoot%\system32\findstr /n "^" "%BACKUPPATH%\MHW_last_cksum.txt"') do if %%G equ 2 (
    echo Previous: %%H
    set PREV=%%H)

for /f "tokens=1*delims=:" %%G in ('%SystemRoot%\system32\findstr /n "^" "%BACKUPPATH%\MHW_curr_cksum.txt"') do if %%G equ 2 (
    echo Current:  %%H
    set CURR=%%H)


if "%PREV%" == "%CURR%" (
    echo Checksums match. No new backup needed.
    echo %date% %time% - Backup requested, file same as last time. Not backing up. >> "%LOGPATH%\MHW_saves_log.txt"
    echo If you would like to backup either way, please set CHK=0 in the file. >> "%LOGPATH%\MHW_saves_log.txt"
    goto END
)

:BACKUP
if %CHK% == 1 "%SystemRoot%\system32\CertUtil" -hashfile "%PATH%\remote\SAVEDATA1000" MD5 > "%BACKUPPATH%\MHW_last_cksum.txt"

set FILENAME=MHW_Save_%date:~4,2%-%date:~7,2%-%date:~10,4%_%time:~0,2%-%time:~3,2%-%time:~6,2%
%SZIPPATH%\7za.exe a -y "%BACKUPPATH%\%FILENAME%" "%PATH%"
if exist "%BACKUPPATH%\%FILENAME%.7z" echo Saved %FILENAME% >> "%LOGPATH%\MHW_saves_log.txt"

:END