<stdin>

script SPREE_FORMATSTR (int which, int killerPln, int killedPln)
{
    int msgString = "";
    int preString = spreeMessages[which];
    int preLen =    StrLen(preString);
    int preChar, preNChar, i;

    int killerGender = GetPlayerInfo(killerPln, PLAYERINFO_GENDER);
    int killedGender = GetPlayerInfo(killedPln, PLAYERINFO_GENDER);

    //Log(s:"--> (", d:which, s:", \"", s:preString, s:"\c-\")");

    for (i = 0; i < preLen; i++)
    {
        preChar = GetChar(preString, i);
        preNChar = GetChar(preString, min(i+1, preLen-1));

        if (preChar == '\\')
        {
            i++;

            switch (preNChar)
            {
              case 'c':
                msgString = StrParam(s:msgString, c:28);
                break;

              default:
                msgString = StrParam(s:msgString, c:preChar, c:preNChar);
                break;
            }
        }
        else if (preChar == '%')
        {
            i++;
            switch (preNChar)
            {
              case 'k':
                msgString = StrParam(s:msgString, n:killerPln+1);
                break;

              case 'o':
                msgString = StrParam(s:msgString, n:killedPln+1);
                break;

              case 'g':
                msgString = StrParam(s:msgString, s:genders_g[killedGender]);
                break;

              case 'h':
                msgString = StrParam(s:msgString, s:genders_h[killedGender]);
                break;

              case 'p':
                msgString = StrParam(s:msgString, s:genders_p[killedGender]);
                break;

              case '%':
                msgString = StrParam(s:msgString, s:"%");
                break;

              default:
                msgString = StrParam(s:msgString, c:preChar, c:preNChar);
                break;
            }
        }
        else
        {
            msgString = StrParam(s:msgString, c:preChar);
        }
    }

    SetResultValue(msgString);
}