//EDO do circuito: v'' + 14v' + 49v = 245*sin(120t)
//Transformamos a edo de ordem 2 acima para o sistema:
// v' = y
// y' = 245sin(120t) -49v -14y

//Colocamos o sistema na forma matricial:
//      dphi/dt = A*phi + C
//onde phi= [v y], A=[0 1; -49 -14], C=[0 245*sin(120t)]

//Temos que:
// d[v y]/dt = [0 1; -49 -14]*[v y] + [0 245*sin(120t)]
//Logo:
// d[v y]/dt = [y -49v-14y+245*sin(120t)]

function dphi = F(t, V)  //Definimos dphi/dt. V é uma lista, onde V(1)=v e V(2)=v'
    //A = [0 1; -49 -14];
        //C = [0; 245*sin(120*t)];
        //dphi = (A*[V(1); V(2)] + C);
    dphi = [V(2); -49*V(1)-14*V(2)+245*sin(120*t)]
endfunction

clf; //Limpa janela de graficos.

t0 = 0; //Tempo inicial.
t=t0:0.002:2; //Intervalo de tempo no qual a solucao será computada.
v0 = [0;0]; //Condicoes iniciais: Vc(0)=0; Ic(0)=0 <=> Q'(0)=0; Vc'=Q'/C => Vc'(0)=0

v = ode(v0,t0,t,F); //Calculamos a voltagem Vc do capacitor.
plot(t, v(1,:), "r"); //Plotando o grafico em cor vermelha.

xlabel(["Tempo t";"(s)"]);
ylabel(["Voltagem do capacitor Vc"; "(Volt)"]);
xtitle("Solucao Numerica - RLC em Serie");

set(gca(),"data_bounds",matrix([0,2,-0.04,0.14],2,-1)); //Definimos os limites dos eixos X e Y.