picard script

$set(_startswithdate,
	$if(
		$rsearch(%album%,\(\\A\\d{4}\(-\\d{2}\){0\,2}: \)),
		1,
	)
)

$set(_livestartswithdate,
	$if(
		$and(
			%_startswithdate%,
			$rsearch(%releasetype%,live)
		),
		1,
	)
)

$set(_broadcaststartswithdate,
	$if(
		$and(
			%_startswithdate%,
			$inmulti(%releasetype%,broadcast)
		),
		1,
	)
)

$if($not(%_placed%),
	$if($inmulti(%releasetype%,audiobook),
		$set(_placed,1)
		Audiobooks/
	)
)
$if($not(%_placed%),
	albums by artist/
)
$if(
	$eq($left($if2(%albumartist%,%artist%),4),The ),
		$right($if2(%albumartist%,%artist%), $sub($len($if2(%albumartist%,%artist%)),4))\, The,
	$if2(%albumartist%,%artist%)
)
$if(
	%artist_disambig%,
		 \(%artist_disambig%\),
)/

$if($not(%_placed%),
	$if($eq(%releasestatus%,bootleg),
		$if($inmulti(%releasetype%,live),
			$set(_placed,1)
			Live Bootlegs/,
			$if($inmulti(%releasetype%,demo),
				$set(_placed,1)
				Bootleg Demos/,
				Bootlegs/
			)
		)
	)
)
$if($eq(%releasestatus%,promotion),
	Promotional/
)

$if($not(%_placed%),
	$if(
		$and(
			$not(%_primaryreleasetype%),
			$not($eq(%album%,[non-album tracks]))
		),
		$set(_placed,1)
		Unspecified/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,interview),
		$set(_placed,1)
		Interviews/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,spokenword),
		$set(_placed,1)
		Spokenword/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,demo),
		$if($inmulti(%releasetype%,single),
			$set(_placed,1)
			Demo Singles/,
			$if($inmulti(%releasetype%,ep),
				$set(_placed,1)
				Demo EPs/,
				$set(_placed,1)
				Demos/
			)
		)
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,dj-mix),
		$set(_placed,1)
		DJ-Mixes/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,mixtape/street),
		$set(_placed,1)
		Mixtapes/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,remix),
		$set(_placed,1)
		Remixes/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,soundtrack),
		$set(_placed,1)
		Soundtracks/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,broadcast),
		$set(_placed,1)
		Broadcasts/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,other),
		$set(_placed,1)
		Other/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,single),
		$set(_placed,1)
		Singles/
	)
)
$if($not(%_placed%),
	$if(
		$and(
			$inmulti(%releasetype%,live),
			$inmulti(%releasetype%,album)
		),
		$set(_placed,1)
		Live Albums/
	)
)
$if($not(%_placed%),
	$if(
		$and(
			$inmulti(%releasetype%,live),
			$inmulti(%releasetype%,ep)
		),
		$set(_placed,1)
		Live EPs/
	)
)
$if($not(%_placed%),
	$if(
		$and(
			$inmulti(%releasetype%,compilation),
			$ne(%albumartist%,Various Artists)
		),
		$set(_placed,1)
		Compilations/
	)
)
$if($not(%_placed%),
	$if($inmulti(%releasetype%,ep),
		$set(_placed,1)
		EPs/
	)
)
$if(
	$not(
		$or(%_livestartswithdate%,%_broadcaststartswithdate%)
	),
		%originaldate% ,
)
%album%
$if(
	%disambig%,
		 \(%disambig%\),
	$if(
		%_releasecomment%,
			 \(%_releasecomment%\),
	)
)/
$if(
	$gt(%totaldiscs%,1),
		Disc %discnumber%
		$if(
			%discsubtitle%,
				: %discsubtitle%,
		)/,
)
$if(
	$gt(%totaltracks%,99),
		$num(%tracknumber%,3) ,
	$num(%tracknumber%,2)
)
$if(
	$ne(%albumartist%,%artist%),
		%artist% - ,
)
$if(
	$and(
		%_recordingcomment%,
		$eq(%album%,[non-album tracks])
	),
	%title% \(%_recordingcomment%\),
	%title%
)