Gunship for C64 BASIC listing - pre-game setup

1 poke 56333,127 : poke 808,234 : poke 792,193
2 poke 52,116 : poke 56,116 : clr : print "[wht]"chr$(8); : of=53265
3 for i=.to 63 : cl$=cl$+chr$(.) : next : goto 691
4 cz=peek(53280) and 15 : cz=-12*(.cz<>12)-11*(cz<>11) : poke 53280,cz : poke 53281,cz
5 return
6 poke 55822,i : poke 55862,i : poke 55902,i : return
7 poke 55942,i : poke 55982,i : return
8 i=. : for j=6to 121 : if (peek(et+j) and 47)=38then h%(i)=j : i=i+1 : gosub 4
9 next : j=h%(int(rnd(0)*i)) : return
10 gosub 11 : print i$; : return
11 i$=left$("000000",sd+1-len(str$(v)))+right$(str$(v),len(str$(v))-1) : return
12 if fu+i>376then i=376-fu
13 if fu+i<.then i=fu
14 j=cw : j=j+6.5*i : if  j>mx then  22
15 fu=fu+i : cw=j : poke  214,14 : print  : poke 211,23
16 sd=4 : v=fu : gosub 10 : z=22-int(fu/16.3) : u=12-int(fu/28.9)
17 if z>.then poke 51080+z,.
18 if z<22then poke 51082+z,255
19 if u>.then poke 51060+u,.
20 if u<12then poke 51062+u,255
21 goto 25
22 poke 214,18 : print "[red]" : poke 211,30
23 v=cw : sd=5 : gosub 10
24 for i=1to 100 : next
25 poke 214,18 : print "[cya]" : poke 211,30
26 v=cw : sd=5 : goto 10
27 j=cw : j=j+i*26 : if j>mxthen  22
28 rn=rn+i : cw=j : i=rn*20 : poke  214,13 : print  : poke 211,23
29 v=i : sd=4 : gosub 10 : print  : goto 25
30 if (i<>.) and (i<>4)then return
31 j=cw-w%(s1)+w%(i) : if j>mxthen  22
32 u=s1 : s1=i : cw=j : poke sp+2,225+s1 : poke sp+7,225+s1 : poke 53289,c%(s1)
33 poke 53294,c%(s1) : gosub 25
34 wp%(u)=wp%(u)-1 : wp%(i)=wp%(i)+1
35 if u>.then j=u : gosub 38
36 if i>.then j=i : gosub 38
37 return
38 z=wp%(j)*wc%(j) : poke 214,12+j : print  : poke 211,37
39 v=z : sd=2 : goto 10
40 j=cw-w%(s2)+w%(i) : if j>mxthen 22
41 u=s2 : s2=i : cw=j : poke sp+3,225+s2 : poke sp+6,225+s2 : poke 53290,c%(s2)
42 poke 53293,c%(s2) : gosub 25 : goto 34
43 j=cw-w%(s3)+w%(i) : if j>mxthen 22
44 u=s3 : s3=i : cw=j : poke sp+4,225+s3 : poke sp+5,225+s3 : poke 53291,c%(s3)
45 poke 53292,c%(s3) : gosub 25 : goto 34
46 j=cw-ch*20+i*20 : if j>mxthen 22
47 cw=j : ch=i
48 i=8 : if ch=1then i=15
49 gosub 6 : goto 54
50 j=cw-fr*20+i*20 : if j>mxthen 22
51 cw=j : fr=i
52 i=8 : if fr=1then i=10
53 gosub 7
54 poke 214,15 : print  : poke 211,23 : i=ch*30
55 v=i : sd=4 : gosub 10 : print  : poke 211,23 : i=fr*30 : v=i : gosub 10 : goto 25
56 i=peek(mb+i*12+1) : j=int((peek(eh+i)+8)/16-1) : gosub 58 : i$=a$+"-"
57 j=int((peek(ey+i)+8)/16-1) : gosub 58 : i$=i$+a$ : return
58 a$=left$("00",3-len(str$(j)))+right$(str$(j),len(str$(j))-1) : return
59 i=peek(mb+(i-1)*12) : if i=1then print "at"; : return
60 print "in the vicinity of"; : return
61 poke 53269,. : open 15,8,15 : open 2,8,2,"#1" : for i=.to 3 : print#15,"u1";2;.;1;i+1
62 print#15,"b-p";2;. : poke a0,. : poke a1,140+i : sys ke+69 : next : close 2 : close 15
63 sys 65484 : goto 69
64 sys ke+66 : for i=.to 3 : poke (140+i)*256,1 : poke (140+i)*256+1,i+2 : next
65 poke 142*256+192,cp : poke 53269,.
66 open 15,8,15 : open 2,8,2,"#1" : for i=.to 3 : print#15,"b-p";2;.
67 poke a0,. : poke a1,140+i : sys ke+72 : print#15,"u2";2;.;1;i+1 : next : close 2 : close 15
68 sys 65484
69 open 15,8,15,"i0 : " : close 15 : return
70 if un=.then i$="[grn]Very Low " : i=. : goto  82
71 i=fl+ln+wt : if i=2then i=1
72 i=i+un+(2-qu)+sf*2-(sf=2)+1
73 on igosub 75,75,75,76,76,77,77,78,78,79,79,80,80,81,81
74 goto 82
75 i$="[grn]Very Low " : return
76 i$="[grn]Low      " : return
77 i$="[blu]Moderate " : return
78 i$="[blu]High     " : return
79 i$="[pur]Very High" : return
80 i$="[pur]Extreme  " : return
81 i$="[red]Ultimate " : return
82 print i$; : return
83 l=20 : f$="" : m=0 : poke 211,x : for i=1to l : print "-"; : next : print "<"; : poke 211,x
84 print "┤[lf]";
85 get ky$ : if ky$=""then 85
86 a$="-" : if m=lthen a$="<"
87 if ky$=chr$(13)then print a$; : return
88 if ky$<>chr$(20)then 91
89 if m=0then 85
90 print "[lf]┤"a$"[lf][lf]"; : m=m-1 : f$=left$(f$,len(f$)-1)
91 if ky$="[clr]"then 83
92 if ky$=" "then if m<lthen print "-┤[lf]"; : goto 98
93 if asc(ky$)>192 and asc(ky$)<219then 96
94 if asc(ky$)<32 or asc(ky$)>95then 85
95 if ky$=chr$(34)then 85
96 if m=lthen 85
97 print ky$"┤[lf]";
98 f$=f$+ky$ : m=m+1 : goto 85
99 print "[blu] ";
100 i=asc(mid$(rs$(p),21,1)) : gosub 311 : print i$;
101 print  "  ";left$(rs$(p),20);
102 poke 211,28 : i=p : gosub  312 : v=sc : gosub 122 : print " pts." : j=p : gosub 110
103 print  "                                      "; : poke 211,3 : print "[red]"dc$
104 return
105 i$=n$+left$(cl$,20-len(n$)) : i$=i$+chr$(r) : v=sc : gosub 125
106 i$=i$+chr$(lo)+chr$(hi) : i$=i$+mid$(rs$(cp),24,17) : i$=i$+chr$(fl)+chr$(ln)
107 i$=i$+chr$(wt)+chr$(qu)+chr$(un)+chr$(sf)
108 print "[clr][wht][dn][dn][dn][dn][dn][dn][dn][dn][dn][dn][dn][dn]            Please Stand By"
109 i$=i$+cl$ : rs$(cp)=left$(i$,64) : return
110 v=asc(mid$(rs$(j),47,1)) : dc$="" : if vthen dc$=mid$("KIAMIA",v*3-2,3)
111 m=0 : for  i=12 to  0 step  -1
112 a=asc(mid$(rs$(j),24+i,1)) : if a=0then  118
113 m=m+1 : i$=mid$(m$,i*5+1,5) : j$=" "
114 for  x=1 to  5 : if mid$(i$,x,1)<>" "then j$=j$+mid$(i$,x,1)
115 next : j$=j$+"[dgrey]" : if a>1then j$=j$+right$(str$(a),len(str$(a))-1)
116 j1$=dc$+j$ : if  len(j1$)-m*2>35 then  i=-1 : goto  118
117 dc$=j1$
118 next : j$="" : j1$="" : return
119 v=f : gosub 125 : poke a0,lo : poke a1,hi : v=t : gosub 125 : poke a2,lo : poke a3,hi
120 v=l : gosub 125 : poke a4,lo : poke a5,hi : sys ke+48 : return
121 f=bf+mp*512+en*256 : l=256 : goto 119
122 i$=str$(v*10) : if left$(i$,1)=" "then print right$(i$,len(i$)-1); : return
123 print i$; : return
124 v=asc(mid$(rs$(cp),i+1,1)) : return
125 if v<0then v=65536+v
126 hi=int(v/256) : lo=v-hi*256 : return
127 gosub 125 : poke db+i*2,lo : poke db+i*2+1,hi : i=i+1 : return
128 rem
129 goto 145 : poke a0,0 : sys ke+60
130 print "[blk][clr]" : poke 214,14 : print
131 qq=int(rnd(0)*20)+1 : f$="i"+right$(str$(qq),len(str$(qq))-1)
132 gosub 681
133 for i=1to 10 : read f$ : poke 211,1 : print "[or]▌▔[blk] "f$; : read f$
134 poke 211,21 : print "[or]▌▔[blk] "f$;
135 if i<>10then  print
136 next
137 poke 214,10 : print  : print "[wht]                                        ";
138 print "[blk] Use joystick to select identification,"
139 print "      then press the fire button : "
140 poke ke+554,15*4 : poke of,0
141 sys ke+12 : sys ke+39
142 ss=1 : gosub 674
143 poke a1,sm : sys ke : op=peek(a0)
144 if op<>(qq-1)then 149
145 poke of,0 : sys ke+12 : gosub 675 : gosub 673
146 cp=asc(mid$(rs$(8),1,1)) : if cp=11then cp=0 : goto 267
147 j=cp : gosub 110 : gosub 299 : i=46 : gosub 124 : if vthen 267
148 goto 185
149 poke of,0 : sys ke+12 : gosub 675
150 print "[clr][red][dn][dn][dn][dn][dn][dn][dn][dn][dn][dn]    INCORRECT VEHICLE IDENTIFICATION[dn][blk]"
151 print "          You are assigned to"
152 print "          Training in the USA"
153 gosub 674 : for i=0to 2500 : next
154 cp=11 : bd=1 : gosub 299 : goto 228
155 poke of,0
156 sys ke+12
157 print "[clr][dn][dn][dn] [blk]SELECT REALITY LEVELS : [dn]"
158 print " [blk]FLYING YOUR HELICOPTER"
159 print "[lgrey]  ▗▗└ Realistic :  "fl$(1);
160 print "  ▗▗└ Easy :  "fl$(0)
161 print "[dn] [blk]LANDING YOUR HELICOPTER"
162 print "[lgrey]  ▗▗└ Realistic :  "ln$(1);
163 print "  ▗▗└ Easy :  "ln$(0)
164 print "[dn] [blk]WEATHER EFFECTS"
165 print "[lgrey]  ▗▗└ Realistic :  "wt$(1);
166 print "  ▗▗└ Easy :  "wt$(0)
167 print "[dn][mgrey]┌┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┴";
168 print "[blk] SELECT ENEMY QUALITY : "
169 print "[lgrey]  ▗▗└ 1st Line"
170 print "  ▗▗└ 2nd Line"
171 print "  ▗▗└ 3rd Line"
172 print "[dn]        [blk]Overall Risk - "; : gosub 70
173 poke a0,1 : sys ke+60 : gosub  670
174 print "[home][dn][dn][mgrey]┌┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┬┴";
175 poke sl+2-fl,1 : poke sl+4-ln,1 : poke sl+6-wt,1
176 poke sl+7+qu,1
177 poke a1,sm : sys ke+21 : ss=63 : gosub 674
178 poke a1,sm : sys ke : op=peek(a0)
179 if op=0then 185
180 if op>0 and op<3then fl=1-(op-1) : goto 184
181 if op>2 and op<5then ln=1-(op-3) : goto 184
182 if op>4 and op<7then wt=1-(op-5) : goto 184
183 qu=op-7
184 poke 214,22 : print  : poke 211,23 : gosub 70 : goto 178
185 if cp=11then 129
186 i=peek(db+124) : if ithen poke db+124,0 : on igoto 228,342,315,267
187 gosub 673
188 print "[clr][blk][dn][dn][dn] CURRENT PILOT" : print "  [blu]"r$" [red]"n$"[blu]";
189 poke 211,28 : v=sc : gosub 122 : print "pts."
190 print "  [red]"dc$
191 print "[dn] [blk]CURRENT DUTY ASSIGNMENT" : print "[dn]       ";
192 gosub 193 : print  : goto  199
193 on un+1goto 194,195,196,197,198
194 i$="038114" : print "[blu]Flight training in the USA"; : return
195 i$="136114" : print "[blu]1st Cavalry in Southeast Asia"; : return
196 i$="240114" : print "[blu]82nd Airborne in Central America"; : return
197 i$="340114" : print "[blu]101st Air Assault in Middle East"; : return
198 i$="435114" : print "[blu]3rd Armored in Western Europe"; : return
199 poke rl,148 : poke rl+1,0 : poke sh,val(left$(i$,1)) : poke sx,val(mid$(i$,2,2))
200 poke sy,val(right$(i$,3))
201 print "        vs ";
202 on qugoto 204,205
203 print "1st"; : goto 206
204 print "2nd"; : goto 206
205 print "3rd";
206 print " Line Enemy"
207 poke  214,11 : print  : print  "[blk] CURRENT STYLE OF FLYING[dn][dn]" : poke 211,9
208 gosub 209 : print  : goto  213
209 on sf+1goto 210,211,212
210 i$="548154" : print "[blu]Regular Missions[blk]"; : return
211 i$="646154" : print "[blu]Volunteer Missions[blk]"; : return
212 i$="746154" : print "[blu]Volunteer Hazardous Duty[blk]"; : return
213 poke sh+1,val(left$(i$,1)) : poke sx+1,val(mid$(i$,2,2))
214 poke sy+1,val(right$(i$,3))
215 print "[dn][dn] [blk]CURRENT REALITY LEVELS"
216 print "   [blu]▎ [blu]"fl$(fl)
217 print "   [blu]▎ [blu]"ln$(ln)
218 print "   [blu]▎ [blu]"wt$(-wt*(un>0))
219 print "[dn]   [blk]Current level of risk is : "; : gosub 70
220 sys ke+18
221 poke a0,2 : sys ke+60
222 print "[home] [blk]Change : "
223 print "[mgrey]▋[rvs]Pilot[rvoff]▋[rvs]Duty[rvoff]▋[rvs]Style[rvoff]▋[rvs]Reality[rvoff]";
224 gosub 670
225 ss=255 : gosub 674
226 poke a1,sm : sys ke : op=peek(a0)
227 on opgoto 267,315,342,155
228 poke 53265,0 : sys ke+12 : poke 53280,11 : poke 53281,11 : gosub 105 : poke 53265,27
229 i$=mid$("tnsecamewe",un*2+1,2) : mp=int(rnd(0)*4) : en=int(rnd(0)*2)
230 if un=0then mp=0 : en=0
231 f$="mission."+i$ : gosub 680 : t=mb : gosub 121
232 ms=200 : gosub 239 : m2=ms : m2$=md$ : gosub 239
233 f$="tiles."+i$ : gosub 680 : t=tb : f=bf+256*mp : l=256 : gosub 119
234 f$="enemies."+i$ : gosub 680 : t=eh : f=bf+1280*mp+640*en : l=640 : gosub 119
235 f$="bitmap."+i$ : gosub 680 : t=bb : gosub 121
236 f$="arm" : gosub 680 : if un=0then i$="we"
237 f$="map.chr."+i$ : gosub 680
238 mp=mp+1 : en=en+1 : goto 243
239 i=int(rnd(0)*13)+1 : if i=msthen 239
240 if peek(mb+(i-1)*12)=0then 239
241 ms=i : goto 603
242 return
243 on ungoto 245,246,247,248
244 tp=76 : goto 250
245 i=36 : a=70 : j=31 : b=60 : goto 249
246 i=31 : a=75 : j=26 : b=65 : goto 249
247 i=36 : a=75 : j=26 : b=55 : goto 249
248 i=41 : a=50 : j=26 : b=40 : goto 249
249 tp=int(rnd(1)*i)+a : if dy$="night" then  tp=int(rnd(1)*j)+b
250 if wt=0 or un=0then tp=76 : wn=2
251 for j=1to 11 : a=peek(mb+(ms-1)*12+j) : poke et+a,peek(et+a) or 144
252 a=peek(mb+(m2-1)*12+j) : poke et+a,peek(et+a) or 80 : next
253 poke ke+556,0 : poke ke+557,4
254 i=ms-1 : gosub 56 : g1$=i$
255 i=m2-1 : gosub 56 : g2$=i$
256 gosub 598
257 od$="" : for i=0to 6 : od$=od$+chr$(48+int(rnd(0)*10)) : next
258 ps=int(rnd(0)*16) : gosub 563
259 tm=int(rnd(0)*24)+1 : dy$="day" : if tm<6 or tm>20then dy$="night" : goto 261
260 tm=int(tm/2)*2
261 v=tm*100 : sd=4 : gosub 11 : tm$=i$
262 dr=int(rnd(0)*360) : v=dr : sd=3 : gosub 11 : dr$=i$
263 wn=int(rnd(0)*10)+2 : if int(rnd(0)*8)>5then wn=wn+10
264 if wt=0 or un=0then tp=76 : wn=2
265 gosub 4 : gosub 8 : hx=peek(eh+j) : hy=peek(ey+j)
266 goto  365
267 gosub 673 : poke 53270,200
268 print  "[blu][clr][dn][dn][dn][blk] AH-64A Pilot Roster & Service Records[dn]"
269 for z=0to 7 : p=z : gosub 99 : if z/2=int(z/2)then gosub 4
270 next : print "[home][dn][cya]▊[rvs]Erase Pilot[rvoff]";
271 poke a0,3 : sys ke+60
272 sys ke+12 : gosub 670
273 poke sl+2+cp,1 : poke a1,sm : sys ke+21 : ss=1 : gosub 674
274 poke a1,sm : sys ke : op=peek(a0)
275 if op=0then 289
276 if op<>1then cp=op-2 : goto 274
277 poke sl+1,0
278 print  "[home][dn][cya]▊[rvs]Erase Pilot[rvoff]";
279 poke 214,21 : print  : print  "[blk]        Enter new Pilot's Name"
280 print  "        >"; : poke 198,0 : x=9 : gosub 83 : if f$=""then 283
281 rs$(cp)=f$+left$(cl$,20-len(f$))+left$(cl$,20)+chr$(1)+left$(cl$,2)
282 rs$(cp)=rs$(cp)+chr$(2)+left$(cl$,40)
283 poke  214,21 : print  : print  "                                "
284 print  "                                "
285 poke 214,4+cp*2 : print  : print "[blu]                                       ";
286 v=(5+cp*2)*40+39 : poke 51200+v,32 : poke 55296+v,6
287 poke 214,4+cp*2 : print  : p=cp : gosub 99
288 goto  273
289 if asc(mid$(rs$(cp),47,1))=0then 296
290 poke 214,21 : print  : print "[red] You cannot use a Missing or Dead Pilot"
291 print "[blk]   Erase this pilot or select another.";
292 poke sl,0 : i=0 : gosub 297 : i=16 : gosub 297
293 poke 214,21 : print  : print "                                       "
294 print "                                      ";
295 print "[home][dn]"; : poke  211,30 : print "[grn]▋[rvs]Continue[rvoff][blk]" : goto 274
296 gosub 299 : goto 185
297 if (peek(56320) and 16)=ithen 297
298 return
299 n$="" : i=0
300 if i=20 or mid$(rs$(cp),i+1,1)=chr$(0)then 302
301 n$=n$+mid$(rs$(cp),i+1,1) : i=i+1 : goto 300
302 i=asc(mid$(rs$(cp),21,1)) : r=i : gosub 311 : r$=i$
303 j=cp : gosub 110 : i=cp : gosub 312 : sc$=i$
304 i=40 : gosub 124 : fl=v
305 i=41 : gosub 124 : ln=v
306 i=42 : gosub 124 : wt=v
307 i=43 : gosub 124 : qu=v
308 i=44 : gosub 124 : un=v
309 i=45 : gosub 124 : sf=v
310 return
311 i$=mid$("SGTWO12LT1LTCPTMAJLTCCOL",i*3+1,3) : return
312 sc=asc(mid$(rs$(i),22,1))+256*asc(mid$(rs$(i),23,1))
313 if sc>32767then sc=sc-65536
314 i$=str$(sc) : return
315 poke of,0
316 print "[blk][clr][dn][dn][dn] CHOOSE YOUR DUTY ASSIGNMENT : [dn]" : i$="       "
317 print i$"[cya]Flight Training in the USA : "
318 print i$"[lgrey]Learn to fly and shoot against"
319 print i$"enemies using "chr$(34)"blanks/"chr$(34)"[lf].[dn]"
320 print i$"[cya]1st Cavalry in Southeast Asia : "
321 print i$"[lgrey]A good first tour; the enemy has"
322 print i$"poor weapons, but is hard to find"
323 print i$"[cya]82nd Airborne in Central America : ";
324 print i$"[lgrey]Tougher rumbles in the jungle."
325 print i$"Guerillas have better armaments.[dn]"
326 print i$"[cya]101st Air Assault in Middle East : ";
327 print i$"[lgrey]Desert duels :  Beware the Russian-";
328 print i$"built SAMs and flak guns.[dn]"
329 print i$"[cya]3rd Armored in Western Europe : "
330 print i$"[lgrey]Desperate missions to stop the"
331 print i$"red steamroller from the east."
332 poke a0,4 : sys ke+60
333 gosub  670
334 sys ke+6
335 print "[home][dn][blk] Overall Risk :  "; : gosub 70
336 poke sl+1+un,1
337 poke a1,sm : sys ke+21 : gosub 674
338 poke a1,sm : sys ke+0 : op=peek(a0)
339 if op=0then goto 185
340 un=op-1
341 print "[home]" : poke 211,15 : gosub 70 : goto 338
342 poke of,0
343 print "[clr][blk][dn][dn][dn] WHAT STYLE OF MISSIONS WILL YOU FLY?[dn]" : i$="         "
344 print i$"[cya]Regular Missions"
345 print i$"[lgrey]Your best chance of surviving"
346 print i$"the war :  do what you're told"
347 print i$"and come back home intact![dn]"
348 print i$"[cya]Volunteer Missions"
349 print i$"[lgrey]Step forward for tougher"
350 print i$"missions, extra risks, and"
351 print i$"a chance to be a hero.[dn]"
352 print i$"[cya]Volunteer Hazardous Duty"
353 print i$"[lgrey]Just the ticket for gung-ho"
354 print i$"superheroes who don't worry"
355 print i$"about details like survival.[dn]"
356 poke 214,21 : print  : poke 211,15 : gosub 70
357 sys ke+9
358 poke 214,20 : print  : print "     [blk]Your overall level of risk is"
359 poke a0,5 : sys ke+60 : gosub  670
360 poke sl+1+sf,1
361 poke a1,sm : sys ke+21 : gosub 674
362 poke a1,sm : sys ke : op=peek(a0)
363 if op=0then 185
364 sf=op-1 : poke 214,21 : print  : poke 211,15 : gosub 70 : goto 362
365 poke of,0 : poke 53270,200 : print "[clr]";
366 sys ke+12 : if un=0then  396
367 poke 648,4
368 for i=0to 16 : poke 53248+i,0 : next
369 gosub 582
370 print "[clr][blk]OPS ORDER [blu]"od$;
371 print "[pwr][blk]ATK HEL BN, [blu]"un$;
372 print "[pwr][blk]OPS PASSWORD :  [red]"ps$; : print "[pwr][blk]COUNTERSIGN :  [red]"cs$;
373 print "[pwr][blk]H-HOUR [blu]"tm$"[pwr][pwr][blk]MISSION :  [blu]"ms$"[pwr]";
374 print "[pwr][blk]OBJECTIVE : [pwr]  [mgrey]You are to ";
375 print "[red]"md$" [mgrey]"; : i=ms : gosub 59
376 print " g1 [red]("g1$;
377 print ")[mgrey]. However, as a secondary objective, you may be ";
378 print "ordered to ";
379 print "[red]"m2$" [mgrey]"; : i=m2 : gosub 59
380 print " grid [red]("g2$;
381 print ")[mgrey].[pwr][pwr]   This is a [red]"dy$"[mgrey] mission. The wind is blowing at"wn;
382 print "kts from ";
383 i=dr+11 : if i>359then i=i-360
384 i=int(i/22.5)
385 i$=mid$(" N NNE NEENE E ESE SESSE S SSW SWWSW W WNW NWNNW",i*3+1,3) : a$=""
386 for i=1to 3 : j$=mid$(i$,i,1) : if j$="N"then a$=a$+"north"
387 if j$="S"then a$=a$+"south"
388 if j$="E"then a$=a$+"east"
389 if j$="W"then a$=a$+"west"
390 next : i$=chr$(asc(left$(a$,1))+128)+right$(a$,len(a$)-1) : print i$;
391 print " (";
392 v=dr : sd=3 : gosub 10
393 print "$) and the temperature is"tp"[lf]$[lftarr]";
394 poke  648,sm : poke a1,4 : poke a5,sm : sys ke+15
395 op=0 : goto 583
396 gosub 673
397 print "[clr][dn][dn][dn][blk] OPS ORDER :  [blu]TRAINING FLIGHT"
398 print " [blk]US ARMY HELICOPTER TRAINING CENTER"
399 print " NO OPS PASSWORD REQUIRED[dn][dn]"
400 print " H-HOUR :  [blu]"tm$
401 print "[dn][dn] [blk]MISSION :  [blu]FLIGHT & GUNNERY TRAINING"
402 print "[dn][dn] [blk]OBJECTIVE : " : print  "   [mgrey]You are cleared for a training"
403 print " flight over the gunnery range.  All"
404 print " enemies are armed with simulators"
405 print " that cannot hurt you. Complete flight"
406 print " by returning to the central heli-base."
407 print "   Weather is perfect.  This will"
408 print " be a "dy$" flight."
409 print "[home][cya] [rvs] See [rvoff]" : print  " [rvs] Map [rvoff]";
410 poke a0,6 : sys ke+60
411 gosub 670 : gosub 582 : gosub 674
412 poke a1,sm : sys ke : op=peek(a0)
413 if op=0then 508
414 goto 415
415 poke of,0 : sys ke+12
416 poke a0,0 : poke a1,168 : poke a2,0 : poke a3,192 : poke a4,0 : poke a5,8 : sys ke+51
417 poke ke+556,12 : poke ke+557,12
418 print "[blu][clr]12"spc(36);
419 for i=12to 2step -1 : if i/3=int(i/3)then gosub 4
420 v=i : sd=2 : gosub 10 : print "[]"spc(36)"[]"; : v=i-1 : gosub 10 : print spc(36); : next
421 print "01[]"spc(36)"[]  =01=02=03=04=05=06=07=08=09=10=11=12";
422 poke a0,7 : sys ke+60
423 poke 53282,6 : poke 53283,13 : poke 53288,0 : poke sp+1,230 : poke 53275,0
424 poke s+3,47+(192-(hy-24)) : v=39+(hx-24)*1.5 : gosub 125 : poke s+2,lo
425 poke s+16,hi*2 : sys ke+57 : ss=3 : bk=5 : gosub 674 : poke 198,0
426 if (peek(56320) and 16)=0then 428
427 get i$ : if i$=""then 426
428 poke 53265,0 : poke 53270,200 : poke 53281,1
429 poke a0,0 : poke a1,168 : poke a2,0 : poke a3,192 : poke a4,0 : poke a5,8 : sys ke+51
430 goto 365
431 poke 53265,0 : print "[clr]";
432 poke 648,4
433 print "[clr][blk]OPS ORDER [blu]"od$;
434 print "[pwr][blk]ATK HEL BN, [blu]"un$;
435 print "[pwr][blk]MISSION :  [blu]"ms$;
436 print "[pwr][pwr][pwr][blk]G-2 INTELLIGENCE BRIEFING : [pwr]  [mgrey]";
437 on ungoto  438,439,440,441
438 print "NVA and VC"; : goto  442
439 print "FSLN"; : goto  442
440 print "Arab"; : goto  442
441 print "Warsaw Pact";
442 print " forces are expected to have ";
443 on qugoto 445,446
444 print "elite troops with the latest equipment"; : goto  447
445 print "trained troops with good equipment"; : goto 447
446 print "inexperienced troops with obsolete equipment";
447 print " in this area.  They carry ";
448 gosub 4 : gosub 633 : print "[red]"i$;
449 print "[mgrey] for protection.[pwr]  Enemy local air defenses include [red]";
450 gosub 647 : print a$;
451 print "[mgrey].[pwr]  Enemy Mi-24 Hind helicopters ";
452 if un=1then print "are not"; : goto 454
453 print "[red]ARE";
454 print "[mgrey] believed to be operating in this area.[pwr][pwr]";
455 print "  Overall, G-2 expects this mission's difficulty to be [lred]"; : gosub 70
456 print "[lftarr]";
457 poke 648,sm : poke a1,4 : poke a5,sm : sys ke+15
458 op=2 : goto 583
459 poke of,0 : print "[clr]";
460 poke  648,4 : poke 53270,200
461 print "[blk][clr]ATK HEL BN, [blu]"un$;
462 print "[pwr][red]PRE-FLIGHT CHECKLIST : [pwr][pwr]";
463 print "[blk]DO YOU KNOW YOUR COUNTERSIGN?[pwr]";
464 print "[mgrey]   If you don't your own air defenses will shoot ";
465 print "you down![pwr][pwr][blk]DO YOU KNOW YOUR TARGETS?[pwr]";
466 print "[mgrey]   It's hard to succeed in your mission if you forget your";
467 print " orders! ";
468 print "Nothing is more embarrassing than ";
469 print "forgetting where to find the target![pwr][pwr]";
470 print "[blk]REMEMBER THE TIME AND WEATHER[pwr]";
471 print "[mgrey]   It's a "dy$" Mission![pwr]";
472 print "   The wind is"wn"kts from"dr;
473 print "[lf]$[pwr]   The temperature is"tp"[lf]$F which ";
474 print "will affect weight you can carry.[lftarr]"
475 poke 648,sm : poke a1,4 : poke a5,sm : sys ke+15
476 poke 214,21 : print
477 print "[cya]▊[rvs]Yes,    [rvoff]                  ▊[rvs] No, return[rvoff]"
478 print "▊[rvs]Continue[rvoff]                  ▊[rvs]to briefing[rvoff]";
479 poke a0,8 : sys ke+60 : poke ke+562,39 : poke ke+563,91
480 sys ke+12 : ss=1 : gosub 674
481 poke a1,sm : sys ke : op=peek(a0)
482 poke of,0
483 if op=1then 365
484 goto 508
485 poke of,0
486 poke ke+551,0
487 print "[clr][dn][dn] [grn]Going on Sick Call?"
488 print "[dn] [mgrey]It's a favorite way for malingerers"
489 print " and cowards to avoid tough missions."
490 print "[dn] You'll be scrubbed from this mission,"
491 print " but the CO won't be happy about it."
492 print " He will arrange for your transfer"
493 print " to another unit, immediately."
494 print "[dn] He'll also put a reprimand in your"
495 print " personnel file, [red]making promotions"
496 print " much harder!"
497 print "[dn][dn][dn][dn] [blk]Do you really want to go on"
498 print " Sick Call?"
499 print "[dn][dn][dn] [cya][rvs] Yes [rvoff]                             [cya][rvs] No [rvoff]";
500 poke a0,9 : sys ke+60
501 poke ke+562,39 : poke ke+563,94
502 sys ke+12 : ss=1 : gosub 674
503 poke a1,sm : sys ke : op=peek(a0)
504 if op=1then 365
505 un=un-1 : i$=left$(rs$(cp),23) : i=asc(mid$(rs$(cp),24,1)) : if i<255then i=i+1
506 i$=i$+chr$(i)+right$(rs$(cp),40) : rs$(cp)=i$ : j=cp : gosub 110
507 goto 185
508 gosub 673 : poke 53264,0
509 d$="1" : gosub 758 : gosub 64
510 gosub 673 : poke 53264,0
511 poke ke+551,1 : if tp<76then tp=76
512 print "[clr][cya]";
513 gosub 561
514 poke a0,10 : sys ke+60 : poke 53281,1
515 poke a0,0 : poke a1,188 : poke a2,0 : poke a3,216 : poke a4,0 : poke a5,4 : sys ke+48
516 mx=21000-50*abs(76-tp) : cw=10760 : s1=0 : s2=0 : s3=0
517 for i=0to 4 : wp%(i)=0 : poke sp+i+2,225 : next : poke sp+7,225
518 on ungoto 520,521,522,523
519 mx=mx-700 : fu=376 : rn=60 : ch=1 : fr=1 : hl=1 : f1=1 : f2=0 : sw=1 : goto 524
520 mx=mx-350 : fu=376 : rn=60 : ch=1 : fr=1 : hl=0 : f1=1 : f2=1 : sw=0 : goto 524
521 fu=376 : rn=60 : ch=1 : fr=1 : hl=1 : f1=0 : f2=1 : sw=1 : goto 524
522 mx=mx-700 : fu=376 : rn=30 : ch=1 : fr=1 : hl=1 : f1=0 : f2=1 : sw=1 : goto 524
523 fu=374 : rn=60 : ch=1 : fr=1 : hl=1 : f1=0 : f2=1 : sw=1
524 cw=cw+fu*6.5+rn*26 : for i=51082to 51103 : poke i,255 : next
525 poke 214,20 : print  : for i=51062to 51073 : poke i,255 : next
526 poke 211,36-len(str$(mx)) : print right$(str$(mx),len(str$(mx))-1);
527 i=ch : ch=0 : gosub 46 : i=fr : fr=0 : gosub 50 : gosub 4
528 i=0 : gosub 12 : i=0 : gosub 27 : gosub 4
529 i=sw*4 : gosub 30 : i=f2*2 : gosub 43 : i=f1*3 : gosub 40 : gosub 4
530 if s2=0then i=hl : gosub 40 : goto 532
531 if s3=0then i=hl : gosub 43
532 bk=0 : gosub 674
533 poke ke+562,147 : poke ke+563,94 : if un>0then 535
534 poke l1+12,41 : j=8 : for i=56216to 56225 : poke i,j : poke i+40,8 : j=0 : next
535 hd=0 : poke sp+1,225
536 poke a1,sm : sys ke : op=peek(a0)
537 if (op=0) and (rn<60)then i=1 : gosub 27 : goto 535
538 if (op=1) and (rn>0)then i=-1 : gosub 27 : goto 535
539 if (op=2) and (fu<376)then i=8 : gosub 12 : goto 535
540 if (op=3) and (fu>0)then i=-8 : gosub 12 : goto 535
541 if op=4 and ch<1then i=ch+1 : gosub 46 : goto 535
542 if op=5 and ch>0then i=ch-1 : gosub 46 : goto 535
543 if op=6 and fr<1then i=fr+1 : gosub 50 : goto 535
544 if op=7 and fr>0then i=fr-1 : gosub 50 : goto 535
545 if op=8then hd=1 : poke sp+1,226 : goto 536
546 if op=9then hd=2 : poke sp+1,227 : goto 536
547 if op=10then hd=4 : poke sp+1,229 : goto 536
548 if op=11then hd=3 : poke sp+1,228 : goto 536
549 if op<>15then 554
550 xx=peek(ke+560) : poke sl+15,0 : if xx>45 or xx<6then i=hd : gosub 30 : goto 535
551 if xx>38 or xx<13then i=hd : gosub 40 : goto 535
552 if xx>31 or xx<19then i=hd : gosub 43 : goto 535
553 goto 536
554 if op=12then poke of,0 : gosub 559 : gosub 561 : goto 485
555 if op=14then poke of,0 : gosub 561 : goto 715
556 if op=13then 558
557 goto  535
558 poke of,0 : gosub 559 : goto 524
559 cw=cw-fu*6.5-rn*26-(ch+fr)*20 : fu=376 : rn=00 : ch=0 : fr=0 : hl=0 : f1=0 : f2=0 : sw=0
560 for i=0to 4 : poke sp+2+i,225 : next : poke sp+7,225 : return
561 poke a0,0 : poke a1,176 : poke a2,0 : poke a3,192 : poke a4,0 : poke a5,12 : sys ke+51
562 return
563 if ps>9then 565
564 on ps+1goto 566,567,568,569,570,571,572,573,574,575
565 on ps-9goto 576,577,578,579,580,581
566 ps$="ACCENT" : cs$="TRAMPOLINE" : return
567 ps$="BILLBOARD" : cs$="KICKBACK" : return
568 ps$="CROMAGNON" : cs$="MELODRAMA" : return
569 ps$="DAKOTA" : cs$="ONSTAGE" : return
570 ps$="ELECTRA" : cs$="VERTICAL" : return
571 ps$="FOOTHOLD" : cs$="INSOLENT" : return
572 ps$="GRENADIER" : cs$="NOCTURNE" : return
573 ps$="HEDGEHOG" : cs$="LOCKSMITH" : return
574 ps$="IVORY" : cs$="WILLOW" : return
575 ps$="KNOCKOUT" : cs$="PUREBRED" : return
576 ps$="LOZENGE" : cs$="ROMANTIC" : return
577 ps$="MAZURKA" : cs$="YELLOW" : return
578 ps$="NEBULA" : cs$="QUAKER" : return
579 ps$="OVATION" : cs$="UPSTAGE" : return
580 ps$="PENTHOUSE" : cs$="SYMPHONY" : return
581 ps$="QUARTZ" : cs$="ZEBRA" : return
582 poke a0,11 : sys ke+60 : ss=31 : return
583 print "[home][cya]";
584 for i=0to 3 : if i=opthen print  "       "; : goto  586
585 print  "▒▁[rvs]"op$(i,0)"[rvoff]▎";
586 next : print
587 for i=0to 3 : if i=opthen print  "       "; : goto  589
588 print  "▊[rvs]"op$(i,1)"[rvoff]";
589 next
590 poke rs+1,0 : poke rs,67 : poke g1,33 : poke g2,33 : poke v1,0 : poke v2,0 : poke g1+1,33
591 poke g2+1,33 : poke v1+1,1 : poke v2+1,1 : sys ke+24 : gosub  582
592 poke a0,12 : sys ke+60 : gosub  670
593 poke l1+1+op,41
594 gosub 674
595 poke a1,sm : sys ke : i=peek(a0)
596 on igoto 365,415,431,485
597 goto  459
598 on ungoto 599,600,601,602
599 un$="6 REGT, 1 CAV DIV" : return
600 un$="CBAA, 82 ABN DIV" : return
601 un$="CBAA, 101 AAS DIV" : return
602 un$="CBAA, 3 ARM DIV" : return
603 if un=0then  return
604 if ms>10then  607
605 on msgosub 609,610,611,612,613,614,615,616,617,618
606 goto 622
607 on ms-10gosub 619,620,621
608 goto 622
609 md$="Dheadquarters1" : return
610 md$="Ddepot1" : return
611 md$="Dheli-base1" : return
612 md$="DAA guns2" : return
613 md$="Dmobile SAMs2" : return
614 md$="Dtanks3" : return
615 md$="DBMPs & BTRs3" : return
616 md$="Dinfantry3" : return
617 md$="Dbunker3" : return
618 md$="Stroops3" : return
619 md$="Sbase3" : return
620 md$="Clear LZ3" : return
621 md$="Search & Destroy5" : return
622 i=val(right$(md$,1)) : md$=left$(md$,len(md$)-1)
623 on igosub 624,625,626,627,628 : goto  629
624 ms$="Interdiction Strike" : return
625 ms$="Tactical Strike" : return
626 ms$="Ground Support" : return
627 ms$="Interception" : return
628 ms$="Search & Destroy" : return
629 if left$(md$,1)="D"then md$="destroy enemy "+right$(md$,len(md$)-1)
630 if ms=13then return
631 if left$(md$,1)="S"then md$="support friendly "+right$(md$,len(md$)-1)
632 return
633 i=(un-1)*3+(2-qu)
634 if i=11then i$="SA-14" : goto 646
635 on igoto 636,637,638,639,640,641,642,643,644,645
636 i$="mostly Machine-guns, some SA-7" : goto  646
637 i$="SA-7" : goto 646
638 i$="SA-7" : goto 646
639 i$="SA-7" : goto 646
640 i$="SA-7B" : goto 646
641 i$="SA-7" : goto 646
642 i$="SA-7B" : goto 646
643 i$="SA-7B" : goto 646
644 i$="SA-7" : goto 646
645 i$="SA-7B"
646 i$=i$+" short range IR missiles" : return
647 i=(un-1)*3+(2-qu)
648 if i=11then  i$="SA-11 and SA-13NZSU-30 AATandGC" : goto 661
649 on igoto 651,652,653,654,655,656,657,658,659,660
650 i$="S-60 57mm guns without radar and ZU-23L" : goto 661
651 i$="[lf]GR and ZU-23L" : goto 661
652 i$="[lf]GC and ZU-23L" : goto 661
653 i$="SA-9N[lf]GR, and ZU-23L" : goto 661
654 i$="SA-9NZSU-57-2 AAT[lf]GR, and ZU-23L" : goto 661
655 i$="SA-9NZSU-23-4 AAT[lf]GC, and ZU-23mmL" : goto 661
656 i$="SA-9NSU-57-2 AATandGR" : goto 661
657 i$="SA-8 and SA-9NZSU-23-4 AATandGR" : goto 661
658 i$="SA-8B and SA-9BNZSU-23-4M AATandGC" : goto 661
659 i$="SA-8 and SA-9NZSU-23-4 AATandGR" : goto 661
660 i$="SA-8B and SA-9BNZSU-23-4M AATandGC"
661 a$="" : for i=1to len(i$) : b$=mid$(i$,i,1) : if i/5=int(i/5)then gosub 4
662 if b$="N"then a$=a$+" missiles, " : goto 669
663 if b$="T"then a$=a$+" tanks, " : goto 669
664 if b$="G"then a$=a$+" S-60 57mm guns with " : goto 669
665 if b$="C"then a$=a$+"radar fire control" : goto 669
666 if b$="R"then a$=a$+"search radar" : goto 669
667 if b$="L"then a$=a$+" light cannons" : goto 669
668 a$=a$+b$
669 next : return
670 print "[home][dn]"; : poke 211,30 : print "[grn]▋[rvs]Continue[rvoff][blk]"
671 print "[blk]||||||||||||||||||||||||||||||||||||||||";
672 poke a0,13 : sys ke+60 : poke ke+562,143 : poke ke+563,6 : return
673 poke of,0 : poke ke+552,0 : poke ke+553,159 : poke ke+554,0 : poke ke+555,99 : return
674 poke 53269,ss : ss=255 : poke 53280,11 : poke 53281,bk : bk=1 : poke 53265,27 : return
675 sys ke+12 : poke of,0 : poke  56576,0 : poke 648,200 : poke 53272,32 : poke 53270,216
676 for i=2to 16 : poke 53248,0 : next
677 poke 53269,255
678 poke sp,177 : poke 53287,12
679 poke 53280,11 : poke 53281,1 : return
680 rem
681 poke 53269,0 : sys ke+54
682 gosub 687
683 poke 781,b-int(b/256)*256 : poke 782,b/256
684 poke 780,0 : poke 56333,127 : poke 808,237 : sys 65493 : poke 808,234
685 if (st  and 191)<>0then 682
686 poke 808,234 : poke 792,193 : sys ke+3 : return
687 for i=0to len(f$)-1 : poke 1006+i,asc(mid$(f$,i+1,1)) : next
688 poke 780,0 : poke 781,8 : poke 782,1 : sys 65466
689 poke 780,len(f$) : poke 781,238 : poke 782,3 : sys 65469
690 return
691 ke=117*256
692 if peek(828+58*2)=0then cp=11
693 dim rs$(11),w%(4),wc%(4),c%(4)
694 sm=200 : s=53248 : sp=sm*256+1016 : sh=ke+120 : rl=sh+6 : sx=rl+6 : sy=sx+6
695 a0=165 : a1=a0+1 : a2=a1+1 : a3=a2+1 : a4=a3+1 : a5=a4+1 : a6=a5+1 : a7=a6+1
696 no=ke+144 : l1=no+1 : t1=l1+24 : r1=t1+24 : b1=r1+24 : c1=b1+24 : ex=c1+24 : gr=ex+24
697 sl=gr+24 : cr=sl+24 : l2=cr+24 : t2=l2+24 : r2=t2+24 : b2=r2+24 : c2=b2+24
698 rs=ke+481 : g1=rs+5 : v1=g1+5 : g2=v1+5 : v2=g2+5 : ss=255 : bk=1
699 bt=ke+539 : pt=bt+2 : hr=pt+2 : ml=hr+2 : bc=ml+2 : pc=bc+2
700 db=828 : sv=49*256 : oc=21464 : mb=144*256 : cb=145*256 : tb=146*256 : bb=147*256
701 eh=148*256 : ey=eh+128 : eg=ey+128 : eo=eg+128 : et=eo+128 : bf=160*256
702 m$="[mgrey]SR  [mgrey]NDS [mgrey]SEAC[mgrey]CAC [mgrey]MEC [mgrey]WEC [mgrey]AM  [mgrey]PH  [mgrey]ACM [mgrey]BSV [mgrey]SS  [mgrey]DSC [mgrey]CMOH"
703 for i=0to 3 : for j=0to 1 : read op$(i,j) : next : next
704 read fl$(1),fl$(0),ln$(1),ln$(0),wt$(1),wt$(0)
705 read dm$(0),dm$(1),dm$(2)
706 read w%(0),w%(1),w%(2),w%(3),w%(4)
707 read wc%(0),wc%(1),wc%(2),wc%(3),wc%(4)
708 read c%(0),c%(1),c%(2),c%(3),c%(4)
709 for i=0to 11 : rs$(i)=cl$ : next
710 gosub 61 : sys ke+63
711 if cp<>11then cp=asc(mid$(rs$(8),1,1))
712 j=cp : gosub 110 : gosub 299
713 poke of,0 : sys ke+3 : gosub 675 : poke ke+551,0 : poke 53271,0 : poke 53277,0
714 poke 53276,0 : goto 185
715 gosub 673
716 v=ps : i=0 : gosub 127
717 v=-(dy$="night") : gosub 127
718 v=3-qu : gosub 127
719 v=fu*.415*128 : gosub 127
720 v=fu*.585*128 : gosub 127
721 v=fl*2+ln : gosub 127
722 v=(sf+1)*-(un>0) : gosub 127
723 v=int(abs(76-tp)/5) : gosub 127
724 v=int(((wn-2)*cos(dr*(<PIPE>/180)))/2) : gosub 127
725 v=int(((wn-2)*sin(dr*(<PIPE>/180)))/2) : gosub 127 : gosub 4
726 v=rn : gosub 127
727 v=wp%(4)*2 : gosub 127
728 v=wp%(2)*7+wp%(3)*19 : gosub 127
729 v=wp%(1)*8 : gosub 127
730 v=fr*10 : gosub 127
731 v=ch*10 : gosub 127
732 v=(m2-1)*256+(ms-1) : gosub 127
733 v=un : gosub 127
734 v=mp+en*256 : gosub 127 : gosub 4
735 for j=1to 64 : poke db+37+j,asc(mid$(rs$(cp),j,1)) : next : gosub 4
736 v=0 : i=43 : gosub 127
737 v=hx*256 : i=52 : gosub 127
738 v=hy*256+128*(un=3) : gosub 127
739 v=0 : gosub 127 : gosub 127 : gosub 127 : gosub 127 : gosub 127
740 v=cp : i=59 : gosub 127
741 v=-4*(un=0) : gosub 127
742 v=tp : gosub 127
743 v=0 : gosub 127
744 for i=0to 9 : poke db+i+128,31 : next
745 for i=1to len(ps$) : poke db+127+i,asc(mid$(ps$,i,1))-192 : next : gosub 4
746 d$="2" : gosub 758
747 sys ke+54 : poke of,0 : poke  53270,200 : poke  56576,3 : poke 53272,22 : poke 53269,0
748 poke 53281,11 : poke 53280,11 : poke 53282,0 : poke 648,4
749 print "[dgrey][clr][dn][dn]load "chr$(34)"6"chr$(34)",8,1[dn][dn][dn][dn][dn]"
750 print "[wht]            Please Stand By[dgrey][home]";
751 poke 631,13 : poke 198,1 : poke of,27 : poke 808,237 : new
752 poke 53269,0 : print "[clr][wht][dn][dn][dn][dn][dn][dn][dn][dn]      Turn disk over and insert it"
753 if d$="2"then print "[dn]           Backside face "chr$(34)"UP"chr$(34)
754 if d$="1"then print "[dn]           Frontside face "chr$(34)"UP"chr$(34)
755 print "[dn][dn][dn][dn]         press BUTTON when ready"
756 bk=11 : ss=0 : gosub 674
757 if peek(56320) and 16then 757
758 print "[clr]" : poke 53269,0 : open 15,8,15,"i0 : " : open 2,8,2,"#1"
759 print#15,"u1";2;0;18;0 : print#15,"b-p";2;163 : get #2,i$ : close 2 : close 15
760 if i$<>d$then 761
761 poke of,0 : return
762 data"See ","Brief ","See "," Map  ","See ","Intel "
763 data"Sick"," Call "
764 data"real flight performance","simplified flight"
765 data"crash landings possible","all landings are perfect"
766 data"highly variable weather","light winds, temp. 76$F"
767 data" [lgrn]Operational"," [yel]Damaged"," [lred]DESTROYED"
768 data0,2400,1600,2640,400,0,8,14,38,2,0,7,3,13,1
769 data"T-74","M1A1 Abrams","BMP-2","M2A1 Bradley","MT-LB","M113A3 APC"
770 data"BTR-70","M163 Vulcan","SA-6 Gainful","M247 Sgt York","SA-8 Gecko"
771 data"M48A1 Chaparral","SA-9 Gaskin","UH-60 Blackhawk","SA-13 Gopher"
772 data"Merkava Mk2","ZSU-23-4 Shilka","ZSU-57-2"
773 data"Mi-24 Hind-D","Hughes 500MD"