Logarithmic Spiral's Caustic

a = 0.2;
\[Theta]max = Pi;
\[Theta]cont = 4 Pi;
\[Theta]min = -15;
s[\[Theta]_] := Exp[a \[Theta]] {Cos[\[Theta]], Sin[\[Theta]]};
red = RGBColor[222/255, 55/255, 29/255];
transf[t_] := ((1 - t) + t (2 a/(1 + a^2))) {{a t + (1 - t), t}, {-t,
     a t + (1 - t)}};
frame[t_] :=
  Show[
   ParametricPlot[
    {
     s[\[Theta]],
     transf[1 - If[t < 1.2, 0, Min[1, 1.5 (t - 1.2)]]].s[\[Theta]]
     }, {\[Theta], -20, 40},
    PlotStyle -> {Directive[red, Thick,
       Opacity[0.5 - 0.5 Tanh[5 (t - 1)]]],
      Directive[red, Thick, Opacity[0.5 Tanh[5 (t - 1.1)] + 0.5]]}
    , PlotRange -> 1.1 Norm[s[\[Theta]max]], Axes -> None,
    Background -> RGBColor[44/255, 71/255, 98/255]],
   Graphics[
    Table[
     {
      White,
      Opacity[0.32 (0.5 - 0.5 Tanh[7 (t - 1.1)])],
      Line[{{0, 0}, s[\[Theta]]}],
      Block[{p = s'[\[Theta]], q},
       q = {-p[[2]], p[[1]]};
       Line[{s[\[Theta]], s[\[Theta]] + 100 q/Norm[q]}]
       ]
      }
     , {\[Theta], \[Theta]min - 0.01, \[Theta]min +
       Min[t, 1] (\[Theta]max + \[Theta]cont - \[Theta]min), \
(\[Theta]max - \[Theta]min)/143}]
    , PlotRange -> 1.1 Norm[s[\[Theta]max]]]
   ];
Manipulate[frame[t], {{t, 0.8}, 0, 1.9}]