@echo off
setlocal
::
:: config
::
set url=http://go.microsoft.com/fwlink/?LinkID=121721
::
::end config
::
for %%a in (86 64) do call:init x%%a
del /f /q log.tmp
del /f /q sig.tmp
GOTO:EOF

:init
::parameters MachineType[x86|x64]
if not exist %1 mkdir %1
if exist %1\mpam-fe.exe (
        call:update %1 %~dp0%1\mpam-fe.exe
    ) else (
        call:proc_full %1 "%url%&arch=%1"
    )
GOTO:EOF

:update
::parameters MachineType[x86|x64] "filepath"

::engine version
set _tmp=%random%.tmp
mkdir %~dp0%_tmp%
pushd %~dp0%_tmp%
%~dp0%1\mpam-fe.exe -extract
%~dp0sigcheck -q %~dp0%_tmp%\mpengine.dll > sig.tmp
for /f "tokens=2 delims=:-  " %%a in ('findstr /C:"File version" sig.tmp') do set eng=%%a
popd
rmdir /q /s %~dp0%_tmp%
::

::mpam-fe.exe vdbVersion
sigcheck -q %1\mpam-fe.exe > sig.tmp
for /f "tokens=2 delims=:   " %%a in ('findstr /C:"File version" sig.tmp') do call:spider %1 %%a %eng%
GOTO:EOF

:spider
::parameters MachineType[x86|x64] vdbVersion vEngineVersion
wget --spider %url%^&arch=%1^&avdelta=%2^&asdelta=%2^&eng=%3 -o log.tmp
for /f "tokens=3" %%a in ('findstr "d.exe$" log.tmp') do call:proc_delta %1 %%a
for /f "tokens=3" %%a in ('findstr "fe.exe$" log.tmp') do call:proc_full %1 %%a
GOTO:EOF

:proc_delta
echo dl delta
wget -nv --no-cache -P%1 -N %2
GOTO:EOF

:proc_full
echo dl full
del /f /q %1\mpam-d.exe >nul 2>nul
wget -nv -P%1 -N %2