SGLauncher Old Syntax

Main {
  /*
  We first set the window values
  Size it to fit the background picture's size
  Make the backgroundcolour dark
  And put our new title into the taskbar button
  */
  Window("x y w400 h220","000000","Example #1")
  //We then position the movebox, to make the titlebar, that's painted onto our background picture, act like one
  Movebox("x0 y0 w400 h25")

  //Execute one of the specified actionlists (chosen randomly)
  Autoexec("ExeclistRnd(Screen1 Screen2 Screen3 Screen4)")

  //After the launcher window is set up, we put our background picture in it
  Image("Background.png","","x0 y0 w400 h220")

  //We also put in the Button's images
  Image("Button-N.png","Button-H.png","x180 y135 w205 h21")
  Image("$Last","$Last","x180 y160 w205 h21")
  Image("$Last","$Last","x180 y185 w205 h21")

  //And maybe a screenshot to show the user what he can expect?
  Image("Screen-1-Thumb.jpg","","x5 y30 w145 h110","PreviewImage")
  //Show some text, when the user hovers the screenshot
  Mouseover("x5 y30 w145 h110","Tip(Hello! This is an example screenshot of my game!)","Tip()")

  //Configure the text's new font
  Font("Arial","FFFFFF","9","Bold")
  //Give the titlebar some text
  Text("Game Launcher","x5 y5 w100 h15")
  //And add texts onto the button images
  Text("Start Game","x250 y137 w100 h15")
  Text("About Game","x250 y162 w100 h15")
  Text("Exit Game","x250 y187 w205 h15")

  //Actionlist that alter the preview image (for random screenshots)
  Screen1 [ SetID(PreviewImage); SetImage(Screen-1-Thumb.jpg) ]
  Screen2 [ SetID(PreviewImage); SetImage(Screen-2-Thumb.jpg) ]
  Screen3 [ SetID(PreviewImage); SetImage(Screen-3-Thumb.jpg) ]
  Screen4 [ SetID(PreviewImage); SetImage(Screen-4-Thumb.jpg) ]

  //Lastly, we give the buttons some actions
  Rect("x180 y135 w205 h21","Msg(You may execute a game, once this button is pressed!)")
  Rect("x180 y165 w205 h21","Msg(About\n\nExample Launcher)")
  Rect("x180 y185 w205 h21","Exit()")
}