nchat-git-4.27.g85b407a-1

# Maintainer: Your Name <[email protected]>

pkgname=nchat-git
_pkgbase=${pkgname%-git}
pkgver=4.27.g85b407a
pkgrel=1
pkgdesc='Console-based chat client for Linux and macOS with support for Telegram.'
arch=(x86_64 aarch64 i686 armv7h)
url='https://github.com/d99kris/nchat'
license=(MIT)
depends=(file gcc-libs glibc libpng libxcb ncurses openssl sqlite zlib)
makedepends=(bash git ccache cmake gperf help2man go)
provides=($_pkgbase)
conflicts=($_pkgbase)
source=("git+$url")
md5sums=(SKIP)

pkgver() {
    cd $_pkgbase
    printf '%s.g%s' $(grep NCHAT_VERSION lib/common/src/version.h | cut -f2 -d\") $(git rev-parse --short HEAD)
}

prepare() {
    cd $_pkgbase
    sed -i '/^CMAKEARGS=/c\CMAKEARGS="-DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_INSTALL_MANDIR=/usr/share/man"' make.sh
}

build() {
    cd $_pkgbase
    bash make.sh build
}

package() {
    cd $_pkgbase
    DESTDIR="$pkgdir" cmake --install build --config Release
    install -Dvm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}