ASTDR and ASTDRmc

# ASTDR DeRainbow function v1.53

  function ASTDR(clip input, int "strength", int "tempsoftth", int "tempsoftrad", int "tempsoftsc", float "blstr", int "tht", int "FluxStv", int "dcn", bool "edgem")
  {
  strn          = Default(strength, 5)
  blstr         = Default(blstr, 0.5)
  tht           = Default(tht, 255)
  tschrth       = Default(tempsoftth, 30)
  tschrrad      = Default(tempsoftrad, 3)
  tschrsc       = Default(tempsoftsc, 3)
  FluxStv       = Default(FluxStv, 75)
  dcn           = Default(dcn, 15)
  edgem         = default(edgem, false)

  momask    = input.tweak(sat=1.1).mt_motion(thc2=1,thc1=1,thy2=1,thy1=1,y=3,v=3,u=3,tht=tht)
  momaskinv = momask.mt_expand(u=3, v=3).mt_inflate(u=3, v=3).Invert().Levels(0,2,255,0,255)

  filtered_uv = input.DeCross(ThresholdY=15, Noise=dcn, Margin=1).FluxSmoothST(FluxStv,FluxStv).Mergeluma(input).awarpsharp2(depth=4,chroma=6,cplace="MPEG2").hqdn3d(ls=0,lt=0,cs=strn*3/5,ct=strn)
              \ .temporalsoften(tschrrad,0,tschrth,tschrsc,2).blur(blstr).Mergeluma(input).aWarpSharp2(depth=4,chroma=6,cplace="MPEG2").fft3dfilter(sigma=1,sigma3=4,plane=3,degrid=1)

  filtered = mt_merge(filtered_uv, input, momaskinv,y=2,u=3,v=3,luma=true)

  mt_merge(input, filtered, momask.mt_expand(mode="both", y=1,u=3,v=3).mt_inflate(y=1,u=3,v=3),y=2,u=3,v=3)
  edgem ? mt_merge(input, last, input.mt_edge("sobel", 4, 4, 4, 4).mt_expand().mt_inflate(),y=2,u=3,v=3,luma=true) : last
  }

# ASTDRmc DeRainbow function v1.5

  function ASTDRmc(clip prerb, int "strength", int "tempsoftth", int "tempsoftrad", int "tempsoftsc", float "blstr", int "tht", int "FluxStv", int "dcn", bool "edgem", int "thSAD")
  {

  tht      = Default(tht, 255)
  tschrrad = Default(tempsoftrad, 3).min(5)
  thSAD    = Default(thSAD, tht)

derbmask = (VersionNumber() < 2.60) ? prerb.tedgemask(threshY=2).mt_inflate() : prerb.TEMmod(threshY=2).mt_inflate()

derbsuper = prerb.MSuper()

b5v = tschrrad > 4 ? MAnalyse(derbsuper, delta=5, truemotion = true, isb = true, chroma=false) : nop()
b4v = tschrrad > 3 ? MAnalyse(derbsuper, delta=4, truemotion = true, isb = true, chroma=false) : nop()
b3v = tschrrad > 2 ? MAnalyse(derbsuper, delta=3, truemotion = true, isb = true, chroma=false) : nop()
b2v = tschrrad > 1 ? MAnalyse(derbsuper, delta=2, truemotion = true, isb = true, chroma=false) : nop()
b1v = MAnalyse(derbsuper, delta=1, truemotion = true, isb = true, chroma=false)
f1v = MAnalyse(derbsuper, delta=1, truemotion = true, isb = false, chroma=false)
f2v = tschrrad > 1 ? MAnalyse(derbsuper, delta=2, truemotion = true, isb = false, chroma=false) : nop()
f3v = tschrrad > 2 ? MAnalyse(derbsuper, delta=3, truemotion = true, isb = false, chroma=false) : nop()
f4v = tschrrad > 3 ? MAnalyse(derbsuper, delta=4, truemotion = true, isb = false, chroma=false) : nop()
f5v = tschrrad > 4 ? MAnalyse(derbsuper, delta=5, truemotion = true, isb = false, chroma=false) : nop()

f5c = tschrrad > 4 ? prerb.MCompensate(derbsuper, f5v, thSAD=thSAD) : nop()
f4c = tschrrad > 3 ? prerb.MCompensate(derbsuper, f4v, thSAD=thSAD) : nop()
f3c = tschrrad > 2 ? prerb.MCompensate(derbsuper, f3v, thSAD=thSAD) : nop()
f2c = tschrrad > 1 ? prerb.MCompensate(derbsuper, f2v, thSAD=thSAD) : nop()
f1c = prerb.MCompensate(derbsuper, f1v)
b1c = prerb.MCompensate(derbsuper, b1v)
b2c = tschrrad > 1 ? prerb.MCompensate(derbsuper, b2v, thSAD=thSAD) : nop()
b3c = tschrrad > 2 ? prerb.MCompensate(derbsuper, b3v, thSAD=thSAD) : nop()
b4c = tschrrad > 3 ? prerb.MCompensate(derbsuper, b4v, thSAD=thSAD) : nop()
b5c = tschrrad > 4 ? prerb.MCompensate(derbsuper, b5v, thSAD=thSAD) : nop()

mcclip = tschrrad == 5 ? interleave(f5c,f4c,f3c,f2c,f1c,prerb,b1c,b2c,b3c,b4c,b5c) : \
         tschrrad == 4 ? interleave(f4c,f3c,f2c,f1c,prerb,b1c,b2c,b3c,b4c) : \
         tschrrad == 3 ? interleave(f3c,f2c,f1c,prerb,b1c,b2c,b3c) : \
         tschrrad == 2 ? interleave(f2c,f1c,prerb,b1c,b2c) : \
                         interleave(f1c,prerb,b1c)

ASTDRclip = mcclip.ASTDR(strength=strength,tempsoftth=tempsoftth,tempsoftrad=tempsoftrad,tempsoftsc=tempsoftsc,blstr=blstr,tht=tht,FluxStv=FluxStv,dcn=dcn,edgem=edgem)

mt_merge(prerb,ASTDRclip.selectevery(tschrrad * 2 + 1, tschrrad), derbmask,luma=true,y=2,u=3,v=3)
  }