mIRC pastebin script

;You have to paste it on remotes

alias -l ht2chr {
  if (#x* iswm $1) return $chr($base($mid($1, 3), 16, 10))
  elseif (#* iswm $1) return $chr($mid($1, 2))
  else return $ht2as($1)
}
alias -l ht2as {
  var %A quot amp lt gt nbsp iexcl cent pound curren yen brvbar sect uml copy ordf $&
    laquo not shy reg macr deg plusmn sup2 sup3 acute micro para middot cedil sup1 $&
    ordm raquo frac14 frac12 frac34 iquest Agrave Aacute Acirc Atilde Auml Aring AElig $&
    Ccedil Egrave Eacute Ecirc Euml Igrave Iacute Icirc Iuml ETH Ntilde Ograve Oacute $&
    Ocirc Otilde Ouml times Oslash Ugrave Uacute Ucirc Uuml Yacute THORN szlig agrave $&
    aacute acirc atilde auml aring aelig ccedil egrave eacute ecirc euml igrave iacute $&
    icirc iuml eth ntilde ograve oacute ocirc otilde ouml divide oslash ugrave uacute $&
    ucirc uuml yacute thorn yuml
  var %B 34 38 60 62 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 $&
    177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 $&
    199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 $&
    221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 $&
    243 244 245 246 247 248 249 250 251 252 253 254 255
  return $chr($gettok(%B, $findtokcs(%A, $1, 32), 32))
}
alias html2ascii { return $regsubex($1-,/&(.{2,6});/Ug, $ht2chr(\t)) }

alias pastebin {
  if ($regex($strip($2-), /^(?:.*?\s)?(?:https?:\/\/)?(?:www\.)?pastebin.com(?:\/(u))?\/(\w+)\/?(?:\s.*)?$/i)) {
    if (!%pastebinTimeout. [ $+ [ $nick ] ]) {
      sockopen pastebin. [ $+ [ $nick ] ] pastebin.com 80
      if ($regml(0) == 2) {
        sockmark pastebin. [ $+ [ $nick ] ] $+($1,:,$regml(2),:,$regml(1))
      }
      else {
        sockmark pastebin. [ $+ [ $nick ] ] $+($1,:,$regml(1))
      }
    }
  }
}

on *:TEXT:*:*: { pastebin $iif($left($target,1) == $chr(35), #, $nick) $1- }
on *:INPUT:*: { pastebin $target $1- }

on *:SOCKOPEN:pastebin.*: {
  var %id = $gettok($sock($sockname).mark,2,58)
  sockwrite -nt $sockname GET / $+ $iif($numtok($sock($sockname).mark,58) == 3,u/ $+ %id,%id) HTTP/1.0
  sockwrite -nt $sockname Host: pastebin.com
  sockwrite $sockname $crlf
}

on *:SOCKREAD:pastebin.*: {
  if (!$sockerr) {
    var %sockreader
    sockread %sockreader

    if ($gettok($sock($sockname).mark,3,58) != u) {
      if ($regex(%sockreader, <div class="content_title">(This paste has been removed!)</div>)) {
        msg $gettok($sock($sockname).mark,1,58) 12 $+ $regml(1)
        sockclose $sockname
      }

      if ($regex(%sockreader, <div class="paste_box_line1" title="(.*)">)) { sockmark $sockname $+($sock($sockname).mark,:,$regml(1)) }

      if ($regex(%sockreader, <div class="paste_box_line2">(.*)<\/div>)) {
        var %data = $regml(1), %title = $gettok($sock($sockname).mark,3,58)

        if ($regex(%data, <a href="\/pro" title="(.*?)">)) { var %proUser = $regml(1) }

        if ($regex(%data, /<a href="\/(?:u|archive)\/.*?">(.*?)<\/a>/g)) {
          if ($regml(0) == 2) { var %by = $+($regml(1),$iif(%proUser, 10[ $+ $v1 $+ ])), %syntax = $regml(2) }
          else { var %by = A GUEST, %syntax = $regml(1) }
        }

        if ($regex(%data, /(?:size|expires):\s\b([a-z0-9. ]+)\b/gi)) { var %size = $regml(1), %expires = $regml(2) }

        if ($regex(%data, /<span .*?>(.*?)<\/span>/g)) {
          var %on = $regml(1), %edited = $iif($regml(0) == 3, $regml(2)), %views = $iif($regml(0) == 3, $regml(3), $regml(2))
          msg $gettok($sock($sockname).mark,1,58) 12Title: 04 $+ $html2ascii(%title) 1 $+ $chr(124) 12By: 04 $+ %by 1 $+ $chr(124) 12On: 04 $+ %on $iif(%edited,10( $+ $v1 $+ ) ) 1 $+ $chr(124) 12Syntax: 04 $+ %syntax 1 $+ $chr(124) 12Size: 04 $+ %size 1 $+ $chr(124) 12Views: 04 $+ %views 1 $+ $chr(124) 12Expires: 04 $+ %expires
          sockclose $sockname
        }
      }
    }
    else {
      if ($regex(%sockreader, (?:<div class="content_title">|Moved Temporarily))) {
        msg $gettok($sock($sockname).mark,1,58) 12The user does not exist!
        sockclose $sockname
      }
      if ($regex(%sockreader, <div class="paste_box_line1">(.*)<\/div>)) {
        var %data = $regml(1)
        if ($regex(%data, <a href="/pro" title="(.*?)">)) {
          var %proUser = $regml(1)
        }
        if ($regex(%data, <h1>(.*)<\/h1>)) {
          var %pastebin = $+($regml(1),$iif(%proUser, 10[ $+ $v1 $+ ]))
        }
        sockmark $sockname $+($sock($sockname).mark,:,%pastebin)
      }

      if ($regex(%sockreader, <div class="paste_box_line2">(.*)<\/div>)) {
        var %data = $regml(1)
        if ($regex(%data, /(?:Total Pastes|Pastebin Hits|Total Pastes Hits):\s\b([a-z0-9., ]+)\b/gi)) {
          sockmark $sockname $+($sock($sockname).mark,:,$regml(1),:,$regml(2),:,$regml(3))
        }
        if ($regex(%data, <span .*>(.*)<\/span>)) {
          sockmark $sockname $+($sock($sockname).mark,:,$regml(1))
        }
      }

      if ($regex(%sockreader, <div class="paste_box_line3">(.*)<\/div>)) {
        var %data = $regml(1)
        if ($regex(%data, <img src=".*" class="i_loc" .*?>\s(.*?)&)) {
          var %location = $regml(1)
        }
        if ($regex(%data, <a href="(.*?)")) {
          var %website = $regml(1)
        }
        var %pastebin = $gettok($sock($sockname).mark,4,58), %totalPastes = $gettok($sock($sockname).mark,5,58), %totalPastesHits = $gettok($sock($sockname).mark,7,58), %totalData = $numtok($sock($sockname).mark, 58)
        var %pastebinHits = $gettok($sock($sockname).mark,$iif(%totalData > 6,6,5),58)
        var %joined = $gettok($sock($sockname).mark,$iif(%totalData > 6,8,6),58)

        msg $gettok($sock($sockname).mark,1,58) 4 $+ %pastebin $iif(%totalData > 6,1 $+ $chr(124) 12Total Pastes: 04 $+ %totalPastes,) 1 $+ $chr(124) 12Pastebin Hits: 04 $+ %pastebinHits $iif(%totalData > 6,1 $+ $chr(124) 12Total Pastes Hits: 04 $+ %totalPastesHits,) 1 $+ $chr(124) 12Joined: 04 $+ %joined ago $iif(%location, 1 $+ $chr(124) 12Location: 04 $+ $v1,) $iif(%website, 1 $+ $chr(124) 12Website: 04 $+ $v1,)
        sockclose $sockname
      }
    }
  }
}