shuffle machine v1.2

#UseHook

; ============================================
; the shuffle machine v1.2
; 2016-07-02 21:25, ed @ irc.rizon.net
; copyleft and protected by stallman's beard
;
; lets you go like
; https://www.youtube.com/watch?v=mfSIcx1YgVE
;
; divided into three sections:
; <> toggle left mouse button,
;    enable/disable this with F1
; <> flipflop the A and D keys
; <> flipflop the W and S keys
;
; delete the sections you don't want
;
; don't come crying if this gets you banned,
; i have no idea what different games think
; about messing with the kb/mouse like this
; ============================================



; ============================================
; below this line: Left mouse toggle
; ============================================

mx := false
me := false

; make left mouse button toggle
$LButton::
    if (me = false)
    {
        ; toggle feature has not been
        ; enabled using the F1 hotkey
        Send {LButton Down}
        return
    }
    if (mx = false)
        Send {LButton Down}
    else
        Send {LButton Up}
    mx := !mx
    return

$LButton Up::
    if (me = false)
        ; toggle disabled,
        ; behave like regular LButton
        Send {LButton Up}
    return

; toggle the toggle feature
; https://autohotkey.com/docs/KeyList.htm
$F1::
    me := !me
    return

; ============================================
; above this line: Left mouse toggle
; ============================================



; ============================================
; below this line: keys A and D
; ============================================

ax := false
dx := false

$a::
    ; A was pressed, forward this to windows
    Send {a Down}
    ax := true

    if (dx = true)
    {
        ; D is also pressed, release D
        Send {d Up}
    }
    return

$a Up::
    ; A was released, forward this to windows
    Send {a Up}
    ax := false

    if (dx = true)
    {
        ; D was held down when A was pressed,
        ; simulate D being pressed
        Send {d Up}
        Send {d Down}
    }
    return

$d::
    ; same as above except swap D and A
    Send {d Down}
    dx := true
    if (ax = true)
    {
        Send {a Up}
    }
    return

$d Up::
    Send {d Up}
    dx := false
    if (ax = true)
    {
        Send {a Up}
        Send {a Down}
    }
    return

; ============================================
; above this line: keys A and D
; ============================================



; ============================================
; below this line: keys W and S
; ============================================

wx := false
sx := false

$w::
    ; same as above except
    ; ...you get the drift
    Send {w Down}
    wx := true
    if (sx = true)
    {
        Send {s Up}
    }
    return

$w Up::
    Send {w Up}
    wx := false
    if (sx = true)
    {
        Send {s Up}
        Send {s Down}
    }
    return

$s::
    Send {s Down}
    sx := true
    if (wx = true)
    {
        Send {w Up}
    }
    return

$s Up::
    Send {s Up}
    sx := false
    if (wx = true)
    {
        Send {w Up}
        Send {w Down}
    }
    return

; ============================================
; above this line: keys W and S
; ============================================