API tools faq
paste
Advertisement
T3RRYT3RR0R

Batch Snake v1.4

T3RRYT3RR0R
Dec 8th, 2020 (edited)
1,463
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Batch 10.05 KB | None | 0 0
raw download clone embed print report
  1. @Echo off
  2. ==================================================
  3. ::: Snake by T3RRY Version 1.4 11/12/2020
  4. ::: *** To play Download is REQUIRED from https://drive.google.com/file/d/1_ivtZsSzxEiig3bdCurNFg7SqGES4T53/view?usp=sharing
  5. ::: * This paste is a newer version than contained in the download file *
  6. ::: Download contains:
  7. ::: Getkey.Exe by Antonio {https://stackoverflow.com/users/778560/aacini} for Extended key controls.
  8. ::: Snake.bat by T3RRY {https://stackoverflow.com/users/12343998/t3rr0r}
  9. ==================================================
  10.  If "!![" == "[" (Echo/Delayed expansion Must not be enabled prior to starting %~n0.bat & Pause & Exit /B 0)
  11.  CHCP 65001 > nul
  12. (Set \n=^^^
  13.  
  14. %= Macro Newline Do not Modify this code block =%)
  15.  wmic OS get OSArchitecture,caption | FIND "10" > nul || (ECHO/Windows 10 required for ascii escape codes & Exit /B)
  16.  for /F "delims=#" %%a in ('"prompt #$E# & for %%a in (1) do rem"') do set "\E=%%a"
  17.  For /F "Delims=" %%C in ('dir "%~dp0*GetKey.exe" /B /S') Do If not defined GetKey Set "GetKey="%%C" /n"
  18.  Echo/%GetKey%|findstr.exe /LIC:"GetKey.exe" > nul || (Echo/GetKey.Exe not found in Directory. Game cannot be played without GetKey.exe &Pause &Exit /B 0)
  19.  (For /F "Tokens=1,2 Delims==" %%G in ('Set "}" 2^> Nul ')Do Set "%%~G=") 2> nul
  20.  If not exist "%TEMP%" (Set "Save.Dir=%~dp0")Else Set "Save.Dir=%TEMP%\"
  21.  break >"%Save.Dir%%~n0_testpermission.com" || (
  22.   Echo/You do not have write permission in %Save.Dir%
  23.   Pause
  24.   exit /B 0
  25.  )
  26.  Set Background="%Save.Dir%%~n0_background.~tmp"
  27.  Set Foreground="%Save.Dir%%~n0_foreground.~tmp"
  28.  Set Save="%Save.Dir%%~n0_File.~sav"
  29.  mode 80,26
  30.  Set "\C=%\E%[1X"
  31.  Set Background.Border=Set "Border=" ^& For %%n in (1 2)Do If %%n==2 (%\n%
  32.   For /F "Tokens=1,2,3,4,5,6 Delims={}" %%G in ("!Border!")Do If not "%%L" == "" (%\n%
  33.    Set /A ".Xmin=%%H,.Xmax=%%I,.Ymin=%%J,.Ymax=%%K"%\n%
  34.    Set ".Char=%%L"%\n%
  35.    For %%w in (%%H %%I)Do for /L %%h in (%%J,1,%%K)Do (%\n%
  36.     Set "}%%h;%%w=%\E%[%%h;%%wH%\E%[%%~Gm%%~L"%\n%
  37.     For %%i in (%%J %%K)Do If %%h Equ %%i (%\n%
  38.      For /L %%W in (%%H 1 %%I)Do (%\n%
  39.       Set "}%%h;%%W=%\E%[%%h;%%WH%\E%[%%~Gm%%~L"%\n%
  40.   ))))Else ( Echo/Missing Args for %%Background.Border%% ^& Pause ^> nul )%\n%
  41.  )Else Set Border=
  42.  Set "UPDATE.Background=Set /A ".End=!.Ymax! + 1" & ((For /F "Tokens=2* Delims==" %%G in ('Set "}"')Do (< nul Set /P "=%%~G") & < nul Set /P "=%\E%[!.END!;1H%\E%[0m%\E%[?25l")) >%Background% & Type %Background%"
  43.  Set show.snake=For %%n in (1 2)Do if %%n==2 ( %\n%
  44.   (For /F "Tokens=1,2 Delims={}" %%A in ("!Chars!")Do ( %\n%
  45.     For %%h in ("!head:#=%%~A!")Do ( %\n%
  46.      ^<nul Set /P "=%%~h%\E%[!.End!H" %\n%
  47.     ) %\n%
  48.     For %%t in (!tail!)Do ( %\n%
  49.     ^<nul Set /P "=%\E%[%%~tH%\E%[!Tail.Color!m%%B%\E%[!.End!H%\E%[0m" %\n%
  50.   )))^>%Foreground% ^& Type %foreground% %\n%
  51.  )Else Set Chars=
  52.  Set "Left={x}{-}"&Set "Right={x}{+}"&Set "Up={y}{-}"&Set "Down={y}{+}"
  53.  Set Move.Snake=For %%n in (1 2) Do if %%n==2 ( %\n%
  54.   Set "valid=1" %\n%
  55.   For /F "Tokens=1,2,3,4 Delims={}" %%G in ("!Move.Dir!")Do If not "%%~J" == "" ( %\n%
  56.    If /I "%%G" == "x" (Set /A "lx0=!x0!,ly0=!y0!,nx0= !x0! %%H 1")Else (Set /A "nx0=!x0!") %\n%
  57.    If /I "%%G" == "y" (Set /A "lx0=!x0!,ly0=!y0!,ny0= !y0! %%H 1")Else (Set /A "ny0=!y0!") %\n%
  58.    For /F "Delims=" %%p in ("!ny0!;!nx0!")Do If not "!{%%p!" == "" ( %\n%
  59.     Set "valid=0" %\n%
  60.     For /F "Delims=" %%v in ("!{%%p!")Do ( %\n%
  61.      Set "Cell=%%v" %\n%
  62.      Set "?tail=!Cell:%%I=!" %\n%
  63.      If Not "!?Tail!" == "!Cell!" (Goto :Gameover) %\n%
  64.     ) %\n%
  65.     Set "?tail=!Cell:%%J=!" %\n%
  66.     If Not "!?Tail!" == "!Cell!" ( %\n%
  67.      Set "{!fy!;!fx!="^& Set "fy="^& Set "fx=" %\n%
  68.      Set "Valid=1" %\n%
  69.      Set /A "Score+=50" %\n%
  70.      If !Delay! LSS 5 Set /A "Score+=50" %\n%
  71.      Call :makePi %\n%
  72.      Set /A "tail.len+=1" %\n%
  73.      Set "Tail="!y0!;!x0!",!Tail!" %\n%
  74.      Set "{!ny0!;!nx0!=!Snake.Head!" %\n%
  75.    )) %\n%
  76.    If "!valid!" == "1" ( %\n%
  77.     If !n%%G0! LEQ !.%%Gmin! (Goto :Gameover)else If !n%%G0! GEQ !.%%Gmax! (Goto :Gameover)Else ( %\n%
  78.      If "!Tail.len!" == "0" ( %\n%
  79.       Set "{!y0!;!x0!=" %\n%
  80.       ^<nul Set /P "=%\E%[!y0!;!x0!!H%\C%" %\n%
  81.      )Else ( %\n%
  82.       Set "Tail="!y0!;!x0!",!Tail!" %\n%
  83.       Set "Tail.{i}=0" %\n%
  84.       For %%r in (!Tail!)Do ( %\n%
  85.        If !Tail.{i}! EQU !Tail.Len! ( %\n%
  86.         Set "Tail=!Tail:,"%%~r"=,!" ^& Set "{%%~r="^&^<nul Set /P "=%\E%[%%~r!H%\C%" %\n%
  87.        )Else ( %\n%
  88.         Set "{%%~r=!Snake.Tail!" %\n%
  89.         Set /A "Tail.{i}+=1" %\n%
  90.      ))) %\n%
  91.      Set "{!ny0!;!nx0!=!Snake.Head!" %\n%
  92.      Set /A "%%G0=!n%%G0!" %\n%
  93.  ))))Else Set Move.Dir=
  94.  Set "head=%\E%[!y0!;!x0!H%\E%[!head.color!m#%\E%[0m"
  95.  Set "DefArray=For %%n in (1 2)Do if %%n==2 (Set /A "{i}=0"& For %%G in (!list!)Do (Set "$V[!{i}!]=%%G"& Set /A "{i}+=1"))Else Set List="
  96.  Set "Info=For %%i in (!Theme!)Do <nul Set /P "=%\E%[9;55HTheme  - 0~9 %\E%[!Border.Color[%%i]!m!Theme!%\E%[0m%\E%[10;55HScore: !Score!%\E%[11;55HHigh Score:!HighScore!%\E%[12;55HPi Eaten:!Tail.Len!%\E%[0m%\E%[13;55HDelay:%\E%[K + !Delay! -%\E%[15;55H%\E%[K%\E%[90mHeading: !Dir:space=Pause!     %\E%[16;55H%\E%[90mLast Move: !Key!    ""
  97.  Set "k-72=Up"&Set "k-80=Down"&Set "k-75=Left"&Set "k-77=Right"&Set "k32=space"&Set "k43=plus"&Set "k45=minus"&Set "k27=ESC"
  98.  Set /A "k48=0,k49=1,k50=2,k51=3,k52=4,k53=5,k54=6,k55=7,k56=8,k57=9,Theme=0,HighScore=0"
  99.  Set ".Left=Right"&Set ".Right=Left"&Set ".Up=Down"&Set ".Down=Up"
  100.  Set "Dir=Space"
  101.  Set "Pi.char=%\E%(0{%\E%(B" & set "Pi.color=37"
  102.  Set "}2;55=%\E%[2;55H%\E%[33mControls:"
  103.  Set "}3;55=%\E%[3;55H  ▲    - Up"
  104.  Set "}4;55=%\E%[4;55H  ◄    - Left"
  105.  Set "}5;55=%\E%[5;55H  ▼    - Down"
  106.  Set "}6;55=%\E%[6;55H  ►    - Right"
  107.  Set "}7;55=%\E%[7;55HSpace  - Pause"
  108.  Set "}8;55=%\E%[8;55HEscape - Quit"
  109.  CLS
  110.  Echo/Select Playfield Size:
  111.  Echo/    [  X  ]   [  Y  ]  Area
  112.  Echo/{0}  1;50   x  1;25    1104
  113.  Echo/{1}  2;48   x  2;24     945
  114.  Echo/{2}  6;47   x  4;23     663
  115.  Echo/{3}  7;45   x  5;22     540
  116.  Echo/{4}  10;40  x  6;21     364
  117.  For /F "Delims=" %%z in ('Choice /N /C:01234')Do Set "[s]=[%%z]"
  118.  Set "Delay=10"
  119. :start
  120.  If exist %Save:File=Theme% (
  121.   <%Save:File=Theme% (
  122.   Set /P "Theme="
  123.  ))
  124.  If exist %Save:File=Delay% (
  125.   <%Save:File=Delay% (
  126.   Set /P "Delay="
  127.  ))
  128.  Title Snake by T3RRY & CLS
  129.  Setlocal EnableExtensions EnableDelayedExpansion
  130.  %DefArray:$V=Head.Color% 32 33 34 35 36 37 93 94 95 96
  131.  %DefArray:$V=Tail.Color% 96 95 94 93 37 36 35 33 34 32
  132.  %DefArray:$V=Snake.Head% ☺  ☻  ♂  ♀  ☼  §  @  D  O  K
  133.  %DefArray:$V=Snake.Tail% #  ░  ▒  ▓  ▬  æ  «  »  [  ]
  134.  %DefArray:$V=Border.Char%♥  ♦  ♣  ♠  •  ◘  ○  ◙  ♫  ¶
  135.  %DefArray:$V=Border.Color%    31 93 33 92 "48;2;155;125;60" 35 96 32 36 24
  136.  %DefArray:$V=Border.Size% {1}{50}{1}{25} {2}{48}{2}{24} {6}{47}{4}{23} {7}{45}{5}{22} {10}{40}{6}{21}
  137.  For %%i in (%Theme%)Do For %%o in (head tail)Do If not "!%%o.Color[%%i]!" == "" (Set "%%o.Color=!%%o.Color[%%i]!"&Set "Snake.%%o=!Snake.%%o[%%i]!"&Set "Border.Color=!Border.Color[%%i]!"&Set "Border.Char=!Border.Char[%%i]!")
  138.  %Background.Border%{!Border.Color[%Theme%]!}!Border.Size%[s]%!{!Border.Char[%Theme%]!}
  139.  Set /A "MidX=(.Xmax / 2) + (.Xmin / 2),MidY=(.Ymax / 2) + (.Ymin / 2)"
  140.  Set /A "x0=Midx,y0=MidY,tail.len=0,Score=0"
  141.  %UPDATE.Background%
  142.  Call :makePi
  143.  If exist %Save:File=highscore% (
  144.   <%Save:File=highscore% (
  145.     Set /P "HighScore="
  146.    )
  147.  )
  148. set /A Highscore+=0
  149. :gameloop
  150.  If Defined Last.Dir If /I Not "!Dir!" == "Space" (
  151.   Set "Dir=!Last.Dir!" & Set "Last.Dir="
  152.  )
  153.  If %Score% GTR %HighScore% (
  154.   Set /A "Highscore=%Score%"
  155.   >%Save:File=highscore% Echo/%Score%
  156.  )
  157.  %INFO%
  158.  If /I not "!Dir!" == "Space" For %%D in (!%Dir%!)Do %Move.Snake%%%D{%Snake.Tail%}{%Pi.char%}
  159.  %Show.Snake%{!Snake.Head!}{!Snake.Tail!}
  160.  %getKey%
  161.  For %%e in (!Errorlevel!)Do If not "!k%%e!" == "" For %%v in (!Dir!)Do if not "!k%%e!" == "!.%%v!" (
  162.   Set "cc=0"
  163.   For %%i in (!k%%e!)Do For %%o in (head tail)Do If not "!%%o.Color[%%i]!" == "" (
  164.    Set "%%o.Color=!%%o.Color[%%i]!"&Set "Snake.%%o=!Snake.%%o[%%i]!"&Set /A "cc=1,Theme=%%i"
  165.    >"%Save:File=Theme%" (Echo/!Theme!)
  166.    %Background.Border%{!Border.Color[%%i]!}{!.Xmin!}{!.Xmax!}{!.Ymin!}{!.Ymax!}{!Border.Char[%%i]!}
  167.    %UPDATE.Background%
  168.   )
  169.   If Not "!cc!" == "1" (Set "Key=!k%%e!")Else Goto :gameloop
  170.   If not defined Last.dir If /I "!Key!" == "Space" If /I not "!Dir!" == "!Space!" Set "Last.Dir=!Dir!"
  171.   If /I "!Key!" == "plus" (If !Delay! LSS 75 (Set /A "Delay+=1" & >"%Save:File=Delay%" (Echo/!Delay!)) & Goto :gameloop)
  172.   If /I "!Key!" == "minus" (If !Delay! GEQ 1 (Set /A "Delay-=1" & >"%Save:File=Delay%" (Echo/!Delay!)) & Goto :gameloop)
  173.   If /I not "!Key!" == "minus" If /I not "!key!" == "plus" Set "Dir=!k%%e!"
  174.  )
  175.  If "!Key!" == "" (goto :gameloop)
  176.  If /I "!Key!" == "ESC" (goto :End)
  177.  If %Delay% GTR 0 ( For /L %%d in (1 1 !Delay!)Do Call :Delay 2> nul )Else Call :Delay 2> nul
  178. Goto :gameloop
  179. :Gameover
  180.  Title Game over
  181.  Set "Tail.Color=90"
  182.  Echo/|Choice.exe /N /C:n 2> nul
  183.  %Background.Border%{48;2;75;75;165}{!.Xmin!}{!.Xmax!}{!.Ymin!}{!.Ymax!}{!Border.Char[%%i]!}{#}
  184.  %UPDATE.Background%
  185.  %Show.Snake%{%\E%[31m!Snake.Head!}{!Snake.Tail!}
  186.  Timeout /T 2 /NoBreak > nul
  187.  Del "%Save.Dir%%~n0*.~tmp"
  188.  Pause > Nul
  189.  CLS
  190.  Endlocal
  191. Goto :Start
  192. :End
  193.  <nul Set /P "=%\E%[?25h"
  194.  Del "%Save.Dir%%~n0*.~tmp"
  195.  Endlocal
  196.  Goto :Eof
  197. :makePi function
  198. Setlocal enableDelayedExpansion
  199. :confirmpos
  200.  If not "!fy!" == "" If not "!fx!" == "" ( <nul Set /P "=%\E%[!fy!;!fx!H %\E%[0m" )
  201.  Set "fValid=1"
  202.  Set /A "fXmax=(.Xmax-.Xmin)-1,fYmax=(.Ymax-.Ymin)-1"
  203.  Set /a "nfy=(!random! %% fYmax) + .Ymin ,nfx=(!random! %% fXmax) + .Xmin "
  204.  For /F "delims=" %%g in ("{!nfy!;!nfx!")Do If Not "!%%g!" == "" (Set "fValid=0")
  205.  For /F "delims=" %%h in ("}!nfy!;!nfx!")Do If Not "!%%h!" == "" (Set "fValid=0")
  206.  Set "ftq=!tail:"%nfy%;%nfx%"=!"
  207.  If not %tail.len% EQU 0 (If not "!tail!" == "!ftq!" (Set "fValid=0"))
  208.  If "!fValid!" == "1" (
  209.   <nul Set /P "=%\E%[!nfy!;!nfx!H%\E%[%Pi.color%m!Pi.char!%\E%[0m"
  210.   Endlocal & Set "fy=%nfy%" & Set "fx=%nfx%" & Set "{%nfy%;%nfx%=%Pi.char%"
  211.   Exit /B 0
  212.  ) Else (Set "nfy=" & Set "nfx=")
  213. Goto :confirmpos
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!