alias recent {
  window -c @modified
  window -c @modtemp
  var %mrcFiles,%aFile,%currentItems,%aCurrentItem,%aCurrentItemTime,%timeString
  window -ln -t40 @modified
  window -lhs @modtemp
  CreateCurrentList
  %currentItems = $hget(current,0).item
  while %currentItems {
    %aCurrentItem = $hget(current,%currentItems).item
    %aCurrentItemTime = $hget(current,%acurrentItem)
    %timeString = $asctime(%aCurrentItemTime,dd/mm/yyyy HH:nn:ss)
    ; XOR to give a reverse-sort
    aline @modtemp $xor(%acurrentItemTime,-1) $tab %aCurrentItem $tab %timestring
    dec %currentItems
  }
  filter -wk @modtemp StripAsctime *
  window -a @modified
  :error
  hfree current
  window -c @modtemp
}

alias StripAsctime {
  var %line = $deltok($1,1,9)
  aline @modified %line
}

alias CreateCurrentList {
  hmake current 20
  var %mrcFiles, %aFile
  %mrcFiles = $script(0)
  while %mrcFiles {
    %aFile = $script(%mrcFiles)
    hadd current %afile $file(%afile).mtime
    dec %mrcFiles
  }
}

menu @modified {
  dclick: {
    var %selected = $line(@modified,$1,1)
    tokenize 32 %selected
    var %file = $1
    var %nopath = $nopath(%file)
    clipboard %nopath
    showmirc -s
    sendkeys % $+ r $+ % $+ r $+ ^ $+ m $+ ^ $+ v $+ {enter}
  }
}


alias -l sendkeys {
  var %object = sendkeys $+ $ticks
  .comopen %object WScript.Shell
  if ($com(%object)) { .comclose %object $com(%object,SendKeys,3,bstr,$1-) }
}


alias tab return $chr(9)