caffeine-ng

# Maintainer: Hugo Osvaldo Barrera <hugo@barrera.io>

pkgname=caffeine-ng
pkgver=3.5.0+2+gac736cd
pkgrel=1
pkgdesc="Status bar application able to temporarily inhibit the screensaver and sleep mode."
arch=(any)
url="https://github.com/caffeine-ng/caffeine-ng"
license=(GPL3)
depends=(python-gobject python-xdg python-dbus python-docopt python-ewmh gtk3
         libnotify python-setproctitle python-setuptools python-wheel python-pulsectl)
optdepends=("libappindicator-gtk3: AppIndictor support (eg: Plasma, Unity).")
makedepends=(git python-setuptools-scm)
conflicts=(caffeine caffeine-bzr caffeine-oneclick caffeine-systray)
provides=(caffeine caffeine-bzr caffeine-oneclick caffeine-systray)
replaces=(caffeine-oneclick caffeine-systray)
_commit=ac736cd961ff3d484c1b0fcacf0113673cc2709d
source=("git+https://github.com/caffeine-ng/caffeine-ng.git#commit=$_commit")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir"/caffeine-ng
  git describe --tags | sed 's/^v//;s/-/+/g'
}

build() {
  cd "$srcdir"/caffeine-ng
  python setup.py build
}

package() {
  cd "$srcdir"/caffeine-ng
  export PYTHONHASHSEED=0
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
}