@echo on

set WIMFILE=E:\sources\install.wim
set WIMINDX=0

set BCDLANG=ja-jp

set VHDXFILE=D:\Insider.vhdx
set VHDXSIZE=40000
set DRIVER=R
set DRIVES=S
set DRIVEW=W

REM イメージファイルの確認
if exist %WIMFILE% (goto SELECT_INDX)
echo イメージファイルが見つかりません
exit /b 1

:SELECT_INDX
REM イメージインデックス番号の選択
dism /get-wiminfo /wimfile:"%WIMFILE%"
set /P WIMINDX="デプロイするインデックス番号を入力して下さい: "
set /A WIMINDX=%WIMINDX%*1
if %WIMINDX% gtr 0 (goto CREATE_VHDX)
exit /b 2

:CREATE_VHDX
REM 仮想ディスクを作成し、ボリュームをアタッチする
REM パーティションサイズの目安はMicrosoft Docsによる
REM https://docs.microsoft.com/en-us/windows-hardware/manufacture/desktop/configure-uefigpt-based-hard-drive-partitions
(
echo create vdisk file="%VHDXFILE%" maximum=%VHDXSIZE% type=expandable
echo select vdisk file="%VHDXFILE%"
echo attach vdisk
echo clean
echo convert gpt

echo create partition primary size=1000
echo assign letter=%DRIVER%
echo format quick fs=ntfs
echo set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
echo gpt attributes=0x8000000000000001

echo create partition efi size=260
echo assign letter=%DRIVES%
echo format quick fs=fat32

echo create partition msr size=16

echo create partition primary
echo format quick fs=ntfs
echo assign letter=%DRIVEW%

echo list partition

echo exit
) | diskpart

:DEPLOY_WIN
REM Windowsをデプロイする
dism /Apply-Image /ImageFile:"%WIMFILE%" /Index:%WIMINDX% /ApplyDir:%DRIVEW%:\
bcdboot %DRIVEW%:\Windows /l %BCDLANG% /s %DRIVES%:
mkdir %DRIVER%:\Recovery\WindowsRE
xcopy /h %DRIVEW%:\Windows\System32\Recovery\Winre.wim %DRIVER%:\Recovery\WindowsRE\
ReAgentc /setreimage /path %DRIVER%:\Recovery\WindowsRE\Winre.wim /target %DRIVEW%:\Windows
ReAgentc /info /target %DRIVEW%:\Windows

:UNMOUNT_VHDX
REM ボリュームをアンマウントし、仮想ディスクをデタッチする
(
echo select volume=%DRIVER%
echo remove letter=%DRIVER%

echo select volume=%DRIVES%
echo remove letter=%DRIVES%

echo select volume=%DRIVEW%
echo remove letter=%DRIVEW%

echo select vdisk file="%VHDXFILE%"
echo detach vdisk

echo exit
) | diskpart