REM PGPASSWORD - superuser password
REM postgresFromDir - old server's installation directory
REM postgresToDir - new server's installation directory
REM postgresHost - old and new servers' host
REM postgresFromPort - old server's port
REM postgresToPort - new server's port
REM databaseName - name of the database you want to migrate
set PGPASSWORD=sdl34kapht
set postgresFromDir=C:\Program Files\PostgreSQL\9.0
set postgresToDir=C:\Program Files\PostgreSQL\9.2
set postgresHost=127.0.0.1
set postgresFromPort=10090
set postgresToPort=10092
set databaseName=moloco

REM Reloading PostgreSQL configuration
"%postgresFromDir%\bin\pg_ctl" -D "%postgresFromDir%\data" reload

REM Dumping roles
"%postgresFromDir%\bin\pg_dumpall" --host=%postgresHost% --port=%postgresFromPort% --database=%databaseName% --file="%postgresFromDir%\roles.backup" --username=postgres --roles-only

REM Adding CREATE DATABASE SQL roles dump
echo CREATE DATABASE %databaseName%; >> "%postgresFromDir%\roles.backup"


REM Dumping database
"%postgresFromDir%\bin\pg_dump" --create --host=%postgresHost% --port=%postgresFromPort% --format=tar --file="%postgresFromDir%\%databaseName%.backup" --username=postgres %databaseName%

REM Importing roles to the new PostgreSQL server. Assuming that superuser name and password are the same
REM Also creating new database
"%postgresToDir%\bin\psql" --username=postgres -f "%postgresFromDir%\roles.backup" --host=%postgresHost% --port=%postgresToPort% postgres

REM Importing this database to new PostgreSQL server. Assuming that superuser name and password are the same
"%postgresToDir%\bin\pg_restore" --dbname=%databaseName% --format=tar --username=postgres --host=%postgresHost% --port=%postgresToPort% "%postgresFromDir%\%databaseName%.backup"