Actor InfernoRocketAmmo : Ammo replaces RocketAmmo
{
    Inventory.Amount 5
    Inventory.MaxAmount 50
    Inventory.Icon "LAUNA0"
    Inventory.PickupMessage "Picked up some inferno rockets."
    Inventory.PickupSound "misc/i_pkup"
    Ammo.BackpackAmount 5
    Ammo.BackpackMaxAmount 100
    +COUNTITEM
    States
    {
    Spawn:
        ROCK A -1
        Stop
    }
}

Actor SSAERocketLauncher : Weapon replaces RocketLauncher
{
    Inventory.PickupMessage "Rocket ranger, ready to rocket!"
    Inventory.PickupSound "misc/w_pkup"
    Weapon.AmmoGive 5
    Weapon.AmmoType "InfernoRocketAmmo"
    Weapon.AmmoUse 1
    Weapon.KickBack 200
    Weapon.SelectionOrder 1750
    Weapon.SlotNumber 5
    Weapon.SlotPriority 0
    +WEAPON.EXPLOSIVE
    +WEAPON.NOAUTOAIM
    Tag "XPML21 Rocket Launcher"
    States
    {
    Ready:
        MISG A 1 A_WeaponReady
        Loop
    Deselect:
        MISG A 1 A_Lower
        Loop
    Select:
        TNT1 A 1
        TNT1 A 0 A_GiveInventory("357OneChamber",6)
        TNT1 A 0 A_GiveInventory("357TwoChambers",12)
        TNT1 A 0 A_TakeInventory("SpinMeter",8)
        Goto SeLoop
    SeLoop:
        MISG A 1 A_Raise
        Loop
    Fire:
        MISG B 2 A_GunFlash
        MISG B 21 A_FireCustomMissile("InfernoRocket",0,1)
        MISG B 0 A_Refire
        Goto Ready
    Flash:
        MISF A 2 Bright A_Light1
        MISF B 3 Bright
        MISF CD 4 Bright A_Light2
        Goto LightDone
    Spawn:
        LAUN A -1
        Stop
    }
}

Actor InfernoRocket replaces Rocket
{
    Health 9
    Radius 11
    Height 8
    Damage (Random(5,35)*5)
    Speed 20
    Projectile
    +ROCKETTRAIL
    +SHOOTABLE
    +DEHEXPLOSION
    +CANBOUNCEWATER
    +NOBLOOD
    -NOBLOCKMAP
    SeeSound "weapons/rocklf"
    DeathSound "weapons/rocklx"
    Decal "scorch"
    Obituary "%k blew %o away."
    //SuicideObituary "%k blew %hself away."
    States
    {
    Spawn:
        MISL A 1 Bright
        Loop
    Death:
        MISL B 0 A_Explode(25,75,1,1,50)
        MISL B 8 A_Explode(75,125,0,1,50)
        MISL C 6 Bright
        MISL D 4 Bright
        Stop
    }
}