;Created bY odzi:) - Ciecie zwłok i zbieranie z niego piór, skóry, zeber
;Skrypt kroi nam zwłoki do 0, a nastepnie zbiera przedmioty.
set %ji #jindex
set #sysmsgcol 80
event sysmessage Skrypt Ciecie Zwierzat + Zbieranie Skory itp odpalony [Created bY odzi:)]
repeat
{
      if #CLILOGGED = 0
      {
         repeat
         until #CLILOGGED = 1
         wait 2s
      }
      onhotkey 5
               gosub start
      if %ji < #jindex
      {
         set %ji %ji + 1
         scanjournal %ji
         if Zapisywanie_ in #journal
            gosub zapis
      }
}
until #false

sub zapis
    repeat
    {
          if %ji < #jindex
          {
             set %ji %ji + 1
             scanjournal %ji
             if Koniec_ in #journal
                return
          }
    }
    until #false
return

sub start
    repeat
    {
          finditem YFM G_1
                   if #findkind = -1
                   {
                      gosub zbieraj
                      return
                   }
                   set %cialo #findid
          finditem KAG C_ , #backpackid
                   if #findkind = -1
                   {
                      set #sysmsgcol 45
                      event sysmessage Nie masz nozyczek! Skrypt wraca do poczatku
                      return
                   }
                   set #lobjectid #findid
                   event macro 17
                   set %czas #scnt + 2
                   repeat
                   {
                         if %czas < #scnt
                            return
                         if %ji < #jindex
                         {
                            set %ji %ji + 1
                            scanjournal %ji
                            if Juz_cos in #journal || Anulowano in #journal
                               return
                         }
                   }
                   until #targcurs = 1
                   set #ltargetid %cialo
                   set #ltargetkind 1
                   event macro 22
                   if #targcurs = 1
                      continue
                   gosub skanuj
                   wait 5
          finditem YFM G_1
    }
    until #findkind = -1
    gosub zbieraj
return

sub skanuj
    set %czas #scnt + 5
    repeat
    {
          if %ji < #jindex
          {
             set %ji %ji + 1
             scanjournal %ji
             if Zapisywanie_stanu_ in #journal
                gosub zapis
             if Wiecej_nie_wytniesz_z_ in #journal
                return
             if Polozyles_przedmioty_na_ in #journal
                return
             if Nie_widzisz_ in #journal
                return
             if Juz_cos_ in #journal
                return
             if Anulowano in #journal || Udalo_Ci_sie in #journal
                return
          }
    }
    until %czas < #scnt
return

sub zbieraj
    repeat
    {
          finditem EEG_VLK_UZF_DUF_POF_TZF_RZF_VVD_CLL_BLL_BZH_EUF_KBN_REJ G_2
                   if #findkind = -1
                   {
                      set #sysmsgcol 55
                      event sysmessage Pozbierane
                      return
                   }
                   set %item #findid
                   set %stack #findstack
                   event property %item
                   if #findtype = EEG && #findcol = 1109 || #findtype = EEG && #findcol = 1153 || #findtype = EEG && #findcol = 1154
                   {
                      ignoreitem %item
                      continue
                   }
                   exevent drag %item %stack
                   if %ji < #jindex
                   {
                      set %ji %ji + 1
                      scanjournal %ji
                      if Holding_ in #journal
                      {
                         set #sysmsgcol 55
                         event sysmessage Holding skrypt wraca do poczatku.
                         return
                      }
                   }
                   exevent dropc #backpackid
                   gosub sprawdz
                   set #sysmsgcol 72
                   str Len #Property
                   set %dlugosc #strres - 1
                   str Left #property %dlugosc
                   event sysmessage Zebralem #strres
    }
    until #false
return

sub sprawdz
if #LLIFTEDKIND = 1
   event dropc #backpackid
return