DFSR Backlog

Set wshShell = WScript.CreateObject( "WScript.Shell" )
strComputer = wshShell.ExpandEnvironmentStrings( "%COMPUTERNAME%" )

bConnectForeign = False
Wscript.echo("<<<dfs_backlog:sep(59)>>>")

    Set oWMIService = GetObject("winmgmts:\\" & strComputer & "\root\MicrosoftDFS")
    Set colRGroups = oWMIService.ExecQuery("SELECT * FROM DfsrReplicationGroupConfig")
    For Each oGroup in colRGroups
        'wscript.echo "Replication Group: " & oGroup.ReplicationGroupName
        Set colRGFolders = oWMIService.ExecQuery("SELECT * FROM DfsrReplicatedFolderConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
        For Each oFolder in colRGFolders
            'wscript.echo "  Folder: " & oFolder.ReplicatedFolderName
            Set colRGConnections = oWMIService.ExecQuery("SELECT * FROM DfsrConnectionConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
            For Each oConnection in colRGConnections
                If oConnection.Enabled = True Then
                    If oConnection.Inbound = True Then
                        if bConnectForeign then
                            numBackLog = getBackLogCount(oConnection.PartnerName, oConnection.ConnectionGUID, oFolder.ReplicatedFolderGuid)
                        else
                            numBackLog = getBackLogCount(strComputer, oConnection.ConnectionGUID, oFolder.ReplicatedFolderGuid)
                        end if
                        Wscript.echo oFolder.ReplicatedFolderName & " ( from " & oConnection.PartnerName & ");" & numBackLog
                    Else
                        numBackLog = getBackLogCount(strComputer, oConnection.ConnectionGUID, oFolder.ReplicatedFolderGuid)
                        Wscript.echo oFolder.ReplicatedFolderName & " ( to " & oConnection.PartnerName & ");" & numBackLog
                    End If
                End If
            Next
        Next
    Next

Function getBackLogCount(strComputer, ConnectionGUID, FolderGuid)
    Set oWMIService = GetObject("winmgmts:\\" & strComputer & "\root\MicrosoftDFS")
    Set oDfsIUI = oWMIService.ExecQuery("SELECT * FROM DfsrIdUpdateInfo WHERE ConnectionGuid = '" & ConnectionGUID & "' AND ReplicatedFolderGuid ='" & FolderGuid & "'")
    numBacklog=0
    for each eDfsIUI in oDfsIUI
        numBackLog=numBackLog+1
    next
    getBackLogCount = numBackLog
End Function