Wait4Rez.inc

| Wait4rez.inc v2.21
| tweaked for EQEmulator use
| Anything passed as a parameter will cause Wait4Rez to not consent netbots.

Sub Wait4Rez(NoConsent)
	| set this to the delay time you wish to use between looting items to handle the loot delay on PEQTGC
	/declare BagDelayTime int local 15
	/declare BagDelay bool local 0

	/if (!${Defined[NoConsent]}) {
		| consent all toons in NetBots
		/call consentNB
	}
	/echo Awaiting rez: auto-accepting, and looting my corpse
	| uncomment to memorize a spell set.
	| /if (${Me.MaxMana} && !${Me.Gem[1].Name.Length} && !${Me.Gem[2].Name.Length}) {
	|	/ssm somespellsetname
	|	/delay 5s
	| }
:rezmeffs
	/doevents
	| wait for the confirmation window.
	/delay 1s ${Window[ConfirmationDialogBox].Open}
	| loop if it is not open
	/if (!${Window[ConfirmationDialogBox].Open}) /goto :rezmeffs
	| click yes on the confirmation window
	/nomodkey /notify ConfirmationDialogBox Yes_Button leftmouseup
	/delay 2s
	/if (${Window[RespawnWnd].Open}) /nomodkey /notify RespawnWnd RW_OptionsList listselect 2
	/delay 1s
	/nomodkey /notify RespawnWnd RW_SelectButton leftmouseup
	/delay 2s
:zoneffs
	| corpse is a keyword and does not work right on EQEmu so drop the e to match on name
	/delay 5m ${Spawn[${Me}'s corps].ID}
	/delay 5s ${Spawn[${Me}'s corps].Distance}<100
	/if (${Spawn[${Me}'s corps].ID}) /target id ${Spawn[${Me}'s corps].ID}
	/delay 5s
	/delay 5s ${Target.ID}==${Spawn[${Me}'s corps].ID}
	/if (!${Target.CleanName.Find[${Me}'s Corpse]}) /goto :zoneffs
:corpsepull
	/echo corpsepull
	/if (${Target.Distance}>100 || !${Spawn[${Me}'s corps].ID}) /return
	/if (${Target.Distance}>20) /corpse
	/delay 5s ${Target.Distance}<20
	/loot
	/delay 5s ${Me.State.Equal[BIND]}
	/if (${Me.State.NotEqual[BIND]}) /goto :corpsepull
	/declare loottotal int local
:LootLag
	| /echo lootlag
	/varset loottotal ${Corpse.Items}
	/delay 1s ${loottotal}!=${Corpse.Items}
	/if (${loottotal}!=${Corpse.Items}) /goto :LootLag
	/declare i int local
	/for i 1 to ${loottotal}
:lootagain
		| /echo lootagain
		/if (${Corpse.Item[${i}].SizeCapacity} > 0) /varset BagDelay 1
		/itemnotify loot${i} rightmouseup
		/delay 10s !${Corpse.Item[${i}].ID} && !${Cursor.ID}
		/if (${BagDelay}) /delay ${BagDelayTime}
		/varset BagDelay 0
		/if (${Corpse.Item[${i}].ID}) /goto :lootagain
	/next i
	/nomodkey /notify LootWnd DoneButton leftmouseup
/return

sub consentNB
	/declare x int local
	/delay 1
	/for x 1 to ${NetBots.Counts}
		/consent ${NetBots.Client.Arg[${x}]}
		/delay 1s
	/next x
/return