HybridIVTC v1.2

Function HybridIVTC24(clip input)
{

sw     = input.width()
sh     = input.height()

left   = 0
top    = 908
right  = 1439
bottom = 980

lc     = int((     left)/4)*4
tc     = int((      top)/4)*4
rc     = int((sw- right)/4)*4
bc     = int((sh-bottom)/4)*4

mspal  = input.mt_lutspa(mode="absolute",
\                        expr="x " + string(left-1) + " >= x " + string(right +1) + " <= & y "
\                                  + string(top -1) + " >= y " + string(bottom+1) + " <= & & 255 0 ?", Y=3, U=1, V=1)
\             .RemoveGrain(11, -1)
mspac  = mspal.ConvertToY8().Spline36Resize(sw/2, sh/2, -0.50).ConvertToYV12()
mspa   = YtoUV(mspac, mspac, mspal)

pa24   = input
pa30   = input.Crop(lc, tc, -rc, -bc)

TFM30  = pa24.TFM(mode=5, PP=6, slow=2, scthresh=12.0, cthresh=9, MI=80)
TFM30b = mt_merge(TFM30, TFM30.BlankClip(), mspa.mt_binarize(255, Y=3, U=3, V=3), luma=false, Y=3, U=3, V=3)
IVTC24 = TFM30b.TDecimate(mode=1, hybrid=0, clip2=TFM30)

Bob60  = pa30.QTGMC(Preset="Very Slow").FrameCache(3)

super  = Bob60.SVSuper    ("{pel:2, gpu:1, scale:{up:2, down:4}}")
vector = super.SVAnalyse  ("{gpu:1, block:{w:16, h:16, overlay:2}, main:{levels:0, search:{type:4, coarse:{distance:-10}, bad:{sad:1500}}}, refine:[{thsad:250}]}")
Bob120 = Bob60.SVSmoothFps(super, vector, "{rate:{num:2, den:1, abs:false}, cubic:1, scene:{blend:false}}", url="www.svp-team.com", mt=GetMTMode(True))

Bob24  = Bob120.SelectEvery(5, 0).PointResize(sw, sh, -lc, -tc, sw, sh)

return mt_merge(IVTC24, Bob24, mspa.ChangeFPS(24000, 1001), luma=false, Y=3, U=3, V=3)

}


Function HybridIVTC120(clip input)
{

Bob60  = input.QTGMC(Preset="Slower").FrameCache(3)
#Bob60  = input.nnedi3(field=-2)

super  = Bob60.SVSuper    ("{pel:2, gpu:1, scale:{up:2, down:4}}")
vector = super.SVAnalyse  ("{gpu:1, block:{w:16, h:16, overlay:2}, main:{levels:0, search:{type:4, coarse:{distance:-10}, bad:{sad:1500}}}, refine:[{thsad:250}]}")
Bob120 = Bob60.SVSmoothFps(super, vector, "{rate:{num:2, den:1, abs:false}, cubic:1, scene:{blend:false}}", url="www.svp-team.com", mt=GetMTMode(True))

Bob24  = Bob120.SelectEvery(5, 0)

return Bob24

}

/*
 1t                  2t                  3t                  4t
           1b                  2b                  3b                  4b

 1t              2t              2t              3t              4t
         1b              2b              3b              4b              4b

 1t      1b      2t      2b      2t      3b      3t      4b      4t      4b

 1t1 1t2 1b1 1b2 2t1 2t2 2b1 2b2 2t1 2t2 3b1 3b2 3t1 3t2 4b1 4b2 4t1 4t2 4b1 4b2

 1t1                 2t2                 3b1                 4b2
*/