Janilabo | TSAQuickSort() [Simba]

procedure __TSA_LH_QS(TSA: TStringArray; Lo, Hi: Integer);
var
  L, R: Integer;
  P, T: string;
begin
  P := TSA[((Lo + Hi) div 2)];
  L := Lo;
  R := Hi;
  repeat
    while (TSA[L] < P) do
      Inc(L);
    while (TSA[R] > P) do
      Dec(R);
    if (L <= R) then
    begin
      T := TSA[L];
      TSA[L] := TSA[R];
      TSA[R] := T;
      Inc(L);
      Dec(R);
    end;
  until (L > R);
  if (R > Lo) then
    __TSA_LH_QS(TSA, Lo, R) ;
  if (L < Hi) then
    __TSA_LH_QS(TSA, L, Hi) ;
end;

procedure __TSA_HL_QS(TSA: TStringArray; Lo, Hi: Integer);
var
  L, R: Integer;
  P, T: string;
begin
  P := TSA[((Lo + Hi) div 2)];
  L := Lo;
  R := Hi;
  repeat
    while (TSA[L] > P) do
      Inc(L);
    while (TSA[R] < P) do
      Dec(R);
    if (L <= R) then
    begin
      T := TSA[L];
      TSA[L] := TSA[R];
      TSA[R] := T;
      Inc(L);
      Dec(R);
    end;
  until (L > R);
  if (R > Lo) then
    __TSA_HL_QS(TSA, Lo, R) ;
  if (L < Hi) then
    __TSA_HL_QS(TSA, L, Hi) ;
end;

procedure TSAQuickSort(TSA: TStringArray; order: (so_LowToHigh, so_HighToLow));
var
  h: Integer;
begin
  h := High(TSA);
  if (h > 0) then
  case order of
    so_LowToHigh: __TSA_LH_QS(TSA, 0, h);
    so_HighToLow: __TSA_HL_QS(TSA, 0, h);
  end;
end;

var
  TSA: TStringArray;

begin
  TSA := ['Apple', 'Orange', 'Lemon', 'Banana', 'Pear'];
  TSAQuickSort(TSA, so_HighToLow); // Reversed.
  WriteLn(ToStr(TSA));
  TSAQuickSort(TSA, so_LowToHigh); // Default.
  WriteLn(ToStr(TSA));
end.