OUTPUT_FORMAT(binary)
OUTPUT_ARCH(sh3)

/* Entry point.  Not really important here, since doing binary output */
ENTRY(initialize)

MEMORY
{
        /* Loads code at 300000, skips g3a header */
        rom (rx) : o = 0x00300000, l = 512k
        ram (rwx) : o = 0x08100004, l = 64k  /* pretty safe guess */
}

SECTIONS
{
        /* Code, in ROM */
        .text : {
                *(.pretext)     /* init stuff */
                *(.text)
                *(.text.*)
        } > rom

        /* Read-only data, in ROM */
        .rodata : {
                *(.rodata)
                *(.rodata.*)
        } > rom

        /* RW initialized data, VMA in RAM but LMA in ROM */
        .data : {
                _bdata = . ;
                *(.data)
                *(.data.*);
                _edata = . ;
        } >rom AT>ram

        /* Uninitialized data (fill with 0), in RAM */
        .bss : {
                _bbss = . ;
                *(.bss) *(COMMON);
                _ebss = . ;
        } >ram
}