# Maintainer: tuxayo < victor (replace by @) tuxayo DOT net >
# Contributor: Lex Black <autumn-wind at web dot de>
# Contributor: fnord0 < fnord0 AT riseup DOT net >
# Contributor: Andrejs Mivreņiks <gim at fastmail dot fm>
# Contributor: tuxayo < victor (replace by @) tuxayo DOT net >
# Contributor: Jaap <jaap.aarts1@gmail.com>

pkgname=webgoat
pkgver=8.1.0
pkgrel=1
pkgdesc='Deliberately insecure J2EE web application designed to teach web application security concepts'
arch=('i686' 'x86_64')
url='https://github.com/WebGoat/WebGoat'
license=('GPL2')
depends=('java-runtime=11')
makedepends=('maven' 'git')
optdepends=('webscarab: proxy for analyzing applications that communicate using the HTTP and HTTPS protocols, used to help solve most WebGoat lessons'
            'paros: MitM HTTP/HTTPS proxy, spider, XSS and injection scanner + more, used to help solve WebGoat lessons')
source=("https://github.com/WebGoat/WebGoat/archive/refs/tags/v$pkgver.zip"
        "webgoat.sh"
        "git+https://github.com/WebGoat/WebGoat-Lessons.git")
sha256sums=('5655798f738617cf25fd6a4e8b65212d5b956fa269a1e9f9facee50ec3509e81'
            '3615a09c64eb07709bede9b22782bedeffe7c7097cde1c6bcc2a07adcd28712c'
            'SKIP')
install="$pkgname.install"

prepare() {
  cd "$srcdir/WebGoat-Lessons"
  git checkout master

  # Needed to fix issues with maven
  echo "<settings><localRepository>$srcdir</localRepository></settings>" > "$srcdir/maven-settings.xml"
}

build() {
  cd "$srcdir/WebGoat-$pkgver"
  mvn package
}

package() {
  cd "$srcdir/WebGoat-$pkgver"
  install -Dm755 ../webgoat.sh "$pkgdir/usr/bin/webgoat"
  install -d "$pkgdir/opt/$pkgname"
  install -Dm644 "webgoat-server/target/webgoat-server-v$pkgver.jar" "$pkgdir/opt/$pkgname/webgoat.jar"
}