//////////////////////////
//////////////////////////
//////////////////////////
///Setup
if not @findobject 'weapon'
  headmsg 'Please target your Weapon'
  promptalias 'weapon' 15000
endif
if not @findobject 'shield'
  headmsg 'Please target your Shield'
  promptalias 'shield' 15000
endif
if not @findobject 'lootbag'
  headmsg 'Please target your Lootbag'
  promptalias 'lootbag' 15000
endif
if not @findobject 'regkey'
  headmsg 'Please target your REAGENT key'
  promptalias 'regkey' 15000
endif
if not @findobject 'ingotkey'
  headmsg 'Please target your INGOT Key
  promptalias 'ingotkey' 15000
endif
if not @findobject 'evokey'
  headmsg 'Please target your EVOkey'
  promptalias 'evokey' 15000
endif
if not @findalias 'portableforge'
  headmsg 'Please target your Portable Forge'
  promptalias 'portableforge' 15000
endif
if not @findalias 'portabank'
  headmsg 'Please target your Bank Crystal'
  promptalias 'portabank' 15000
endif
//////////////////////////////////////
//////////////////////////////////////
//////////////////////////////////////
// Lists
if not @listexists 'regs'
  createlist 'regs'
  pushlist 'regs' 0xf7a  // Black Pearl
  pushlist 'regs' 0xf7b  // Blood Moss
  pushlist 'regs' 0xf86  // Mandrake Root
  pushlist 'regs' 0xf84  // Garlic
  pushlist 'regs' 0xf85  // Ginseng
  pushlist 'regs' 0xf88  // Nightshade
  pushlist 'regs' 0xf8d  // Spider's Silk
  pushlist 'regs' 0xf8c  // Sulphurous Ash
  pushlist 'regs' 0xf8e // Nox Crystal
  pushlist 'regs' 0xf8a // Pig Iron
  pushlist 'regs' 0xf8f // Grave Dust
  pushlist 'regs' 0xf78 // Bat Wing
  pushlist 'regs' 0xf7d // Daemon Blood
  pushlist 'regs' 0xf7e // Bone
  pushlist 'regs' 0xef3 // Blank Scrolls
  pushlist 'regs' 0x4077 // Dragon Blood
  // pushlist 'regs' 12345 //
endif
////////////////////////
if not @listexists 'Jewelry'
  @createlist 'Jewelry'
endif
if list 'Jewelry' == 0
  @pushlist 'Jewelry' 0x108a
  @pushlist 'Jewelry' 0x1f09
  @pushlist 'Jewelry' 0x1086
  @pushlist 'Jewelry' 0x1f06
endif
@removelist 'tailorclips'
if not @listexists 'tailorclips'
  createlist 'tailorclips'
  pushlist 'tailorclips' 0x1079 //hide
  pushlist 'tailorclips' 0x1b0a //bones
  pushlist 'tailorclips' 0x1b0d //bones
  pushlist 'tailorclips' 0x1b0f //bones
  pushlist 'tailorclips' 0x1b0c //bones
  pushlist 'tailorclips' 0x1b17 //bones
  pushlist 'tailorclips' 0x1b0b //bones
  pushlist 'tailorclips' 0x1b0e //bones
  pushlist 'tailorclips' 0x1b10 //bones
  pushlist 'tailorclips' 0x1b09 //bones
endif
///////////////////////////////////////
///////////////////////////////////////
///////////////////////////////////////
//Timers
if not timerexists 'consecratetimer'
  createtimer 'consecratetimer'
  settimer 'consecratetimer' 0
endif
if not timerexists 'discotimer'
  createtimer 'discotimer'
  settimer 'discotimer' 0
endif
if not timerexists 'bandagetimer'
  createtimer 'bandagetimer'
  settimer 'bandagetimer' 0
endif
if not timerexists 'abilitytimer'
  createtimer 'abilitytimer'
  settimer 'abilitytimer' 0
endif
/////////
/////////
/////////
///////// Main Loop
//equip weapon
if not @findobject 'righthand'
  equipitem 'weapon' 2
  pause 500
endif
//equip shield
if not @findobject 'lefthand' and @findobject 'righthand'
  equipitem 'shield' 2
  pause 500
endif
@getenemy 'murderer' 'enemy' 'criminal' 'gray' 'closest'
pause 400
if @findobject 'enemy'
  @clearjournal
  if @inrange 'enemy' 10
    if hits 'enemy' == maxhits 'enemy'
      virtue 'honor'
      waitfortarget 5000
      target! 'enemy' 2000
      pause 1000
      canceltarget
      attack 'enemy'
    endif
    ////////////////////////////////////////
    //use ability
    // comment out the one you wish not to use
    if mana >= 44 and timer 'abilitytimer' > 500
      //primary
      //setability 'primary' 'on'
      //secondary
      setability 'secondary' 'on'
      //
    endif
    ///////////////////////////
    ///////////////////////////
    ///////////////////////////
    /////Disco target
    if not @injournal 'jarring' and not @injournal 'already' and not @injournal 'would have no effect'
      if timer 'discotimer' >= 2050 and @inrange 'enemy' 6
        useskill 'Discordance'
        waitfortarget 1000
        target! 'enemy' 2000
        settimer 'discotimer' 0
        pause 126
        canceltarget
      endif
      canceltarget
    endif
    ////////////////
    ////////////////
    ////////////////
    //// Enemy of one
    if not buffexists 'Enemy of One'
      cast 'Enemy of One'
      pause 250
    endif
    ////////////////
    ////////////////
    ////////////////
    // Divine Fury
    if not buffexists "divine fury"
      cast 'Divine Fury'
      pause 500
      if @injournal 'not yet recovered' 'system' or @injournal 'you are already' 'system'
        replay
      endif
    endif
    /////////////////////
    /////////////////////
    /////////////////////
    ///// Consecrate Weapon
    if timer 'consecratetimer' >= 9000
      if not buffexists "Consecrate Weapon"
        cast "Consecrate Weapon"
        pause 500
        settimer 'consecratetimer' 0
        if @injournal 'not yet recovered' 'system' or @injournal 'you are already' 'system'
          replay
        endif
      endif
    endif
    attack 'enemy'
  endif
endif
////////////////////////////////////////
////////////////////////////////////////
////////////////////////////////////////
/// Healing
if timer 'bandagetimer' >= 10250
  //poisoned
  if poisoned 'self'
    bandageself
    waitfortarget 1500
    target! 'self'
    settimer 'bandagetimer' 0
  elseif diffhits > 8
    bandageself
    waitfortarget 1500
    target! 'self'
    settimer 'bandagetimer' 0
  endif
  pause 200
endif
///////////////////////////////////////////
///////////////////////////////////////////
///////////////////////////////////////////
// smelt ore's
if @usetype! 0x19b9 'any' 'backpack'
  waitfortarget 1500
  @target! 'portableforge'
elseif @usetype! 0x19b8 'any' 'backpack'
  waitfortarget 1500
  @target! 'portableforge'
elseif @usetype! 0x19ba 'any' 'backpack'
  waitfortarget 1500
  @target! 'portableforge'
endif
///////////////////////////////
//clip hides to leather
for 0 to 'tailorclips'
  while @findtype 'tailorclips[]'
    @usetype 0xf9f
    waitfortarget 15000
    @target! 'found'
  endwhile
endfor
///////////////////////////////////////////
///////////////////////////////////////////
///////////////////////////////////////////
// Use Storage Key's
////////////////////////////////
//store ingots
if @findtype 0x1bf2
  waitforcontext 'ingotkey' 2 15000
  waitforgump 0x6abce12 15000
  replygump 0x6abce12 0
endif
/////////////////////////////////////
//store reagents
for 0 to 'regs'
  while @findtype 'regs[]' 'backpack'
    waitforcontext 'regkey' 2 15000
    waitforgump 0x6abce12 15000
    replygump 0x6abce12 0
    pause 200
    break
  endwhile
endfor
/////////////////////////////////////////
////store hides in bank (temp)
if @findtype 0x1081
  @useobject 'portabank'
  pause 300
  organizer 'bank'
endif
////////////////////////////////
////////////////////////////////
////////////////////////////////
///Loot Jewelry
/////////////////////////
//Find Corpse
if @findtype '0x2006' 'any' 'ground' '1' '1'
  @setalias '0' 'found'
  @useobject '0'
  pause 300
  //////////////////////////
  //Locate Jewelry
  for 0 to Jewelry
    for 2
      if @findtype Jewelry[] 0 '0'
        @setalias 'Skills' 'found'
        waitforproperties 'Skills' 3000
        if @property 'Swordsmanship' 'Skills' >= 12
          sysmsg 'Swords!' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Parry' 'Skills' >= 14
          sysmsg 'Parry!' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Tactics' 'Skills' >= 14
          sysmsg 'Tactics' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Animal Taming' 'Skills' >= 14
          sysmsg 'Taming' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Archery' 'Skills' >= 14
          sysmsg 'Archery' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Anatomy' 'Skills' >= 14
          sysmsg 'Anatomy' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Bushido' 'Skills' >= 14
          sysmsg 'Bushido' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Animal Lore' 'Skills' >= 14
          sysmsg 'Animal Lore' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Evaluating Intelligence' 'Skills' >= 14
          sysmsg 'Evaluating Intelligence' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Lower Reagent Cost' 'Skills' >= 17
          sysmsg 'Lower Reagent Cost' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Faster Cast Recovery' 'Skills' >= 2 and @property 'Faster Casting' 'Skills' >=1
          sysmsg 'FCR/FC' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        endif
      endif
    endfor
  endfor
endif
//Close Corpse
ignoreobject '0'
////////////////////////////////
// checks and gold
if @findtype 0xeed 0x0 'backpack'
  useobject 0x42c79fe3
  waitforgump 0x9021dd59 1500
  replygump 0x9021dd59 5 2
  waitfortarget 1500
  targettype! 0xeed 0x0
  pause 100
  canceltarget
  pause 400
  replygump 0x9021dd59 0 2
elseif @findtype 0x14f0 52 'backpack'
  useobject 0x42c79fe3
  waitforgump 0x9021dd59 1500
  replygump 0x9021dd59 5 2
  waitfortarget 1500
  targettype! 0x14f0 52
  pause 100
  canceltarget
  pause 400
endif