# Maintainer: Emmanuel Gil Peyrot <linkmauve@linkmauve.fr>
# Contributor: aldelaro5 <aldelaro5@gmail.com>

_pkgbase='decaf-emu'
pkgname="$_pkgbase-git"
pkgver=r3123.accde26a
pkgrel=1
pkgdesc="An experimental open-source Nintendo Wii U emulator"
arch=('x86_64')
url="https://github.com/decaf-emu/decaf-emu"
license=('GPL')
depends=('zlib' 'sdl2')
makedepends=('git' 'cmake')
source=("$_pkgbase::git+https://github.com/decaf-emu/decaf-emu"
        'git+https://github.com/zeux/pugixml#commit=d2deb42'
        #'git+https://github.com/kobalicek/asmjit'
        'git+https://github.com/gabime/spdlog#commit=93d84e5'
        'git+https://github.com/USCiLab/cereal#commit=51cbda5'
        'git+https://github.com/exjam/ovsocket#commit=863b889'
        'git+https://github.com/cginternals/glbinding#commit=98d3695'
        'git+https://github.com/decaf-emu/gsl-lite#commit=369fcb5'
        'git+https://github.com/decaf-emu/addrlib#commit=d30a77f'
        'git+https://github.com/exjam/excmd#commit=c2e8d49'
        'git+https://github.com/ocornut/imgui#commit=6384eee'
        'git+https://github.com/johnmcfarlane/fixed_point.git#commit=7a084e2'
        'git+https://github.com/decaf-emu/libbinrec.git#commit=da8482b')
md5sums=('SKIP'
         'SKIP'
         'SKIP'
         'SKIP'
         'SKIP'
         'SKIP'
         'SKIP'
         'SKIP'
         'SKIP'
         'SKIP'
         'SKIP'
         'SKIP')

pkgver() {
  cd "$srcdir/$_pkgbase"
  echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/$_pkgbase"
  mkdir -p build

  git submodule init
  git config submodule.libraries/pugixml.url "$srcdir/pugixml"
  #git config submodule.libraries/asmjit.url "$srcdir/asmjit"
  git config submodule.libraries/spdlog.url "$srcdir/spdlog"
  git config submodule.libraries/cereal.url "$srcdir/cereal"
  git config submodule.libraries/ovsocket.url "$srcdir/ovsocket"
  git config submodule.libraries/glbinding.url "$srcdir/glbinding"
  git config submodule.libraries/gsl-lite.url "$srcdir/gsl-lite"
  git config submodule.libraries/addrlib.url "$srcdir/addrlib"
  git config submodule.libraries/excmd.url "$srcdir/excmd"
  git config submodule.libraries/imgui.url "$srcdir/imgui"
  git config submodule.libraries/fixed_point.url "$srcdir/fixed_point"
  git config submodule.libraries/libbinrec.url "$srcdir/libbinrec"
}

build() {
  cd "$srcdir/$_pkgbase"
  git submodule update \
    libraries/pugixml \
    libraries/spdlog \
    libraries/cereal \
    libraries/ovsocket \
    libraries/glbinding \
    libraries/gsl-lite \
    libraries/addrlib \
    libraries/excmd \
    libraries/imgui \
    libraries/fixed_point \
    libraries/libbinrec

  cd build
  cmake .. -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd "$srcdir/$_pkgbase/build"
  make DESTDIR="$pkgdir/" install
}