import crafttweaker.item.IIngredient;
import crafttweaker.item.IItemStack;

function funcCrushingAdd(input as IIngredient, output as IIngredient, energy as long, output2 as IIngredient, chance as float){
    var longchance = chance *100;
    var stackOutputList = output.items as IItemStack[];
    var stackInputList = input.items as IItemStack[];
    var stackOutput2List = output2.items as IItemStack[];
    var stackOutput = stackOutputList[0];
    var stackInput = stackInputList[0];
    var stackOutput2 = stackOutput2List[0];
    var ncMultiplier = energy/8000;
    var trEnergy = energy/20;
    var trEnergy2 = energy/5;

    mods.mekanism.crusher.addRecipe(input, stackOutput);
    mods.metallurgyreforged.Crusher.addRecipe(input, stackOutput);
    mods.techreborn.grinder.addRecipe(stackOutput, input, 20, trEnergy);
    mods.techreborn.industrialGrinder.addRecipe(stackOutput, stackOutput2, null, null, input, null, 5, trEnergy2);
    mods.immersiveengineering.Crusher.addRecipe(stackOutput, input, energy, stackOutput2, chance);
    mods.nuclearcraft.manufactory.addRecipe([input, stackOutput, 1, ncMultiplier]);
    mods.ic2.Macerator.addRecipe(stackOutput, input);
    mods.enderio.SagMill.addRecipe([stackOutput, stackOutput2], [1, chance], input, null, energy);
    #for non-IIngredient handlers
    for loopinput in stackInputList{
        mods.thermalexpansion.Pulverizer.addRecipe(stackOutput, loopinput, energy, stackOutput2, longchance);
        mods.actuallyadditions.Crusher.addRecipe(stackOutput, loopinput, stackOutput2, longchance);
        mods.extrautils2.Crusher.add(stackOutput, loopinput, stackOutput2, chance);
        mods.integrateddynamics.MechanicalSqueezer.addRecipe(loopinput, stackOutput, 1, stackOutput2, chance);
    }
}
#overload #1
function funcCrushingAdd(input as IIngredient, output as IIngredient, energy as long){
    #var longchance = chance * 100;
    var stackOutputList = output.items as IItemStack[];
    var stackInputList = input.items as IItemStack[];
    #var stackOutput2List = output2.items as IItemStack[];
    var stackOutput = stackOutputList[0];
    var stackInput = stackInputList[0];
    #var stackOutput2 = stackOutput2List[0];
    var ncMultiplier = energy/8000;
    var trEnergy = energy/20;
    var trEnergy2 = energy/5;

    mods.mekanism.crusher.addRecipe(input, stackOutput);
    mods.metallurgyreforged.Crusher.addRecipe(input, stackOutput);
    mods.techreborn.grinder.addRecipe(stackOutput, input, 20, trEnergy);
    mods.techreborn.industrialGrinder.addRecipe(stackOutput, null, null, null, input, null, 5, trEnergy2);
    mods.immersiveengineering.Crusher.addRecipe(stackOutput, input, energy);
    mods.nuclearcraft.manufactory.addRecipe([input, stackOutput, 1, ncMultiplier]);
    mods.ic2.Macerator.addRecipe(stackOutput, input);
    mods.enderio.SagMill.addRecipe([stackOutput], [1], input, null, energy);
    #for non-IIngredient handlers
    for loopinput in stackInputList{
        mods.thermalexpansion.Pulverizer.addRecipe(stackOutput, loopinput, energy);
        mods.actuallyadditions.Crusher.addRecipe(stackOutput, loopinput);
        mods.extrautils2.Crusher.add(stackOutput, loopinput);
        mods.integrateddynamics.MechanicalSqueezer.addRecipe(loopinput, stackOutput);
    }
}

function funcAlloyingAdd(input1 as IIngredient, input2 as IIngredient, output as IIngredient, energy as long){
    var stackInput1List = input1.items as IItemStack[];
    var stackInput2List = input2.items as IItemStack[];
    var stackOutputList = output.items as IItemStack[];
    var stackInput1 = stackInput1List[0];
    var stackInput2 = stackInput2List[0];
    var stackOutput = stackOutputList[0];
    var ncMultiplier = energy/4000;
    var trEnergy = energy/20;

    mods.techreborn.alloySmelter.addRecipe(stackOutput, input1, input2, 20, trEnergy);
    mods.immersiveengineering.AlloySmelter.addRecipe(stackOutput, input1, input2, 200);
    mods.immersiveengineering.ArcFurnace.addRecipe(stackOutput, input1, null, 20, trEnergy, [input2]);
    mods.nuclearcraft.alloy_furnace.addRecipe([input1, input2, stackOutput, 1, ncMultiplier]);
    mods.enderio.AlloySmelter.addRecipe(stackOutput, [input1, input2], energy);
    for loopinput1 in stackInput1List{
        for loopinput2 in stackInput2List{
            mods.thermalexpansion.InductionSmelter.addRecipe(stackOutput, loopinput1, loopinput2, energy);
        }
    }
}


# #--------------------------------execute-------------------------------------------------#

# #crushing
funcCrushingAdd(<mysticalagriculture:ice_essence>, <minecraft:snowball> * 16, 4000, null, 0);
funcCrushingAdd(<mysticalagriculture:stone_essence>, <ic2:dust:15> * 8, 4000, null, 0);
funcCrushingAdd(<mysticalagriculture:dirt_essence>, <calculator:soil> * 6, 4000, null, 0);
funcCrushingAdd(<mysticalagriculture:nature_essence>, <thermalfoundation:material:816> * 2, 4000, null, 0);
funcCrushingAdd(<mysticalagriculture:wood_essence>, <thermalfoundation:material:800> * 16, 4000, null, 0);
# #alloying
funcAlloyingAdd(<metallurgy:shadow_iron_ingot> * 2, <metallurgy:lemurite_ingot>, <metallurgy:shadow_steel_ingot> * 3, 4000);
funcAlloyingAdd(<ore:ingotCopper> * 3, <ore:ingotZinc>, <metallurgy:brass_ingot> * 4, 4000);
funcAlloyingAdd(<metallurgy:deep_iron_ingot> * 3, <metallurgy:infuscolium_ingot>, <metallurgy:black_steel_ingot> * 4, 4000);
funcAlloyingAdd(<ore:ingotBronze> * 2, <ore:ingotIron>, <metallurgy:damascus_steel_ingot> * 3, 4000);
funcAlloyingAdd(<metallurgy:rubracium_ingot> * 2, <metallurgy:mithril_ingot>, <metallurgy:haderoth_ingot> * 3, 4000);
funcAlloyingAdd(<metallurgy:carmot_ingot>, <metallurgy:sanguinite_ingot>, <metallurgy:etherium_ingot> * 2, 4000);
funcAlloyingAdd(<metallurgy:kalendrite_ingot>, <ore:ingotPlatinum>, <metallurgy:amordrine_ingot> * 2, 4000);
funcAlloyingAdd(<ore:ingotSilver>, <ore:ingotMithril>, <ore:ingotQuicksilver> * 2, 4000);
funcAlloyingAdd(<ore:ingotSteel>, <ore:ingotInfuscolium>, <ore:ingotHepatizon> * 2, 4000);
funcAlloyingAdd(<ore:ingotEximite>, <ore:ingotMeutoite>, <ore:ingotDesichalkos> * 2, 4000);
funcAlloyingAdd(<ore:ingotPlatinum>, <ore:ingotOrichalcum>, <ore:ingotCelenegil> * 2, 4000);
funcAlloyingAdd(<ore:ingotGold>, <ore:ingotIron>, <ore:ingotAngmallen> * 2, 4000);
funcAlloyingAdd(<ore:ingotAdamantine>, <ore:ingotAtlarus>, <ore:ingotTartarite> * 2, 4000);
funcAlloyingAdd(<ore:ingotAlduorite>, <ore:ingotCeruclase>, <ore:ingotInolashite> * 2, 4000);
funcAlloyingAdd(<ore:ingotLutetium>, <ore:ingotOsmium>, <ore:ingotKrik> * 2, 4000);