gtkhash PKGBUILD

pkgbase=gtkhash
pkgname=(gtkhash gtkhash-nemo gtkhash-nautilus gtkhash-thunar gtkhash-caja)
pkgver=1.1.1
pkgrel=1
pkgdesc="A GTK+ utility for computing message digests or checksums"
arch=('i686' 'x86_64' 'mips64el')
url="http://gtkhash.sourceforge.net/"
license=('GPL')
makedepends=('intltool' 'librsvg' 'nemo' 'libnautilus-extension' 'thunar' 'caja') # ← remove FMs here!
depends=('dconf' 'nettle' 'gtk3')
source=("https://github.com/tristanheaven/gtkhash/releases/download/v$pkgver/$pkgname-$pkgver.tar.xz")
sha256sums=('a18c09a6af5b26c79bda81ab8a1835679fefbf2b87f1df4858c42ad45729f6bf')

prepare() {
  if [[ "`pkg-config --modversion thunarx-3 2>/dev/null`" != '' && $( vercmp '1.7.0' "`pkg-config --modversion thunarx-3 2>/dev/null`" ) -ge 0 ]] ; then
    cd gtkhash-$pkgver
    find . -type f -exec sed -i 's:thunarx-2:thunarx-3:g' '{}' \;

    autoreconf -v -i
  fi
}
build() {
  cd gtkhash-$pkgver

  ./configure --prefix=/usr --disable-schemas-compile --enable-gtkhash \
              --enable-linux-crypto --enable-nettle --disable-blake2 --with-gtk=3.0 \
              --enable-nemo --enable-nautilus --enable-thunar --enable-caja # ← remove FMs here!
  make
}

package_gtkhash() {
  make -C gtkhash-$pkgver DESTDIR="$pkgdir/" install

  # remove filemanager plugins
  rm -rf "$pkgdir"/usr/lib
}

package_gtkhash-nemo() {
  pkgdesc+=' (Nemo filemanager plugin)'
  depends=('gtkhash' 'nemo')

  make -C gtkhash-$pkgver/src/nautilus DESTDIR="$pkgdir/" install
  # remove other filemanager plugins
  rm -rf "$pkgdir"/usr/lib/{thunarx-*,nautilus,caja}
}

package_gtkhash-nautilus() {
  pkgdesc+=' (Nautilus filemanager plugin)'
  depends=('gtkhash' 'nautilus')

  make -C gtkhash-$pkgver/src/nautilus DESTDIR="$pkgdir/" install
  # remove other filemanager plugins
  rm -rf "$pkgdir"/usr/lib/{thunarx-*,caja,nemo}
}

package_gtkhash-thunar() {
  pkgdesc+=' (Thunar filemanager plugin)'
  depends=('gtkhash')
  if [[ "`pkg-config --modversion thunarx-3 2>/dev/null`" != '' ]] ; then
    depends+=('thunar>=1.7.0')
  else
    depends+=('thunar<1.7.0')
  fi

  make -C gtkhash-$pkgver/src/nautilus DESTDIR="$pkgdir/" install
  # remove other filemanager plugins
  rm -rf "$pkgdir"/usr/lib/{nautilus,caja,nemo}
}

package_gtkhash-caja() {
  pkgdesc+=' (Caja filemanager plugin)'
  depends=('gtkhash' 'caja')

  make -C gtkhash-$pkgver/src/nautilus DESTDIR="$pkgdir/" install
  # remove other filemanager plugins
  rm -rf "$pkgdir"/usr/lib/{thunarx-*,nautilus,nemo}
}