/*
    USHORT *VideoMem = (PUSHORT)0xb8000;
    unsigned Buffer  = ((0x01 << 8) | (0xb0 & 0xff));
    memset(VideoMem, Buffer, 80*25 * 2);

    _mouse_x = 0;
    _mouse_y = 0;
    initPS2();
    for (;;) {
        VideoMem[ (_mouse_y*80) + _mouse_x ] = ((0x01 << 8) | (0xb0 & 0xff));
        mouse_handler();
        VideoMem[ (_mouse_y*80) + _mouse_x ] = 0x020f;
    }
*/

; Assembler Code is adapted from osdev.org
; me: make little bit hack (variables)
;
; The code displays a mouse cursor (in text mode - a character
; at 0;9
; but the ps2 mice wont be work, yet

section .text

;dl=1 read, dl=2 write
ps2wait:
      mov         ecx, 1000
.1:   in          al, 64h
      and         al, dl
      jnz         .2
      dec         ecx
      jnz         .1
.2:   ret
ps2wr:
      mov         dh, al
      mov         dl, 2
      call        ps2wait
      mov         al, 0D4h
      out         64h, al
      call        ps2wait
      mov         al, dh
      out         60h, al
      ;no ret, fall into read code to read ack
ps2rd:
      mov         dl, 1
      call        ps2wait
      in          al, 60h
      ret

      ;initialize legacy ps2 user input
global _initPS2
_initPS2:
      xor         eax, eax
      mov         dl, 2
      call         ps2wait
      mov         al, 0A8h
      out         64h, al
      ;get ack
      call         ps2rd
      ;some compaq voodoo magic to enable irq12
      mov         dl, 2
      call         ps2wait
      mov         al, 020h
      out         64h, al
      mov         dl, 1
      call         ps2wait
      in         al, 60h
      bts         ax, 1
      btr         ax, 5
      mov         bl, al
      mov         dl, 2
      call         ps2wait
      mov         al, 060h
      out         64h, al
      call         ps2wait
      mov         al, bl
      out         60h, al
      ;get optional ack
      mov         dl, 1
      call         ps2wait

      ;restore to defaults
      mov         al, 0F6h
      call         ps2wr
      ;enable Z axis
      mov         al, 0F3h
      call         ps2wr
      mov         al, 200
      call         ps2wr
      mov         al, 0F3h
      call         ps2wr
      mov         al, 100
      call         ps2wr
      mov         al, 0F3h
      call         ps2wr
      mov         al, 80
      call         ps2wr
      mov         al, 0F2h
      call         ps2wr
      call         ps2rd
      mov         byte [packetsize], 3
      or         al, al
      jz         .noZaxis
      mov         byte [packetsize], 4
.noZaxis:   ;enable 4th and 5th buttons
      mov         al, 0F3h
      call         ps2wr
      mov         al, 200
      call         ps2wr
      mov         al, 0F3h
      call         ps2wr
      mov         al, 200
      call         ps2wr
      mov         al, 0F3h
      call         ps2wr
      mov         al, 80
      call         ps2wr
      mov         al, 0F2h
      call         ps2wr
      call         ps2rd

      ;set sample rate
      mov         al, 0F3h
      call         ps2wr
      mov         al, byte[samplerate] ;200
      call         ps2wr
      ;set resolution
      mov         al, 0E8h
      call         ps2wr
      mov         al, byte [resolution] ;3
      call         ps2wr
      ;set scaling 1:1
      mov         al, 0E6h
      call         ps2wr
      ;enable
      mov         al, 0F4h
      call         ps2wr

      ;reset variables
      xor         eax, eax
      mov         dword [cnt], eax
      mov         dword [y], eax

      ret


global _mouse_handler
_mouse_handler:
      xor         ecx, ecx
      mov         cx, 1000
      xor         eax, eax
.waitkey:   in         al, 64h
      dec         cl
      jnz         .1
      ret
.1:
      and         al, 20h
      jz         .waitkey
      in         al, 60h
      mov         cl, al
      in         al, 61h
      out         61h, al
      xor         ebx, ebx
      mov         bl, byte [cnt]
      add         ebx, packet
      mov         byte [ebx], cl
      inc         byte [cnt]
      mov         bl, byte [cnt]
      cmp         bl, byte [packetsize]
      jb         .end
      mov         byte [cnt], 0

      ;get buttons state
.2:
      mov         al, byte [packet]
      and         al, 7
      mov         cl, byte [packet+3]
      and         cl, 0F0h
      cmp         cl, 0F0h
      je         .no45btn
      shr         cl, 1
      or         al, cl
.no45btn:   mov         byte [buttons], al
      ;get delta X
      movsx      eax, byte [packet+1]
      add         word [x], ax
      ;get delta Y
      movsx      eax, byte [packet+2]
      add         word [y], ax
      ;get delta Z
      mov         cl, byte [packet+3]
      and         cl, 0Fh
      cmp         cl, 8
      jb         .3
      or         cl, 0F0h
.3:   movsx      eax, cl
      add         word [z], ax

    mov eax, [x]
    mov [__mouse_x], eax

    mov eax, [y]
    mov [__mouse_y], eax

;buttons,x,y,z variables contains valid values now.
;here you possibly want to send a mouse event message to your gui process.
.end:
    ret

section .data
global __mouse_x
global __mouse_y

__mouse_x:      dw 0
__mouse_y:      dw 0

videomem :      dd 0xb8000

packetsize: db 0
resolution: db 3
samplerate: db 200

packet: dd 0   ;raw packet
;keep them together
cnt: db 0      ;byte counter
buttons: db 0   ;buttons, each bit represents one button from bits 1-5, 0-released, 1-pressed
x: dw 0      ;position on x,y,z axis
y: dw 0
z: dw 0