Get flint by mining gravel with a bowl (CT script)

mods.jei.JEI.addDescription(<minecraft:flint>,"Can be obtained with a 100 percent chance by mining gravel with a bowl");
mods.jei.JEI.addDescription(<minecraft:bowl>,"Can be used to obtained flint by mining gravel");

events.onBlockBreak(
    function(event as crafttweaker.event.BlockBreakEvent) {
        if (event.isPlayer && (event.block.definition.id == "minecraft:gravel")) {
            if (isNull(event.player.currentItem) || (event.player.currentItem.name != <minecraft:bowl>.name)) {
                return;
            }

            var new_amount = event.player.currentItem.amount - 1;
            if (new_amount > 0) {
                event.player.setItemToSlot(
                        crafttweaker.entity.IEntityEquipmentSlot.mainHand(),
                        event.player.currentItem.withAmount(new_amount));
            }   else {
                event.player.setItemToSlot(crafttweaker.entity.IEntityEquipmentSlot.mainHand(), null);
            }
            if(!event.world.isRemote()) {
                event.world.spawnEntity(<minecraft:flint>.withAmount(1).createEntityItem(event.world, event.position));
            }
        }
    }
);