mgb

@name money gang bank
@inputs Main:wirelink [User,Register]:entity
@outputs Door:number
@persist [Side,CashPerPrinter,PayInterval,Payroll,LoginMSG]:number [CurUser,Owner]:entity [Account]:table
@trigger

if(first() | duped() | dupefinished()){

    setName("money gang bank - Bims")
    elevateMoneyGive()

    CashPerPrinter = 1750
    PayInterval = 10
    CurUser = noentity()
    Account = table()
    Owner = owner()
    Side = 1
    Payroll = 1
    LoginMSG = 1

    function number wirelink:egpButton(Index:number,Player:entity){
        Pos=This:egpPos(Index)
        Size=This:egpSize(Index) / 2
        return inrange(This:egpCursor(Player),Pos-Size,Pos+Size)
    }

    function void entity:addAccount(){
        Account[This:steamID(),table] = table(
        "Player" = This,
        "PrinterCount" = 0
        )
    }

    function number entity:hasAccount(){
        return Account[This:steamID(),table] ? 1 : 0
    }

    function void entity:removeAccount(){
        Account:remove(This:steamID())
    }

    Main:egpClear()
    Main:egpBox(1,vec2(256,256),vec2(512,512)) Main:egpColor(1,44,62,80,255)
    Main:egpText(2,"money gang bank",vec2(256,156)) Main:egpAlign(2,1,1) Main:egpFont(2,"Courier New",50)
    Main:egpBox(3,vec2(256,306),vec2(512,126)) Main:egpColor(3,52,73,94,255)
    Main:egpText(4,"du modtager "+CashPerPrinter+"kr pr genstand",vec2(256,276)) Main:egpAlign(4,1,1) Main:egpFont(4,"Courier New",25)
    Main:egpText(5,"udbetaling hvert "+PayInterval+". minut",vec2(256,306)) Main:egpAlign(5,1,1) Main:egpFont(5,"Courier New",25)
    Main:egpText(6,"bankmand "+Owner:name(),vec2(256,336)) Main:egpAlign(6,1,1) Main:egpFont(6,"Courier New",25)
    Main:egpBox(7,vec2(0,0),vec2(0,0))

    for(I = 4,6){ Main:egpParent(I,7)}

    Main:egpText(8,"Velkommen tilbage!",vec2(256,206)) Main:egpAlign(8,1,1) Main:egpFont(8,"Courier New",30)
    Main:egpText(9,"0 ud af 4",vec2(256,306)) Main:egpAlign(9,1,1) Main:egpFont(9,"Courier New",40)
    Main:egpText(10,"log ud",vec2(256,426)) Main:egpAlign(10,1,1) Main:egpFont(10,"Courier New",30)
    Main:egpBox(11,vec2(256,426),vec2(156,46)) Main:egpColor(11,0,0,0,0)
    Main:egpBox(12,vec2(0,0),vec2(0,0))

    for(I = 8,11){ Main:egpParent(I,12)}

    Main:egpPos(12,vec2(-512))

    function void side(N:number){
        switch(N){
            case 1,
                Main:egpPos(7,vec2(0))
                Main:egpPos(12,vec2(512))
                Side = 1
                CurUser = noentity()
            break

            case 2,
                Main:egpPos(7,vec2(512))
                Main:egpPos(12,vec2(0))
                Side = 2
            break
        }
    }

    function void mainInfoUpdate(){
        Main:egpSetText(8,"Velkommen "+CurUser:name())
        Main:egpSetText(9,Account[CurUser:steamID(),table]["PrinterCount",number]+" ud af 4")
    }

    timer("Payout",PayInterval*60000)
    timer("Distance",3000)
}

if(~User & User & ops() < 100){
    if(Side == 1){
        if(Main:egpButton(1,User)){
            if(!User:hasAccount()){
                User:addAccount()
            }
            CurUser = User
            side(2)
            mainInfoUpdate()
        }
    }
    elseif(Side == 2){
        if(Main:egpButton(11,CurUser)){
            side(1)
        }
    }
}

if(~Register & Register:isPrinter() & Side == 2 & Account[CurUser:steamID(),table]["PrinterCount",number] < 4){
    Account[CurUser:steamID(),table]["PrinterCount",number] = Account[CurUser:steamID(),table]["PrinterCount",number] + 1
    mainInfoUpdate()
    print(CurUser:name()+" har indsat en genstand!")
    concmd("play buttons/bell1.wav")
}

if(clk("Payout")){
    if(Payroll){
        foreach(_,V:table = Account){
            if(V["Player",entity]:isPlayer()){
                moneyGive(V["Player",entity],V["PrinterCount",number]*CashPerPrinter)
            }
            else{
                print("Fjernede en konto ("+V["Player",entity]:name()+")")
                V["Player",entity]:removeAccount()
            }
        }
        print("Laver udbetaling til kunder")
    }
    else{
        print("Udbetaling er slukket")
    }
    timer("Payout",PayInterval*60000)
}
elseif(clk("Distance")){
    if(Side == 2){
        if(CurUser:pos():distance(Main:entity():pos()) > 125){
            side(1)
            print("Loggede ud af E2en pga. distance")
        }
    }
    timer("Distance",3000)
}

event chat(Player:entity,Message:string,_:number){
    if(Player == Owner & Message:sub(1,1) == "!"){
        local Rest = Message:sub(2)
        local Args = Rest:explode(" ")

        switch(Args[1,string]){
            case "fl",
                side(1)
                hideChat(1)
                print("Logger ud af E2en")
            break

            case "cpp",
                CashPerPrinter = Args[2,string]:toNumber()
                hideChat(1)
                print(aeL()+"ndrede udkomst per genstand til "+CashPerPrinter+"kr")
                Main:egpSetText(4,"du modtager "+CashPerPrinter+"kr pr genstand")
            break

            case "remove",
                if(findPlayerByName(Args[2,string]):hasAccount()){
                    findPlayerByName(Args[2,string]):removeAccount()
                    hideChat(1)
                    print("Fjernede "+findPlayerByName(Args[2,string]):name()+" som kunde")
                }
                else{
                    print("Fejl")
                }
            break

            case "add",
                if(!findPlayerByName(Args[2,string]):hasAccount()){
                    findPlayerByName(Args[2,string]):addAccount()
                    hideChat(1)
                    print("Tilf"+oe()+"jede "+findPlayerByName(Args[2,string]):name()+" som kunde")
                }
                else{
                    print("Fejl")
                }
            break

            case "set",
                local X = findPlayerByName(Args[2,string])
                local Y = Args[3,string]:toNumber()
                if(X:hasAccount()){
                    Account[X:steamID(),table]["PrinterCount",number] = Y
                    print("Satte "+X:name()+"s genstande til "+Y)
                }
                else{
                    print("Fejl")
                }
                hideChat(1)
            break

            case "payroll",
                if(Payroll){
                    Payroll = 0
                    print("Slukkede for udbetalinger")
                }
                else{
                    Payroll = 1
                    print("Aktiverede for udbetalinger")
                }
                hideChat(1)
            break

            case "msg",
                if(LoginMSG){
                    LoginMSG = 0
                    print("Slukkede for privat annoncering")
                }
                else{
                    LoginMSG = 1
                    print("Aktiverede for privat annoncering")
                }
                hideChat(1)
            break

            case "list",
                foreach(K,V:table = Account){
                    print(K+". ",V["Player",entity]:name()+" - indsat: "+V["PrinterCount",number]+"/4")
                }
                hideChat(1)
            break

            case "help",
                hideChat(1)
                print("fl - cpp - remove - add - set - payroll - msg - list - help")
            break

            default,
            print("Ukendt kommando: "+Args[1,string])
        }
    }
}

event playerDisconnected(Player:entity){
    if(Player:hasAccount()){
        Player:removeAccount()
        print("Fjernede en konto grundet personen er logget ud ("+Player:name()+")")
        concmd("play buttons/blip1.wav")
    }
}

event playerConnected(Player:entity){
    if(LoginMSG){
        sendMessage(Player,"Velkommen til Stavox! Kom og inds"+ae()+"t dine genstande hos money gang bank<3")
    }
}

Door = !CurUser:isValid()