SUMMARY = "Simple terminal emulator based on linux kernel mode setting (KMS)."
DESCRIPTION = "\
    Kmscon is a simple terminal emulator based on linux kernel mode setting \
    (KMS). It is an attempt to replace the in-kernel VT implementation with \
    a userspace console. \
"
HOMEPAGE = "https://github.com/kmscon/kmscon"
BUGTRACKER = "https://github.com/kmscon/kmscon/issues"
CVE_PRODUCT = "kmscon"

SECTION = "graphics"

LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://COPYING;md5=6d4602d249f8a3401040238e98367d9e"

DEPENDS = "\
    libtsm \
    libxkbcommon \
    udev \
"

SRC_URI = "git://github.com/kmscon/kmscon;branch=main;protocol=https"
SRCREV = "7d46650dbb0826f9b89de42f879be879391c14fd"

inherit meson pkgconfig
inherit_defer ${@bb.utils.contains("DISTRO_FEATURES", "systemd", "systemd", "", d)}

PACKAGECONFIG_GL ?= "${@bb.utils.filter('DISTRO_FEATURES', 'opengl', d)}"
PACKAGECONFIG ??= "${PACKAGECONFIG_GL}"

PACKAGECONFIG[backspace_sends_delete] = "-Dbackspace_sends_delete=true, -Dbackspace_sends_delete=false"
PACKAGECONFIG[font_pango] = "-Dfont_pango=enabled, -Dfont_pango=disabled, pango"
PACKAGECONFIG[multi_seat] = "-Dmulti_seat=enabled, -Dmulti_seat=disabled, systemd"
PACKAGECONFIG[opengl] = "-Dmulti_seat=enabled -Drenderer_gltex=enabled, -Dmulti_seat=disabled -Drenderer_gltex=disabled, libdrm virtual/libgles2 virtual/libgbm"
PACKAGECONFIG[session_dummy] = "-Dsession_dummy=enabled, -Dsession_dummy=disabled"
PACKAGECONFIG[session_terminal] = "-Dsession_terminal=enabled, -Dsession_terminal=disabled"
PACKAGECONFIG[video_drm2d] = "-Dvideo_drm2d=enabled, -Dvideo_drm2d=disabled, libdrm"
PACKAGECONFIG[video_fbdev] = "-Dvideo_fbdev=enabled, -Dvideo_fbdev=disabled, xf86-video-fbdev"

EXTRA_OEMESON:append = " \
    -Delogind=disabled \
    -Dextra_debug=false \
    -Dfont_unifont=enabled \
    -Dtests=false \
"

SYSTEMD_SERVICE:${PN} = "kmscon.service"
FILES:${PN} += "${systemd_system_unitdir}/[email protected]"

do_install:append() {
    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'false', 'true', d)}; then
        rm -rf ${D}${libdir}/systemd
    fi
}

RDEPENDS:${PN} = "xkeyboard-config"

BBCLASSEXTEND = "native nativesdk"