# $Id$
# Maintainer: Juergen Hoetzel <juergen@archlinux.org>
# Contributor: Renchi Raju <renchi@green.tam.uiuc.edu>

pkgname=emacs
pkgver=25.1
pkgrel=4
pkgdesc="The extensible, customizable, self-documenting real-time display editor"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/emacs/emacs.html"
license=('GPL3')
depends=('gpm' 'libotf' 'm17n-lib' 'gtk2' 'hicolor-icon-theme' 'gconf' 'desktop-file-utils' 'alsa-lib' 'gnutls')
source=(ftp://ftp.gnu.org/gnu/emacs/$pkgname-$pkgver.tar.xz)
md5sums=( 'SKIP' )

build() {
  cd "$srcdir"/$pkgname-$pkgver
  export REL_ALLOC=no
  export ac_cv_lib_gif_EGifPutExtensionLast=yes
  ./configure \
    --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib --localstatedir=/var \
    --program-transform-name='s/^ctags$/ctags.emacs/' \
    --without-all --disable-acl --with-xml2 --with-zlib --with-gnutls \
    --with-dbus --with-xft --with-libotf --with-xim --with-m17n-flt \
    --without-gconf --without-sound --with-x-toolkit=gtk2
  make
}

package() {
  cd "$srcdir"/$pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # remove conflict with ctags package
  # mv "$pkgdir"/usr/bin/{ctags,ctags.emacs}
  # mv "$pkgdir"/usr/share/man/man1/{ctags.1.gz,ctags.emacs.1}

  # fix user/root permissions on usr/share files
  find "$pkgdir"/usr/share/emacs/$pkgver -exec chown root:root {} \;
  # fix perms on /var/games
  chmod 775 "$pkgdir"/var/games
  chmod 775 "$pkgdir"/var/games/emacs
  chmod 664 "$pkgdir"/var/games/emacs/*
  chown -R root:games "$pkgdir"/var/games
}