Ruletka 0.2

on *:text:!ruletka*:#:{
  if (!$2) || ($2 !isnum 1-20) || (!$3) || ($3 !isnum 1-10) {
    msg # Składnia: !ruletka <ilość graczy> <ilość komór>
  }
  else {
    if (!%ruletka) {
      set %delim 44
      set %ruletka 1
      set %kanal $chan
      set %gracze $addtok(%gracze,$nick,%delim)
      set %ilosc.reg $calc($2 - 1)
      set %komory $iif($3 < $2,$2,$3)
      msg %kanal $nick chce grać w ruletkę! Jeżeli ty też chcesz, pisz !join.
    }
  }
}

on *:text:!join:#:{
  if (%ruletka == 1) {
    if ($istok(%gracze,$nick,%delim)) {
      notice $nick Nie możesz dołączyć dwa razy.
    }
    else {
      set %gracze $addtok(%gracze,$nick,%delim)
      dec %ilosc.reg
      msg %kanal $nick też jest w grze. Pozostało %ilosc.reg rejestracji.
      if (%ilosc.reg == 0) {
        set %ruletka 2
        set %nr $r(1,$numtok(%gracze,%delim))
        set %gracz $gettok(%gracze,%nr,%delim)
        set %liczba.graczy $numtok(%gracze,%delim)
        msg %kanal KONIEC REJESTRACJI
        unset %ilosc.reg
        .timer 1 2 msg %kanal Pierwszym graczem jest: %gracz
      }
    }
  }
}
on *:text:!strzal:#:{
  if (%ruletka == 2) {
    if ($nick == %gracz) {
      if (%liczba.graczy == %nr || %liczba.graczy < %nr) {
        set %nr 1
      }
      else {
        inc %nr
      }
      var %strzal $r(1,%komory)
      var %bum 2
      msg %kanal $nick podnosi pistolet, modli się, i pociąga za spust...
      if (%strzal == %bum) {
        set %wynik. [ $+ [ %liczba.graczy ] ] %gracz
        set %gracz $gettok(%gracze,%nr,%delim)
        .timer 1 3 kick %kanal $nick KABOOM!
        set %gracze $remtok(%gracze,$nick,1,%delim)
        set %liczba.graczy $numtok(%gracze,%delim)
        if (%liczba.graczy == 1) {
          .timer 1 3 msg %kanal $nick niestety nie miał farta...
          .timer 1 4 msg %kanal KONIEC GRY, ZWYCIĘZCĄ JEST: %gracze $+ !!!
          set %wynik.1 %gracze
          .timer 1 5 .signal wyniki %kanal
          unset %ruletka %kanal %gracze %komory %nr %gracz %liczba.graczy %delim
        }
        else {
          .timer 1 4 msg %kanal $nick niestety nie miał farta... Następny w kolejce: %gracz
        }
      }
      else {
        set %gracz $gettok(%gracze,%nr,%delim)
        .timer 1 3 msg %kanal (*klik*) $nick ma farta... tym razem. Następny w kolejce jest: %gracz
      }
    }
  }
}

on *:SIGNAL:wyniki:{
  msg $1 TABELA:
  .timer 1 1 msg $1 1. miejsce: %wynik.1
  .timer 1 2 msg $1 2. miejsce: %wynik.2
  if (%wynik.3) { .timer 1 3 msg $1 3. miejsce: %wynik.3 }
  if (%wynik.4) { .timer 1 4 msg $1 4. miejsce: %wynik.4 }
  if (%wynik.5) { .timer 1 5 msg $1 5. miejsce: %wynik.5 }
  unset %wynik.*
}