#Requires AutoHotkey v2.0

;XButton1 : Back Button
;XButton2 : Forward Button
;WheelLeft/Right: HorizontalWheel
;WheelUp/Down: Mouse Wheel
;LButton, RButton, MButton: Standard Mouse Buttons
;^ : Control
;+ : Shift
;! : Alt
;# : Win

;Keyhistory ; Display the history info in a window

; #######################################################################
; BACK BUTTON
; #######################################################################

; Back down = Control down
XButton1::
{
    Send "{Control Down}"
}

; Back Up = Control Up & Send Back as long as no other hotkey was pressed (if last key was Back)
XButton1 Up::
{
    Send "{Control Up}"
    ; Send Back only when the last button pressed was Back as well
    if (A_PriorKey = "XButton1")
    {
        Send "{XButton1}"
    }
}

; Back + RMouse = Control + F1
; "~" Prevents this chord from interfering with XButton1:: event
~XButton1 & RButton::
{
    Send "{Control Up}"
    Send "+{F1}"
}

; Back + MMmouse = (Navigate previous tab)
; "~" Prevents this chord from interfering with XButton1:: event
~XButton1 & MButton::
{
    Send "{Control Up}"
    Send "^{Tab}"
}

; #######################################################################
; FORWARD BUTTON
; #######################################################################

; Forward Down = Shift Down
XButton2::
{
    Send "{Shift Down}"
}

; Foward Up = Shift Up & Send Foward as long as no other hotkey was pressed (if last key was Foward)
XButton2 Up::
{
    Send "{Shift Up}"
    if (A_PriorKey = "XButton2")
    {
        Send "{XButton2}"
    }
}

; Forward + RMouse = F8
; "~" Prevents this chord from interfering with XButton2:: event
~XButton2 & RButton::
{
    Send "{Shift Up}"
    Send "{F8}"
}

; Forward + MMmouse = (Navigate previous tab)
; "~" Prevents this chord from interfering with XButton2:: event
~XButton2 & MButton::
{
    Send "{Shift Up}"
    Send "^+{Tab}"
}

return