bespokesynth-git

pkgname=bespokesynth-git
pkgdesc="Software modular synth with controllers support, scripting and VST"
pkgver=1.0.0.r217.g1b821f3
pkgrel=1
arch=('x86_64')
url="https://www.bespokesynth.com"
license=('GPL3')
depends=('alsa-lib' 'curl' 'freetype2' 'gtk3' 'jack' 'libglvnd' 'libusb' 'python'
         'webkit2gtk' 'zenity')
makedepends=('cmake' 'git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/BespokeSynth/BespokeSynth.git'
        'git+https://github.com/juce-framework/JUCE.git'
        'git+https://github.com/pybind/pybind11.git'
        'git+https://github.com/surge-synthesizer/tuning-library.git'
        'git+https://github.com/ODDSound/MTS-ESP.git'
        'git+https://github.com/open-source-parsers/jsoncpp.git')
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP')

pkgver() {
  cd "$srcdir/BespokeSynth"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/BespokeSynth"

  for submodule in JUCE pybind11 tuning-library; do
    git submodule init "libs/${submodule}"
    git config submodule."${submodule}".url "$srcdir/${submodule}"
  done

  git submodule init libs/oddsound-mts/MTS-ESP
  git config submodule.MTS-ESP.url "$srcdir/MTS-ESP"

  git submodule init libs/json/jsoncpp
  git config submodule.jsoncpp.url "$srcdir/jsoncpp"

  git submodule update
}

build() {
  cmake -B build -S BespokeSynth \
    -DCMAKE_BUILD_TYPE='None' \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -Wno-dev
  cmake --build build --parallel 4
  make -C build
}

package() {
  make -C build DESTDIR="$pkgdir" install
}