integer Copper;
integer Silver;
integer Gold;
integer Platinum;
integer Mithril;
integer Chan = 1;  //Used for listen channel
integer Listen;  //used for controlling listen
string Texture = "6d93ac56-b349-2ceb-2e4c-ddc632825b17";
list Offsets = [<0,.45,0>,<0,.35,0>,<0,.25,0>,<0,.15,0>,<0,.05,0>,<0,-.05,0>,<0,-.15,0>,<0,-.25,0>,<0,-.35,0>,<0,-.45,0>];

SetText()
{
    //We won't actually set floaty text, or change texture, all do is adjust offsets
    //We will set text starting from Copper to Mith
    llSetLinkPrimitiveParamsFast(13,[PRIM_TEXTURE,3,Texture,<.5,.1,0>,llList2Vector(Offsets,Copper),0]);
    llSetLinkPrimitiveParamsFast(10,[PRIM_TEXTURE,3,Texture,<.5,.1,0>,llList2Vector(Offsets,Silver),0]);
    integer G4 = llFloor(Gold/1000);
    integer G3 = llFloor((Gold-(G4*1000))/100);
    integer G2 = llFloor(((Gold-(G4*1000))-(G3*100))/10);
    integer G1 = Gold - (G4*1000) - (G3*100) - (G2*10);
    //llOwnerSay((string) G4 + (string) G3 + (string) G2 + (string) G1);
    llSetLinkPrimitiveParamsFast(7,[PRIM_TEXTURE,3,Texture,<.5,.1,0>,llList2Vector(Offsets,G1),0]);
    llSetLinkPrimitiveParamsFast(6,[PRIM_TEXTURE,3,Texture,<.5,.1,0>,llList2Vector(Offsets,G2),0]);
    llSetLinkPrimitiveParamsFast(5,[PRIM_TEXTURE,3,Texture,<.5,.1,0>,llList2Vector(Offsets,G3),0]);
    llSetLinkPrimitiveParamsFast(4,[PRIM_TEXTURE,3,Texture,<.5,.1,0>,llList2Vector(Offsets,G4),0]);
}

Check()
{
    if (Copper >= 10)
    {
        Silver += Copper / 10;
        Copper = Copper % 10;
    }
    if (Silver >= 10)
    {
        Gold += Silver / 10;
        Silver = Silver % 10;
    }

    @CheckCopper;
    if (Copper < 0)
    {
        Silver -= 1;
        Copper += 10;
        jump CheckCopper;  //Do this to check again, in case Copper is *still* less than 0
    }
    @CheckSilver;
    if (Silver < 0)
    {
        Gold -= 1;
        Silver += 10;
        jump CheckSilver;  //Check to make sure Silver is not still less than 0
    }

    if (Gold < 0)
    {
        Gold = 0;
        Silver = 0;
        Copper = 0;
        llOwnerSay("You are broke now");
    }
}

default
{
    state_entry()
    {
        Listen = llListen(Chan,"",llGetOwner(),"");
    }
    touch_start(integer Num_Detected)
    {
        if(llDetectedLinkNumber(0) == 2) ++Gold;
        if(llDetectedLinkNumber(0) == 3) --Gold;
        if(llDetectedLinkNumber(0) == 8) --Silver;
        if(llDetectedLinkNumber(0) == 9) ++Silver;
        if(llDetectedLinkNumber(0) == 11) ++Copper;
        if(llDetectedLinkNumber(0) == 12) --Copper;
        Check();
        SetText();
    }
    listen(integer Channel, string Name, key ID, string Message)
    {
        if (llToLower(llGetSubString(Message,0,6)) == "mithril")
        {
            Gold += (integer)llGetSubString(Message,7,-1)*100;
        }
        if (llToLower(llGetSubString(Message,0,7)) == "platinum")
        {
            Gold += (integer)llGetSubString(Message,8,-1)*10;
        }
        if (llToLower(llGetSubString(Message,0,3)) == "gold")
        {
            Gold += (integer)llGetSubString(Message,4,-1);
        }
        if (llToLower(llGetSubString(Message,0,5)) == "silver")
        {
            Silver += (integer)llGetSubString(Message,6,-1);
        }
        if (llToLower(llGetSubString(Message,0,5)) == "copper")
        {
            Copper += (integer)llGetSubString(Message,6,-1);
        }
        Check();
        SetText();
    }
}