renpy shaking tits emotions blinking eyes

# как создать спрайты с трясущейся грудью, с разными эмоциями, при необходимости моргающие
init -3:
    image pixel = Null(1, 1)
    # список героев, если есть грудь, то ее координаты относительно левого верхнего угла спрайта
    $ tits = [("laylastrip", (305, 263)), ("hitry", (280, 600)), ("tasha", (280, 555)), ("ani",(255, 466)), "hanny", "tarisa", "layla", "eureka", "rian", "bron", "guardian", "kiron", "erion", "bertraed", "tryber", "oper", "remdark"]
    # список эмоций (если нужных спрайтов не будет, то они не будут создаваться)
    $ emos = ["angry", "evil", "happy", "ok", "sad", "smile", "wat", "shame"]
    # реалистичная анимация сиськотряса
    transform boobs(name, boob_t = 2.0):
        yanchor 0.0 yzoom 1.0
        easeout (boob_t * .075) yzoom 1.05
        easein  (boob_t * .1) yzoom 0.95
        easeout (boob_t * .125) yzoom 1.025
        easein  (boob_t * .125) yzoom 0.975
        easeout (boob_t * .125) yzoom 1.01
        easein  (boob_t * .15) yzoom 0.990
        easeout (boob_t * .15) yzoom 1.005
        easein  (boob_t * .15) yzoom 1.0
init 1999 python:
    # автоматическое объявление персонажей
    # с дополнительными «верхними половинками»,
    # моргающие, с трясущимися сиськами (если это дамы)
    # то есть у нас есть спрайты высотой 1700 (для того чтобы пробежаться взглядом по всему телу)
    # мы прикручиваем к ним моргающие головы с эмоциями и однократно трясущейся грудью
    # а еще обрезаем результат до высоты экрана (1080) - получаются обычные спрайты
    for i in tits:
        char_name = get_tname(i) # имя перса из списка
        xy = get_tpos(i) # координаты сисек
        w, h = (800, 1700) # стандартные размеры для всех спрайтов
        tits_name = char_name + " tits" # сиськи имяперсонажа_tits.png
        if xy[0] < 1 and xy[1] < 1: # если это мужик,
            tits_name = "pixel" # то пусть трясет невидимыми сиськами
        # перебираем все возможные эмоции
        for emo in emos:
            nemo = char_name + " " + emo # прикручиваем очередную эмоцию
            img_head = nemo + " head" # картинка головы с открытыми глазами (во всю ширину спрайта!)
            img_blink = nemo + " blink" # голова с закрытыми глазами
            # если одна из голов пустая, заменяем на другую
            if not has_img(img_head):
                img_head = "pixel"
            if not has_img(img_blink):
                img_blink = "pixel"
            if img_blink == "pixel":
                img_blink = img_head
            if img_head == "pixel":
                img_head = img_blink
            if img_blink == "pixel":
                img_blink = img_head
            # если есть головы с нужной эмоцией, то создаем спрайты с ними
            if img_head != "pixel" or img_blink != "pixel":
                img_full = LiveComposite((w, h),
                    (0, 0), char_name + ' temp',
                    (0, 0), Animation(img_head, rnd(3, 5) + rnd(0, 10) * .1, img_blink, .1),
                    xy, At(tits_name, boobs(char_name)),
                    yanchor=1.0, align=(.5, 1.0)
                )
                renpy.image(nemo + " full", img_full) # создаем спрайт с анимацией в полный рост
                renpy.image(nemo, LiveCrop((0, 0, w, h - 620), img_full)) # обрезаем ноги
            # если нет голов с эмоциями, то просто обрезаем спрайт, без анимации
            if img_head == "pixel" and img_blink == "pixel" and emo == "ok":
                renpy.image(char_name + " ok", LiveCrop((0, 0, w, h - 620), LiveComposite((w, h), (0, 0), char_name + ' temp')))