mapftp.vbs

Const NETHOOD = &H13& ' Create under NetHood locations

Set objWSHShell = CreateObject("Wscript.Shell")
Set objShell = CreateObject("Shell.Application")
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objShell.Namespace(NETHOOD)
Set objFolderItem = objFolder.Self

If WScript.Arguments.Count < 2 then
    WScript.Echo "Missing parameters"
    WSCript.Quit
End If

strUsername = WScript.Arguments(0)
strPassHash = WScript.Arguments(1)

strNetHood = objFolderItem.Path

strShortcutName = "BankVault Files"
strShortcutPath = "ftp://" & strUsername & ":" & strPassHash & "@127.0.0.1:8021/"

strShareFolder = strNetHood & "\" & strShortcutName & "\"
strShortcut = strShareFolder & "target.lnk"

If objFSO.FolderExists(strShareFolder)=True Then
    Set folderShare = objFSO.GetFolder(strShareFolder)
    folderShare.Delete(True)
End If

objFSO.CreateFolder(strShareFolder)

strDesktopIni = strShareFolder & "\Desktop.ini"

WriteFile strDesktopIni, "[.ShellClassInfo]", 2
WriteFile strDesktopIni, "CLSID2={0AFACED1-E828-11D1-9187-B532F1E9575D}", 8
WriteFile strDesktopIni, "Flags=2", 8

Set objShortcut = objWSHShell.CreateShortcut(strShortcut)
objShortcut.TargetPath = strShortcutPath
objShortcut.WindowStyle = 1
objShortcut.Save

Set fileShortcut = objFSO.GetFile(strShortcut)
fileShortcut.attributes = 36 ' S(4) + A(32)

Set folderShare = objFSO.GetFolder(strShareFolder)
folderShare.attributes = 1 ' R(1)

Function WriteFile(Filename, Text, AccessType)
    Dim fs, f
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.OpenTextFile(FileName, AccessType, true)
    f.WriteLine Text
    f.Close
End Function